lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size);
  26 my $X = \%PublicInbox::Search::X;
  27 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  28 our $DB_NO_SYNC = 0;
  29 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  36
  37 sub new {
  38         my ($class, $ibx, $creat, $shard) = @_;
  39         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         if ($ibx->{-skip_docdata}) {
  66                 $self->{-set_skip_docdata_once} = 1;
  67                 $self->{-skip_docdata} = 1;
  68         }
  69         $ibx->umask_prepare;
  70         if ($version == 1) {
  71                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  72                 my $dir = $self->xdir;
  73                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  74                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  75         } elsif ($version == 2) {
  76                 defined $shard or die "shard is required for v2\n";
  77                 # shard is a number
  78                 $self->{shard} = $shard;
  79                 $self->{lock_path} = undef;
  80         } else {
  81                 die "unsupported inbox version=$version\n";
  82         }
  83         $self->{creat} = ($creat || 0) == 1;
  84         $self;
  85 }
  86
  87 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  88
  89 sub idx_release {
  90         my ($self, $wake) = @_;
  91         if (need_xapian($self)) {
  92                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  93                 $xdb->close;
  94         }
  95         $self->lock_release($wake) if $self->{creat};
  96         undef;
  97 }
  98
  99 sub load_xapian_writable () {
 100         return 1 if $X->{WritableDatabase};
 101         PublicInbox::Search::load_xapian() or return;
 102         my $xap = $PublicInbox::Search::Xap;
 103         for (qw(Document TermGenerator WritableDatabase)) {
 104                 $X->{$_} = $xap.'::'.$_;
 105         }
 106         eval 'require '.$X->{WritableDatabase} or die;
 107         *sortable_serialise = $xap.'::sortable_serialise';
 108         *sortable_unserialise = $xap.'::sortable_unserialise';
 109         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 110         $DB_OPEN = eval($xap.'::DB_OPEN()');
 111         my $ver = (eval($xap.'::major_version()') << 16) |
 112                 (eval($xap.'::minor_version()') << 8);
 113         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 114         1;
 115 }
 116
 117 sub idx_acquire {
 118         my ($self) = @_;
 119         my $flag;
 120         my $dir = $self->xdir;
 121         if (need_xapian($self)) {
 122                 croak 'already acquired' if $self->{xdb};
 123                 load_xapian_writable();
 124                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 125         }
 126         if ($self->{creat}) {
 127                 require File::Path;
 128                 $self->lock_acquire;
 129
 130                 # don't create empty Xapian directories if we don't need Xapian
 131                 my $is_shard = defined($self->{shard});
 132                 if (!-d $dir && (!$is_shard ||
 133                                 ($is_shard && need_xapian($self)))) {
 134                         File::Path::mkpath($dir);
 135                         nodatacow_dir($dir);
 136                         $self->{-set_has_threadid_once} = 1;
 137                 }
 138         }
 139         return unless defined $flag;
 140         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_fsync};
 141         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 142         croak "Failed opening $dir: $@" if $@;
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_list_id ($$$) {
 329         my ($self, $doc, $hdr) = @_;
 330         for my $l ($hdr->header_raw('List-Id')) {
 331                 $l =~ /<([^>]+)>/ or next;
 332                 my $lid = lc $1;
 333                 $doc->add_boolean_term('G' . $lid);
 334                 index_text($self, $lid, 1, 'XL'); # probabilistic
 335         }
 336 }
 337
 338 sub index_ids ($$$$) {
 339         my ($self, $doc, $hdr, $mids) = @_;
 340         for my $mid (@$mids) {
 341                 index_text($self, $mid, 1, 'XM');
 342
 343                 # because too many Message-IDs are prefixed with
 344                 # "Pine.LNX."...
 345                 if ($mid =~ /\w{12,}/) {
 346                         my @long = ($mid =~ /(\w{3,}+)/g);
 347                         index_text($self, join(' ', @long), 1, 'XM');
 348                 }
 349         }
 350         $doc->add_boolean_term('Q' . $_) for @$mids;
 351         index_list_id($self, $doc, $hdr);
 352 }
 353
 354 sub add_xapian ($$$$) {
 355         my ($self, $eml, $smsg, $mids) = @_;
 356         my $doc = $X->{Document}->new;
 357         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 358         my @ds = gmtime($smsg->{ds});
 359         my $yyyymmdd = strftime('%Y%m%d', @ds);
 360         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 361         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 362         add_val($doc, PublicInbox::Search::DT(), $dt);
 363         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 364         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 365         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 366
 367         my $tg = term_generator($self);
 368         $tg->set_document($doc);
 369         index_headers($self, $smsg);
 370
 371         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 372                 $doc->add_boolean_term('O'.$eidx_key);
 373                 $doc->add_boolean_term('P'.
 374                                 "$eidx_key:$smsg->{num}:$smsg->{blob}");
 375         }
 376         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 377         index_ids($self, $doc, $eml, $mids);
 378
 379         # by default, we maintain compatibility with v1.5.0 and earlier
 380         # by writing to docdata.glass, users who never exect to downgrade can
 381         # use --skip-docdata
 382         if (!$self->{-skip_docdata}) {
 383                 # WWW doesn't need {to} or {cc}, only NNTP
 384                 $smsg->{to} = $smsg->{cc} = '';
 385                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 386                 my $data = $smsg->to_doc_data;
 387                 $doc->set_data($data);
 388         }
 389
 390         if (my $altid = $self->{-altid}) {
 391                 foreach my $alt (@$altid) {
 392                         my $pfx = $alt->{xprefix};
 393                         foreach my $mid (@$mids) {
 394                                 my $id = $alt->mid2alt($mid);
 395                                 next unless defined $id;
 396                                 $doc->add_boolean_term($pfx . $id);
 397                         }
 398                 }
 399         }
 400         $self->{xdb}->replace_document($smsg->{num}, $doc);
 401 }
 402
 403 sub _msgmap_init ($) {
 404         my ($self) = @_;
 405         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 406         $self->{mm} //= eval {
 407                 require PublicInbox::Msgmap;
 408                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 409                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 410         };
 411 }
 412
 413 sub add_message {
 414         # mime = PublicInbox::Eml or Email::MIME object
 415         my ($self, $mime, $smsg, $sync) = @_;
 416         my $mids = mids_for_index($mime);
 417         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 418         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 419         $smsg->{num} //= do { # v1
 420                 _msgmap_init($self);
 421                 index_mm($self, $mime, $smsg->{blob}, $sync);
 422         };
 423
 424         # v1 and tests only:
 425         $smsg->populate($mime, $sync);
 426         $smsg->{bytes} //= length($mime->as_string);
 427
 428         eval {
 429                 # order matters, overview stores every possible piece of
 430                 # data in doc_data (deflated).  Xapian only stores a subset
 431                 # of the fields which exist in over.sqlite3.  We may stop
 432                 # storing doc_data in Xapian sometime after we get multi-inbox
 433                 # search working.
 434                 if (my $oidx = $self->{oidx}) { # v1 only
 435                         $oidx->add_overview($mime, $smsg);
 436                 }
 437                 if (need_xapian($self)) {
 438                         add_xapian($self, $mime, $smsg, $mids);
 439                 }
 440         };
 441
 442         if ($@) {
 443                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 444                 return undef;
 445         }
 446         $smsg->{num};
 447 }
 448
 449 sub _get_doc ($$$) {
 450         my ($self, $docid, $oid) = @_;
 451         my $doc = eval { $self->{xdb}->get_document($docid) };
 452         $doc // do {
 453                 warn "E: $@\n" if $@;
 454                 warn "E: #$docid $oid missing in Xapian\n";
 455                 undef;
 456         }
 457 }
 458
 459 sub add_xref3 {
 460         my ($self, $docid, $xnum, $oid, $eidx_key, $eml) = @_;
 461         begin_txn_lazy($self);
 462         my $doc = _get_doc($self, $docid, $oid) or return;
 463         term_generator($self)->set_document($doc);
 464         $doc->add_boolean_term('O'.$eidx_key);
 465         $doc->add_boolean_term('P'."$eidx_key:$xnum:$oid");
 466         index_list_id($self, $doc, $eml);
 467         $self->{xdb}->replace_document($docid, $doc);
 468 }
 469
 470 sub remove_xref3 {
 471         my ($self, $docid, $oid, $eidx_key, $eml) = @_;
 472         begin_txn_lazy($self);
 473         my $doc = _get_doc($self, $docid, $oid) or return;
 474         my $xref3 = PublicInbox::Smsg::xref3(undef, $doc);
 475         for (grep(/\A\Q$eidx_key\E:[0-9]+:\Q$oid\E\z/, @$xref3)) {
 476                 $doc->remove_term('P' . $_);
 477         }
 478         for my $l ($eml->header_raw('List-Id')) {
 479                 $l =~ /<([^>]+)>/ or next;
 480                 my $lid = lc $1;
 481                 $doc->remove_term('G' . $lid);
 482
 483                 # nb: we don't remove the XL probabilistic terms
 484                 # since terms may overlap if cross-posted.
 485                 #
 486                 # IOW, a message which has both <foo.example.com>
 487                 # and <bar.example.com> would have overlapping
 488                 # "XLexample" and "XLcom" as terms and which we
 489                 # wouldn't know if they're safe to remove if we just
 490                 # unindex <foo.example.com> while preserving
 491                 # <bar.example.com>.
 492                 #
 493                 # In any case, this entire sub is will likely never
 494                 # be needed and users using the "l:" prefix are probably
 495                 # rarer.
 496         }
 497         $self->{xdb}->replace_document($docid, $doc);
 498 }
 499
 500 sub get_val ($$) {
 501         my ($doc, $col) = @_;
 502         sortable_unserialise($doc->get_value($col));
 503 }
 504
 505 sub smsg_from_doc ($) {
 506         my ($doc) = @_;
 507         my $data = $doc->get_data or return;
 508         my $smsg = bless {}, 'PublicInbox::Smsg';
 509         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 510         my $dt = get_val($doc, PublicInbox::Search::DT());
 511         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 512         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 513         $smsg->load_from_data($data);
 514         $smsg;
 515 }
 516
 517 sub xdb_remove {
 518         my ($self, $oid, @removed) = @_;
 519         my $xdb = $self->{xdb} or return;
 520         for my $num (@removed) {
 521                 my $doc = _get_doc($self, $num, $oid) or next;
 522                 my $smsg = smsg_from_doc($doc);
 523                 my $blob = $smsg->{blob}; # may be undef if --skip-docdata
 524                 if (!defined($blob) || $blob eq $oid) {
 525                         $xdb->delete_document($num);
 526                 } else {
 527                         warn "E: #$num $oid != $blob in Xapian\n";
 528                 }
 529         }
 530 }
 531
 532 sub remove_by_oid {
 533         my ($self, $oid, $num) = @_;
 534         die "BUG: remove_by_oid is v2-only\n" if $self->{oidx};
 535         $self->begin_txn_lazy;
 536         xdb_remove($self, $oid, $num) if need_xapian($self);
 537 }
 538
 539 sub index_git_blob_id {
 540         my ($doc, $pfx, $objid) = @_;
 541
 542         my $len = length($objid);
 543         for (my $len = length($objid); $len >= 7; ) {
 544                 $doc->add_term($pfx.$objid);
 545                 $objid = substr($objid, 0, --$len);
 546         }
 547 }
 548
 549 # v1 only
 550 sub unindex_eml {
 551         my ($self, $oid, $eml) = @_;
 552         my $mids = mids($eml);
 553         my $nr = 0;
 554         my %tmp;
 555         for my $mid (@$mids) {
 556                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 557                 $nr += scalar @removed;
 558                 $tmp{$_}++ for @removed;
 559         }
 560         if (!$nr) {
 561                 $mids = join('> <', @$mids);
 562                 warn "W: <$mids> missing for removal from overview\n";
 563         }
 564         while (my ($num, $nr) = each %tmp) {
 565                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 566         }
 567         if ($nr) {
 568                 $self->{mm}->num_delete($_) for (keys %tmp);
 569         } else { # just in case msgmap and over.sqlite3 become desynched:
 570                 $self->{mm}->mid_delete($mids->[0]);
 571         }
 572         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 573 }
 574
 575 sub index_mm {
 576         my ($self, $mime, $oid, $sync) = @_;
 577         my $mids = mids($mime);
 578         my $mm = $self->{mm};
 579         if ($sync->{reindex}) {
 580                 my $oidx = $self->{oidx};
 581                 for my $mid (@$mids) {
 582                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 583                         return $num if defined $num;
 584                 }
 585                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 586         } else {
 587                 # fallback to num_for since filters like RubyLang set the number
 588                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 589         }
 590 }
 591
 592 # returns the number of bytes to add if given a non-CRLF arg
 593 sub crlf_adjust ($) {
 594         if (index($_[0], "\r\n") < 0) {
 595                 # common case is LF-only, every \n needs an \r;
 596                 # so favor a cheap tr// over an expensive m//g
 597                 $_[0] =~ tr/\n/\n/;
 598         } else { # count number of '\n' w/o '\r', expensive:
 599                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 600         }
 601 }
 602
 603 sub index_both { # git->cat_async callback
 604         my ($bref, $oid, $type, $size, $sync) = @_;
 605         my ($nr, $max) = @$sync{qw(nr max)};
 606         ++$$nr;
 607         $$max -= $size;
 608         $size += crlf_adjust($$bref);
 609         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 610         my $self = $sync->{sidx};
 611         my $eml = PublicInbox::Eml->new($bref);
 612         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 613                 die "E: could not generate NNTP article number for $oid";
 614         add_message($self, $eml, $smsg, $sync);
 615 }
 616
 617 sub unindex_both { # git->cat_async callback
 618         my ($bref, $oid, $type, $size, $self) = @_;
 619         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 620 }
 621
 622 # called by public-inbox-index
 623 sub index_sync {
 624         my ($self, $opt) = @_;
 625         delete $self->{lock_path} if $opt->{-skip_lock};
 626         $self->{ibx}->with_umask(\&_index_sync, $self, $opt);
 627         if ($opt->{reindex}) {
 628                 my %again = %$opt;
 629                 delete @again{qw(rethread reindex)};
 630                 index_sync($self, \%again);
 631         }
 632 }
 633
 634 sub check_size { # check_async cb for -index --max-size=...
 635         my ($oid, $type, $size, $arg, $git) = @_;
 636         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 637         if ($size <= $arg->{max_size}) {
 638                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 639         } else {
 640                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 641         }
 642 }
 643
 644 sub v1_checkpoint ($$;$) {
 645         my ($self, $sync, $stk) = @_;
 646         $self->{ibx}->git->async_wait_all;
 647
 648         # latest_cmt may be undef
 649         my $newest = $stk ? $stk->{latest_cmt} : undef;
 650         if ($newest) {
 651                 my $cur = $self->{mm}->last_commit || '';
 652                 if (need_update($self, $cur, $newest)) {
 653                         $self->{mm}->last_commit($newest);
 654                 }
 655         } else {
 656                 ${$sync->{max}} = $self->{batch_bytes};
 657         }
 658
 659         $self->{mm}->{dbh}->commit;
 660         if ($newest && need_xapian($self)) {
 661                 my $xdb = $self->{xdb};
 662                 my $cur = $xdb->get_metadata('last_commit');
 663                 if (need_update($self, $cur, $newest)) {
 664                         $xdb->set_metadata('last_commit', $newest);
 665                 }
 666
 667                 # let SearchView know a full --reindex was done so it can
 668                 # generate ->has_threadid-dependent links
 669                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 670                         my $n = $xdb->get_metadata('has_threadid');
 671                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 672                 }
 673         }
 674
 675         $self->{oidx}->rethread_done($sync->{-opt}) if $newest; # all done
 676         commit_txn_lazy($self);
 677         $self->{ibx}->git->cleanup;
 678         my $nr = ${$sync->{nr}};
 679         idx_release($self, $nr);
 680         # let another process do some work...
 681         if (my $pr = $sync->{-opt}->{-progress}) {
 682                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 683         }
 684         if (!$stk) { # more to come
 685                 begin_txn_lazy($self);
 686                 $self->{mm}->{dbh}->begin_work;
 687         }
 688 }
 689
 690 # only for v1
 691 sub process_stack {
 692         my ($self, $sync, $stk) = @_;
 693         my $git = $self->{ibx}->git;
 694         my $max = $self->{batch_bytes};
 695         my $nr = 0;
 696         $sync->{nr} = \$nr;
 697         $sync->{max} = \$max;
 698         $sync->{sidx} = $self;
 699
 700         $self->{mm}->{dbh}->begin_work;
 701         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 702                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 703                 for my $oid (@leftovers) {
 704                         $oid = unpack('H*', $oid);
 705                         $git->cat_async($oid, \&unindex_both, $self);
 706                 }
 707         }
 708         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 709                 $sync->{index_oid} = \&index_both;
 710         }
 711         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 712                 if ($f eq 'm') {
 713                         my $arg = { %$sync, autime => $at, cotime => $ct };
 714                         if ($sync->{max_size}) {
 715                                 $git->check_async($oid, \&check_size, $arg);
 716                         } else {
 717                                 $git->cat_async($oid, \&index_both, $arg);
 718                         }
 719                         v1_checkpoint($self, $sync) if $max <= 0;
 720                 } elsif ($f eq 'd') {
 721                         $git->cat_async($oid, \&unindex_both, $self);
 722                 }
 723         }
 724         v1_checkpoint($self, $sync, $stk);
 725 }
 726
 727 sub log2stack ($$$$) {
 728         my ($sync, $git, $range, $ibx) = @_;
 729         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 730         my ($add, $del);
 731         if ($ibx->version == 1) {
 732                 my $path = $hex.'{2}/'.$hex.'{38}';
 733                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 734                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 735         } else {
 736                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 737                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 738         }
 739
 740         # Count the new files so they can be added newest to oldest
 741         # and still have numbers increasing from oldest to newest
 742         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 743                                 --no-notes --no-color --no-renames --no-abbrev),
 744                                 $range);
 745         my ($at, $ct, $stk);
 746         while (<$fh>) {
 747                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 748                         ($at, $ct) = ($1 + 0, $2 + 0);
 749                         $stk //= PublicInbox::IdxStack->new($3);
 750                 } elsif (/$del/) {
 751                         my $oid = $1;
 752                         if ($D) { # reindex case
 753                                 $D->{pack('H*', $oid)}++;
 754                         } else { # non-reindex case:
 755                                 $stk->push_rec('d', $at, $ct, $oid);
 756                         }
 757                 } elsif (/$add/) {
 758                         my $oid = $1;
 759                         if ($D) {
 760                                 my $oid_bin = pack('H*', $oid);
 761                                 my $nr = --$D->{$oid_bin};
 762                                 delete($D->{$oid_bin}) if $nr <= 0;
 763
 764                                 # nr < 0 (-1) means it never existed
 765                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 766                         } else {
 767                                 $stk->push_rec('m', $at, $ct, $oid);
 768                         }
 769                 }
 770         }
 771         close $fh or die "git log failed: \$?=$?";
 772         $stk //= PublicInbox::IdxStack->new;
 773         $stk->read_prepare;
 774 }
 775
 776 sub prepare_stack ($$$) {
 777         my ($self, $sync, $range) = @_;
 778         my $git = $self->{ibx}->git;
 779
 780         if (index($range, '..') < 0) {
 781                 # don't show annoying git errors to users who run -index
 782                 # on empty inboxes
 783                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 784                 return PublicInbox::IdxStack->new->read_prepare if $?;
 785         }
 786         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 787         log2stack($sync, $git, $range, $self->{ibx});
 788 }
 789
 790 # --is-ancestor requires git 1.8.0+
 791 sub is_ancestor ($$$) {
 792         my ($git, $cur, $tip) = @_;
 793         return 0 unless $git->check($cur);
 794         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 795                 qw(merge-base --is-ancestor), $cur, $tip ];
 796         my $pid = spawn($cmd);
 797         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 798         $? == 0;
 799 }
 800
 801 sub need_update ($$$) {
 802         my ($self, $cur, $new) = @_;
 803         my $git = $self->{ibx}->git;
 804         return 1 if $cur && !is_ancestor($git, $cur, $new);
 805         my $range = $cur eq '' ? $new : "$cur..$new";
 806         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 807         ($n eq '' || $n > 0);
 808 }
 809
 810 # The last git commit we indexed with Xapian or SQLite (msgmap)
 811 # This needs to account for cases where Xapian or SQLite is
 812 # out-of-date with respect to the other.
 813 sub _last_x_commit {
 814         my ($self, $mm) = @_;
 815         my $lm = $mm->last_commit || '';
 816         my $lx = '';
 817         if (need_xapian($self)) {
 818                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 819         } else {
 820                 $lx = $lm;
 821         }
 822         # Use last_commit from msgmap if it is older or unset
 823         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 824                 $lx = $lm;
 825         }
 826         $lx;
 827 }
 828
 829 sub reindex_from ($$) {
 830         my ($reindex, $last_commit) = @_;
 831         return $last_commit unless $reindex;
 832         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 833 }
 834
 835 # indexes all unindexed messages (v1 only)
 836 sub _index_sync {
 837         my ($self, $opt) = @_;
 838         my $tip = $opt->{ref} || 'HEAD';
 839         my $git = $self->{ibx}->git;
 840         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 841         $git->batch_prepare;
 842         my $pr = $opt->{-progress};
 843         my $sync = { reindex => $opt->{reindex}, -opt => $opt };
 844         my $xdb = $self->begin_txn_lazy;
 845         $self->{oidx}->rethread_prepare($opt);
 846         my $mm = _msgmap_init($self);
 847         if ($sync->{reindex}) {
 848                 my $last = $mm->last_commit;
 849                 if ($last) {
 850                         $tip = $last;
 851                 } else {
 852                         # somebody just blindly added --reindex when indexing
 853                         # for the first time, allow it:
 854                         undef $sync->{reindex};
 855                 }
 856         }
 857         my $last_commit = _last_x_commit($self, $mm);
 858         my $lx = reindex_from($sync->{reindex}, $last_commit);
 859         my $range = $lx eq '' ? $tip : "$lx..$tip";
 860         $pr->("counting changes\n\t$range ... ") if $pr;
 861         my $stk = prepare_stack($self, $sync, $range);
 862         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 863         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 864         process_stack($self, $sync, $stk);
 865 }
 866
 867 sub DESTROY {
 868         # order matters for unlocking
 869         $_[0]->{xdb} = undef;
 870         $_[0]->{lockfh} = undef;
 871 }
 872
 873 sub _begin_txn {
 874         my ($self) = @_;
 875         my $xdb = $self->{xdb} || idx_acquire($self);
 876         $self->{oidx}->begin_lazy if $self->{oidx};
 877         $xdb->begin_transaction if $xdb;
 878         $self->{txn} = 1;
 879         $xdb;
 880 }
 881
 882 sub begin_txn_lazy {
 883         my ($self) = @_;
 884         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 885 }
 886
 887 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 888 # This metadata is read by Admin::detect_indexlevel:
 889 sub set_metadata_once {
 890         my ($self) = @_;
 891
 892         return if $self->{shard}; # only continue if undef or 0, not >0
 893         my $xdb = $self->{xdb};
 894
 895         if (delete($self->{-set_has_threadid_once})) {
 896                 $xdb->set_metadata('has_threadid', '1');
 897         }
 898         if (delete($self->{-set_indexlevel_once})) {
 899                 my $level = $xdb->get_metadata('indexlevel');
 900                 if (!$level || $level ne 'medium') {
 901                         $xdb->set_metadata('indexlevel', 'medium');
 902                 }
 903         }
 904         if (delete($self->{-set_skip_docdata_once})) {
 905                 $xdb->get_metadata('skip_docdata') or
 906                         $xdb->set_metadata('skip_docdata', '1');
 907         }
 908 }
 909
 910 sub _commit_txn {
 911         my ($self) = @_;
 912         if (my $xdb = $self->{xdb}) {
 913                 set_metadata_once($self);
 914                 $xdb->commit_transaction;
 915         }
 916         $self->{oidx}->commit_lazy if $self->{oidx};
 917 }
 918
 919 sub commit_txn_lazy {
 920         my ($self) = @_;
 921         delete($self->{txn}) and
 922                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 923 }
 924
 925 sub worker_done {
 926         my ($self) = @_;
 927         if (need_xapian($self)) {
 928                 die "$$ $0 xdb not released\n" if $self->{xdb};
 929         }
 930         die "$$ $0 still in transaction\n" if $self->{txn};
 931 }
 932
 933 1;