lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use Email::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22 *xpfx = *PublicInbox::Search::xpfx;
  23
  24 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  25 use constant {
  26         PERM_UMASK => 0,
  27         OLD_PERM_GROUP => 1,
  28         OLD_PERM_EVERYBODY => 2,
  29         PERM_GROUP => 0660,
  30         PERM_EVERYBODY => 0664,
  31 };
  32
  33 sub new {
  34         my ($class, $inbox, $creat) = @_;
  35         my $git_dir = $inbox;
  36         my $altid;
  37         if (ref $inbox) {
  38                 $git_dir = $inbox->{mainrepo};
  39                 $altid = $inbox->{altid};
  40                 if ($altid) {
  41                         require PublicInbox::AltId;
  42                         $altid = [ map {
  43                                 PublicInbox::AltId->new($inbox, $_);
  44                         } @$altid ];
  45                 }
  46         }
  47         require Search::Xapian::WritableDatabase;
  48         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  49         my $perm = $self->_git_config_perm;
  50         my $umask = _umask_for($perm);
  51         $self->{umask} = $umask;
  52         $self->{lock_path} = "$git_dir/ssoma.lock";
  53         $self->{git} = PublicInbox::Git->new($git_dir);
  54         $self->{creat} = ($creat || 0) == 1;
  55         $self;
  56 }
  57
  58 sub _xdb_release {
  59         my ($self) = @_;
  60         my $xdb = delete $self->{xdb} or croak 'not acquired';
  61         $xdb->close;
  62         _lock_release($self) if $self->{creat};
  63         undef;
  64 }
  65
  66 sub _xdb_acquire {
  67         my ($self) = @_;
  68         croak 'already acquired' if $self->{xdb};
  69         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  70         my $flag = Search::Xapian::DB_OPEN;
  71         if ($self->{creat}) {
  72                 require File::Path;
  73                 _lock_acquire($self);
  74                 File::Path::mkpath($dir);
  75                 $self->{batch_size} = 100;
  76                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  77         }
  78         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  79 }
  80
  81 # we only acquire the flock if creating or reindexing;
  82 # PublicInbox::Import already has the lock on its own.
  83 sub _lock_acquire {
  84         my ($self) = @_;
  85         croak 'already locked' if $self->{lockfh};
  86         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  87                 die "failed to open lock $self->{lock_path}: $!\n";
  88         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  89         $self->{lockfh} = $lockfh;
  90 }
  91
  92 sub _lock_release {
  93         my ($self) = @_;
  94         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  95         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  96         close $lockfh or die "close failed: $!\n";
  97 }
  98
  99 sub add_val ($$$) {
 100         my ($doc, $col, $num) = @_;
 101         $num = Search::Xapian::sortable_serialise($num);
 102         $doc->add_value($col, $num);
 103 }
 104
 105 sub add_values ($$$) {
 106         my ($smsg, $bytes, $num) = @_;
 107
 108         my $ts = $smsg->ts;
 109         my $doc = $smsg->{doc};
 110         add_val($doc, &PublicInbox::Search::TS, $ts);
 111
 112         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 113
 114         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 115
 116         add_val($doc, &PublicInbox::Search::LINES,
 117                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 118
 119         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 120         $doc->add_value(&PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 121 }
 122
 123 sub index_users ($$) {
 124         my ($tg, $smsg) = @_;
 125
 126         my $from = $smsg->from;
 127         my $to = $smsg->to;
 128         my $cc = $smsg->cc;
 129
 130         $tg->index_text($from, 1, 'A'); # A - author
 131         $tg->increase_termpos;
 132
 133         $tg->index_text($to, 1, 'XTO') if $to ne '';
 134         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 135         my $tc = join("\t", $to, $cc);
 136         $tg->index_text($tc, 1, 'XTC') if $tc ne '';
 137         my $tcf = join("\t", $tc, $from);
 138         $tg->index_text($tcf, 1, 'XTCF') if $tcf ne '';
 139
 140         $tg->index_text($from);
 141         $tg->increase_termpos;
 142 }
 143
 144 sub add_message {
 145         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 146         my $db = $self->{xdb};
 147
 148         my ($doc_id, $old_tid);
 149         my $mid = mid_clean(mid_mime($mime));
 150         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
 151
 152         eval {
 153                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 154                 my $smsg = $self->lookup_message($mid);
 155                 if ($smsg) {
 156                         # convert a ghost to a regular message
 157                         # it will also clobber any existing regular message
 158                         $doc_id = $smsg->doc_id;
 159                         $old_tid = $smsg->thread_id;
 160                 }
 161                 $smsg = PublicInbox::SearchMsg->new($mime);
 162                 my $doc = $smsg->{doc};
 163                 $doc->add_term(xpfx('mid') . $mid);
 164
 165                 my $subj = $smsg->subject;
 166                 if ($subj ne '') {
 167                         my $path = $self->subject_path($subj);
 168                         $doc->add_term(xpfx('path') . id_compress($path));
 169                 }
 170
 171                 add_values($smsg, $bytes, $num);
 172
 173                 my $tg = $self->term_generator;
 174
 175                 $tg->set_document($doc);
 176                 $tg->index_text($subj, 1, 'S') if $subj;
 177                 $tg->increase_termpos;
 178                 $tg->index_text($subj) if $subj;
 179                 $tg->increase_termpos;
 180
 181                 index_users($tg, $smsg);
 182
 183                 msg_iter($mime, sub {
 184                         my ($part, $depth, @idx) = @{$_[0]};
 185                         my $ct = $part->content_type || $ct_msg;
 186
 187                         # account for filter bugs...
 188                         $ct =~ m!\btext/plain\b!i or return;
 189
 190                         my (@orig, @quot);
 191                         my $body = $part->body;
 192                         $part->body_set('');
 193                         my @lines = split(/\n/, $body);
 194                         while (defined(my $l = shift @lines)) {
 195                                 if ($l =~ /^\s*>/) {
 196                                         push @quot, $l;
 197                                 } else {
 198                                         push @orig, $l;
 199                                 }
 200                         }
 201                         if (@quot) {
 202                                 $tg->index_text(join("\n", @quot), 0);
 203                                 @quot = ();
 204                                 $tg->increase_termpos;
 205                         }
 206                         if (@orig) {
 207                                 $tg->index_text(join("\n", @orig));
 208                                 @orig = ();
 209                                 $tg->increase_termpos;
 210                         }
 211                 });
 212
 213                 link_message($self, $smsg, $old_tid);
 214                 $tg->index_text($mid, 1);
 215                 $doc->set_data($smsg->to_doc_data($blob));
 216
 217                 if (my $altid = $self->{-altid}) {
 218                         foreach my $alt (@$altid) {
 219                                 my $id = $alt->mid2alt($mid);
 220                                 next unless defined $id;
 221                                 $doc->add_term($alt->{xprefix} . $id);
 222                         }
 223                 }
 224                 if (defined $doc_id) {
 225                         $db->replace_document($doc_id, $doc);
 226                 } else {
 227                         $doc_id = $db->add_document($doc);
 228                 }
 229         };
 230
 231         if ($@) {
 232                 warn "failed to index message <$mid>: $@\n";
 233                 return undef;
 234         }
 235         $doc_id;
 236 }
 237
 238 # returns deleted doc_id on success, undef on missing
 239 sub remove_message {
 240         my ($self, $mid) = @_;
 241         my $db = $self->{xdb};
 242         my $doc_id;
 243         $mid = mid_clean($mid);
 244
 245         eval {
 246                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 247                 $db->delete_document($doc_id) if defined $doc_id;
 248         };
 249
 250         if ($@) {
 251                 warn "failed to remove message <$mid>: $@\n";
 252                 return undef;
 253         }
 254         $doc_id;
 255 }
 256
 257 sub term_generator { # write-only
 258         my ($self) = @_;
 259
 260         my $tg = $self->{term_generator};
 261         return $tg if $tg;
 262
 263         $tg = Search::Xapian::TermGenerator->new;
 264         $tg->set_stemmer($self->stemmer);
 265
 266         $self->{term_generator} = $tg;
 267 }
 268
 269 # increments last_thread_id counter
 270 # returns a 64-bit integer represented as a hex string
 271 sub next_thread_id {
 272         my ($self) = @_;
 273         my $db = $self->{xdb};
 274         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 275
 276         $db->set_metadata('last_thread_id', ++$last_thread_id);
 277
 278         $last_thread_id;
 279 }
 280
 281 sub link_message {
 282         my ($self, $smsg, $old_tid) = @_;
 283         my $doc = $smsg->{doc};
 284         my $mid = $smsg->mid;
 285         my $mime = $smsg->mime;
 286         my $hdr = $mime->header_obj;
 287         my $refs = $hdr->header_raw('References');
 288         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 289         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 290                 # last References should be $irt
 291                 # we will de-dupe later
 292                 push @refs, mid_clean($irt);
 293         }
 294
 295         my $tid;
 296         if (@refs) {
 297                 my %uniq = ($mid => 1);
 298                 my @orig_refs = @refs;
 299                 @refs = ();
 300
 301                 # prevent circular references via References: here:
 302                 foreach my $ref (@orig_refs) {
 303                         if (length($ref) > MAX_MID_SIZE) {
 304                                 warn "References: <$ref> too long, ignoring\n";
 305                         }
 306                         next if $uniq{$ref};
 307                         $uniq{$ref} = 1;
 308                         push @refs, $ref;
 309                 }
 310         }
 311         if (@refs) {
 312                 $smsg->{references} = '<'.join('> <', @refs).'>';
 313
 314                 # first ref *should* be the thread root,
 315                 # but we can never trust clients to do the right thing
 316                 my $ref = shift @refs;
 317                 $tid = $self->_resolve_mid_to_tid($ref);
 318                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 319
 320                 # the rest of the refs should point to this tid:
 321                 foreach $ref (@refs) {
 322                         my $ptid = $self->_resolve_mid_to_tid($ref);
 323                         merge_threads($self, $tid, $ptid);
 324                 }
 325         } else {
 326                 $tid = $self->next_thread_id;
 327         }
 328         $doc->add_term(xpfx('thread') . $tid);
 329 }
 330
 331 sub index_blob {
 332         my ($self, $mime, $bytes, $num, $blob) = @_;
 333         $self->add_message($mime, $bytes, $num, $blob);
 334 }
 335
 336 sub unindex_blob {
 337         my ($self, $mime) = @_;
 338         my $mid = eval { mid_clean(mid_mime($mime)) };
 339         $self->remove_message($mid) if defined $mid;
 340 }
 341
 342 sub index_mm {
 343         my ($self, $mime) = @_;
 344         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 345 }
 346
 347 sub unindex_mm {
 348         my ($self, $mime) = @_;
 349         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 350 }
 351
 352 sub index_mm2 {
 353         my ($self, $mime, $bytes, $blob) = @_;
 354         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 355         index_blob($self, $mime, $bytes, $num, $blob);
 356 }
 357
 358 sub unindex_mm2 {
 359         my ($self, $mime) = @_;
 360         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 361         unindex_blob($self, $mime);
 362 }
 363
 364 sub index_both {
 365         my ($self, $mime, $bytes, $blob) = @_;
 366         my $num = index_mm($self, $mime);
 367         index_blob($self, $mime, $bytes, $num, $blob);
 368 }
 369
 370 sub unindex_both {
 371         my ($self, $mime) = @_;
 372         unindex_blob($self, $mime);
 373         unindex_mm($self, $mime);
 374 }
 375
 376 sub do_cat_mail {
 377         my ($git, $blob, $sizeref) = @_;
 378         my $mime = eval {
 379                 my $str = $git->cat_file($blob, $sizeref);
 380                 # fixup bugs from import:
 381                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 382                 Email::MIME->new($str);
 383         };
 384         $@ ? undef : $mime;
 385 }
 386
 387 sub index_sync {
 388         my ($self, $opts) = @_;
 389         with_umask($self, sub { $self->_index_sync($opts) });
 390 }
 391
 392 sub rlog {
 393         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 394         my $hex = '[a-f0-9]';
 395         my $h40 = $hex .'{40}';
 396         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 397         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 398         my $git = $self->{git};
 399         my $latest;
 400         my $bytes;
 401         my $max = $self->{batch_size}; # may be undef
 402         local $/ = "\n";
 403         my $line;
 404         while (defined($line = <$log>)) {
 405                 if ($line =~ /$addmsg/o) {
 406                         my $blob = $1;
 407                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 408                         $add_cb->($self, $mime, $bytes, $blob);
 409                 } elsif ($line =~ /$delmsg/o) {
 410                         my $blob = $1;
 411                         my $mime = do_cat_mail($git, $blob) or next;
 412                         $del_cb->($self, $mime);
 413                 } elsif ($line =~ /^commit ($h40)/o) {
 414                         if (defined $max && --$max <= 0) {
 415                                 $max = $self->{batch_size};
 416                                 $batch_cb->($latest, 1);
 417                         }
 418                         $latest = $1;
 419                 }
 420         }
 421         $batch_cb->($latest, 0);
 422 }
 423
 424 sub _msgmap_init {
 425         my ($self) = @_;
 426         $self->{mm} = eval {
 427                 require PublicInbox::Msgmap;
 428                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 429         };
 430 }
 431
 432 sub _git_log {
 433         my ($self, $range) = @_;
 434         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 435                                 --raw -r --no-abbrev/, $range);
 436 }
 437
 438 # indexes all unindexed messages
 439 sub _index_sync {
 440         my ($self, $opts) = @_;
 441         my $tip = $opts->{ref} || 'HEAD';
 442         my $reindex = $opts->{reindex};
 443         my ($mkey, $last_commit, $lx, $xlog);
 444         $self->{git}->batch_prepare;
 445         my $xdb = _xdb_acquire($self);
 446         $xdb->begin_transaction;
 447         do {
 448                 $xlog = undef;
 449                 $mkey = 'last_commit';
 450                 $last_commit = $xdb->get_metadata('last_commit');
 451                 $lx = $last_commit;
 452                 if ($reindex) {
 453                         $lx = '';
 454                         $mkey = undef if $last_commit ne '';
 455                 }
 456                 $xdb->cancel_transaction;
 457                 $xdb = _xdb_release($self);
 458
 459                 # ensure we leak no FDs to "git log"
 460                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 461                 $xlog = _git_log($self, $range);
 462
 463                 $xdb = _xdb_acquire($self);
 464                 $xdb->begin_transaction;
 465         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 466
 467         my $mm = _msgmap_init($self);
 468         my $dbh = $mm->{dbh} if $mm;
 469         my $mm_only;
 470         my $cb = sub {
 471                 my ($commit, $more) = @_;
 472                 if ($dbh) {
 473                         $mm->last_commit($commit) if $commit;
 474                         $dbh->commit;
 475                 }
 476                 if (!$mm_only) {
 477                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 478                         $xdb->commit_transaction;
 479                         $xdb = _xdb_release($self);
 480                 }
 481                 # let another process do some work... <
 482                 if ($more) {
 483                         if (!$mm_only) {
 484                                 $xdb = _xdb_acquire($self);
 485                                 $xdb->begin_transaction;
 486                         }
 487                         $dbh->begin_work if $dbh;
 488                 }
 489         };
 490
 491         if ($mm) {
 492                 $dbh->begin_work;
 493                 my $lm = $mm->last_commit || '';
 494                 if ($lm eq $lx) {
 495                         # Common case is the indexes are synced,
 496                         # we only need to run git-log once:
 497                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 498                 } else {
 499                         # Uncommon case, msgmap and xapian are out-of-sync
 500                         # do not care for performance (but git is fast :>)
 501                         # This happens if we have to reindex Xapian since
 502                         # msgmap is a frozen format and our Xapian format
 503                         # is evolving.
 504                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 505
 506                         # first, ensure msgmap is up-to-date:
 507                         my $mkey_prev = $mkey;
 508                         $mkey = undef; # ignore xapian, for now
 509                         my $mlog = _git_log($self, $r);
 510                         $mm_only = 1;
 511                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 512                         $mm_only = $mlog = undef;
 513
 514                         # now deal with Xapian
 515                         $mkey = $mkey_prev;
 516                         $dbh = undef;
 517                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 518                 }
 519         } else {
 520                 # user didn't install DBD::SQLite and DBI
 521                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 522         }
 523 }
 524
 525 # this will create a ghost as necessary
 526 sub _resolve_mid_to_tid {
 527         my ($self, $mid) = @_;
 528
 529         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 530         $smsg->thread_id;
 531 }
 532
 533 sub create_ghost {
 534         my ($self, $mid) = @_;
 535
 536         my $tid = $self->next_thread_id;
 537         my $doc = Search::Xapian::Document->new;
 538         $doc->add_term(xpfx('mid') . $mid);
 539         $doc->add_term(xpfx('thread') . $tid);
 540         $doc->add_term(xpfx('type') . 'ghost');
 541
 542         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 543         $self->{xdb}->add_document($doc);
 544
 545         $smsg;
 546 }
 547
 548 sub merge_threads {
 549         my ($self, $winner_tid, $loser_tid) = @_;
 550         return if $winner_tid == $loser_tid;
 551         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 552         my $thread_pfx = xpfx('thread');
 553         my $db = $self->{xdb};
 554
 555         for (; $head != $tail; $head->inc) {
 556                 my $docid = $head->get_docid;
 557                 my $doc = $db->get_document($docid);
 558                 $doc->remove_term($thread_pfx . $loser_tid);
 559                 $doc->add_term($thread_pfx . $winner_tid);
 560                 $db->replace_document($docid, $doc);
 561         }
 562 }
 563
 564 sub _read_git_config_perm {
 565         my ($self) = @_;
 566         my @cmd = qw(config core.sharedRepository);
 567         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 568         local $/ = "\n";
 569         my $perm = <$fh>;
 570         chomp $perm if defined $perm;
 571         $perm;
 572 }
 573
 574 sub _git_config_perm {
 575         my $self = shift;
 576         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 577         return PERM_GROUP if (!defined($perm) || $perm eq '');
 578         return PERM_UMASK if ($perm eq 'umask');
 579         return PERM_GROUP if ($perm eq 'group');
 580         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 581                 return PERM_EVERYBODY;
 582         }
 583         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 584         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 585
 586         my $i = oct($perm);
 587         return PERM_UMASK if ($i == PERM_UMASK);
 588         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 589         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 590
 591         if (($i & 0600) != 0600) {
 592                 die "core.sharedRepository mode invalid: ".
 593                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 594         }
 595         ($i & 0666);
 596 }
 597
 598 sub _umask_for {
 599         my ($perm) = @_; # _git_config_perm return value
 600         my $rv = $perm;
 601         return umask if $rv == 0;
 602
 603         # set +x bit if +r or +w were set
 604         $rv |= 0100 if ($rv & 0600);
 605         $rv |= 0010 if ($rv & 0060);
 606         $rv |= 0001 if ($rv & 0006);
 607         (~$rv & 0777);
 608 }
 609
 610 sub with_umask {
 611         my ($self, $cb) = @_;
 612         my $old = umask $self->{umask};
 613         my $rv = eval { $cb->() };
 614         my $err = $@;
 615         umask $old;
 616         die $err if $@;
 617         $rv;
 618 }
 619
 620 sub DESTROY {
 621         # order matters for unlocking
 622         $_[0]->{xdb} = undef;
 623         $_[0]->{lockfh} = undef;
 624 }
 625
 626 1;