lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak carp);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(log2stack is_ancestor check_size prepare_stack
  26         index_text term_generator add_val is_bad_blob);
  27 my $X = \%PublicInbox::Search::X;
  28 our ($DB_CREATE_OR_OPEN, $DB_OPEN);
  29 our $DB_NO_SYNC = 0;
  30 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  31 use constant DEBUG => !!$ENV{DEBUG};
  32
  33 my $xapianlevels = qr/\A(?:full|medium)\z/;
  34 my $hex = '[a-f0-9]';
  35 my $OID = $hex .'{40,}';
  36 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  37
  38 sub new {
  39         my ($class, $ibx, $creat, $shard) = @_;
  40         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  41         my $inboxdir = $ibx->{inboxdir};
  42         my $version = $ibx->version;
  43         my $indexlevel = 'full';
  44         my $altid = $ibx->{altid};
  45         if ($altid) {
  46                 require PublicInbox::AltId;
  47                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  48         }
  49         if ($ibx->{indexlevel}) {
  50                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  51                         $indexlevel = $ibx->{indexlevel};
  52                 } else {
  53                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  54                 }
  55         }
  56         $ibx = PublicInbox::InboxWritable->new($ibx);
  57         my $self = PublicInbox::Search->new($ibx);
  58         bless $self, $class;
  59         $self->{ibx} = $ibx;
  60         $self->{-altid} = $altid;
  61         $self->{indexlevel} = $indexlevel;
  62         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  63         if ($ibx->{-skip_docdata}) {
  64                 $self->{-set_skip_docdata_once} = 1;
  65                 $self->{-skip_docdata} = 1;
  66         }
  67         if ($version == 1) {
  68                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  69                 my $dir = $self->xdir;
  70                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  71                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  72         } elsif ($version == 2) {
  73                 defined $shard or die "shard is required for v2\n";
  74                 # shard is a number
  75                 $self->{shard} = $shard;
  76                 $self->{lock_path} = undef;
  77         } else {
  78                 die "unsupported inbox version=$version\n";
  79         }
  80         $self->{creat} = ($creat || 0) == 1;
  81         $self;
  82 }
  83
  84 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  85
  86 sub idx_release {
  87         my ($self, $wake) = @_;
  88         if (need_xapian($self)) {
  89                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  90                 $xdb->close;
  91         }
  92         $self->lock_release($wake) if $self->{creat};
  93         undef;
  94 }
  95
  96 sub load_xapian_writable () {
  97         return 1 if $X->{WritableDatabase};
  98         PublicInbox::Search::load_xapian() or return;
  99         my $xap = $PublicInbox::Search::Xap;
 100         for (qw(Document TermGenerator WritableDatabase)) {
 101                 $X->{$_} = $xap.'::'.$_;
 102         }
 103         eval 'require '.$X->{WritableDatabase} or die;
 104         *sortable_serialise = $xap.'::sortable_serialise';
 105         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 106         $DB_OPEN = eval($xap.'::DB_OPEN()');
 107         my $ver = (eval($xap.'::major_version()') << 16) |
 108                 (eval($xap.'::minor_version()') << 8);
 109         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 110         1;
 111 }
 112
 113 sub idx_acquire {
 114         my ($self) = @_;
 115         my $flag;
 116         my $dir = $self->xdir;
 117         if (need_xapian($self)) {
 118                 croak 'already acquired' if $self->{xdb};
 119                 load_xapian_writable();
 120                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 121         }
 122         if ($self->{creat}) {
 123                 require File::Path;
 124                 $self->lock_acquire;
 125
 126                 # don't create empty Xapian directories if we don't need Xapian
 127                 my $is_shard = defined($self->{shard});
 128                 if (!-d $dir && (!$is_shard ||
 129                                 ($is_shard && need_xapian($self)))) {
 130                         File::Path::mkpath($dir);
 131                         nodatacow_dir($dir);
 132                         $self->{-set_has_threadid_once} = 1;
 133                 }
 134         }
 135         return unless defined $flag;
 136         $flag |= $DB_NO_SYNC if ($self->{ibx} // $self->{eidx})->{-no_fsync};
 137         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 138         croak "Failed opening $dir: $@" if $@;
 139         $self->{xdb} = $xdb;
 140 }
 141
 142 sub add_val ($$$) {
 143         my ($doc, $col, $num) = @_;
 144         $num = sortable_serialise($num);
 145         $doc->add_value($col, $num);
 146 }
 147
 148 sub term_generator ($) { # write-only
 149         my ($self) = @_;
 150
 151         $self->{term_generator} //= do {
 152                 my $tg = $X->{TermGenerator}->new;
 153                 $tg->set_stemmer(PublicInbox::Search::stemmer($self));
 154                 $tg;
 155         }
 156 }
 157
 158 sub index_text ($$$$) {
 159         my ($self, $text, $wdf_inc, $prefix) = @_;
 160         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 161
 162         if ($self->{indexlevel} eq 'full') {
 163                 $tg->index_text($text, $wdf_inc, $prefix);
 164                 $tg->increase_termpos;
 165         } else {
 166                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 167         }
 168 }
 169
 170 sub index_headers ($$) {
 171         my ($self, $smsg) = @_;
 172         my @x = (from => 'A', # Author
 173                 subject => 'S', to => 'XTO', cc => 'XCC');
 174         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 175                 my $val = $smsg->{$field};
 176                 index_text($self, $val, 1, $pfx) if $val ne '';
 177         }
 178 }
 179
 180 sub index_diff_inc ($$$$) {
 181         my ($self, $text, $pfx, $xnq) = @_;
 182         if (@$xnq) {
 183                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 184                 @$xnq = ();
 185         }
 186         index_text($self, $text, 1, $pfx);
 187 }
 188
 189 sub index_old_diff_fn {
 190         my ($self, $seen, $fa, $fb, $xnq) = @_;
 191
 192         # no renames or space support for traditional diffs,
 193         # find the number of leading common paths to strip:
 194         my @fa = split('/', $fa);
 195         my @fb = split('/', $fb);
 196         while (scalar(@fa) && scalar(@fb)) {
 197                 $fa = join('/', @fa);
 198                 $fb = join('/', @fb);
 199                 if ($fa eq $fb) {
 200                         unless ($seen->{$fa}++) {
 201                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 202                         }
 203                         return 1;
 204                 }
 205                 shift @fa;
 206                 shift @fb;
 207         }
 208         0;
 209 }
 210
 211 sub index_diff ($$$) {
 212         my ($self, $txt, $doc) = @_;
 213         my %seen;
 214         my $in_diff;
 215         my @xnq;
 216         my $xnq = \@xnq;
 217         foreach (split(/\n/, $txt)) {
 218                 if ($in_diff && s/^ //) { # diff context
 219                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 220                 } elsif (/^-- $/) { # email signature begins
 221                         $in_diff = undef;
 222                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 223                         # wait until "---" and "+++" to capture filenames
 224                         $in_diff = 1;
 225                 # traditional diff:
 226                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 227                         my ($opt, $fa, $fb) = ($1, $2, $3);
 228                         push @xnq, $_;
 229                         # only support unified:
 230                         next unless $opt =~ /[uU]/;
 231                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 232                                                         $xnq);
 233                 } elsif (m!^--- ("?[^/]+/.+)!) {
 234                         my $fn = $1;
 235                         $fn = (split('/', git_unquote($fn), 2))[1];
 236                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 237                         $in_diff = 1;
 238                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 239                         my $fn = $1;
 240                         $fn = (split('/', git_unquote($fn), 2))[1];
 241                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 242                         $in_diff = 1;
 243                 } elsif (/^--- (\S+)/) {
 244                         $in_diff = $1;
 245                         push @xnq, $_;
 246                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 247                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 248                                                         $1, $xnq);
 249                 } elsif ($in_diff && s/^\+//) { # diff added
 250                         index_diff_inc($self, $_, 'XDFB', $xnq);
 251                 } elsif ($in_diff && s/^-//) { # diff removed
 252                         index_diff_inc($self, $_, 'XDFA', $xnq);
 253                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 254                         my ($ba, $bb) = ($1, $2);
 255                         index_git_blob_id($doc, 'XDFPRE', $ba);
 256                         index_git_blob_id($doc, 'XDFPOST', $bb);
 257                         $in_diff = 1;
 258                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 259                         # traditional diff w/o -p
 260                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 261                         # hunk header context
 262                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 263                 # ignore the following lines:
 264                 } elsif (/^(?:dis)similarity index/ ||
 265                                 /^(?:old|new) mode/ ||
 266                                 /^(?:deleted|new) file mode/ ||
 267                                 /^(?:copy|rename) (?:from|to) / ||
 268                                 /^(?:dis)?similarity index / ||
 269                                 /^\\ No newline at end of file/ ||
 270                                 /^Binary files .* differ/) {
 271                         push @xnq, $_;
 272                 } elsif ($_ eq '') {
 273                         # possible to be in diff context, some mail may be
 274                         # stripped by MUA or even GNU diff(1).  "git apply"
 275                         # treats a bare "\n" as diff context, too
 276                 } else {
 277                         push @xnq, $_;
 278                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 279                         $in_diff = undef;
 280                 }
 281         }
 282
 283         index_text($self, join("\n", @xnq), 1, 'XNQ');
 284 }
 285
 286 sub index_xapian { # msg_iter callback
 287         my $part = $_[0]->[0]; # ignore $depth and $idx
 288         my ($self, $doc) = @{$_[1]};
 289         my $ct = $part->content_type || 'text/plain';
 290         my $fn = $part->filename;
 291         if (defined $fn && $fn ne '') {
 292                 index_text($self, $fn, 1, 'XFN');
 293         }
 294         if ($part->{is_submsg}) {
 295                 my $mids = mids_for_index($part);
 296                 index_ids($self, $doc, $part, $mids);
 297                 my $smsg = bless {}, 'PublicInbox::Smsg';
 298                 $smsg->populate($part);
 299                 index_headers($self, $smsg);
 300         }
 301
 302         my ($s, undef) = msg_part_text($part, $ct);
 303         defined $s or return;
 304         $_[0]->[0] = $part = undef; # free memory
 305
 306         # split off quoted and unquoted blocks:
 307         my @sections = PublicInbox::MsgIter::split_quotes($s);
 308         undef $s; # free memory
 309         for my $txt (@sections) {
 310                 if ($txt =~ /\A>/) {
 311                         index_text($self, $txt, 0, 'XQUOT');
 312                 } else {
 313                         # does it look like a diff?
 314                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 315                                 index_diff($self, $txt, $doc);
 316                         } else {
 317                                 index_text($self, $txt, 1, 'XNQ');
 318                         }
 319                 }
 320                 undef $txt; # free memory
 321         }
 322 }
 323
 324 sub index_list_id ($$$) {
 325         my ($self, $doc, $hdr) = @_;
 326         for my $l ($hdr->header_raw('List-Id')) {
 327                 $l =~ /<([^>]+)>/ or next;
 328                 my $lid = lc $1;
 329                 $doc->add_boolean_term('G' . $lid);
 330                 index_text($self, $lid, 1, 'XL'); # probabilistic
 331         }
 332 }
 333
 334 sub index_ids ($$$$) {
 335         my ($self, $doc, $hdr, $mids) = @_;
 336         for my $mid (@$mids) {
 337                 index_text($self, $mid, 1, 'XM');
 338
 339                 # because too many Message-IDs are prefixed with
 340                 # "Pine.LNX."...
 341                 if ($mid =~ /\w{12,}/) {
 342                         my @long = ($mid =~ /(\w{3,}+)/g);
 343                         index_text($self, join(' ', @long), 1, 'XM');
 344                 }
 345         }
 346         $doc->add_boolean_term('Q' . $_) for @$mids;
 347         index_list_id($self, $doc, $hdr);
 348 }
 349
 350 sub eml2doc ($$$;$) {
 351         my ($self, $eml, $smsg, $mids) = @_;
 352         $mids //= mids_for_index($eml);
 353         my $doc = $X->{Document}->new;
 354         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 355         my @ds = gmtime($smsg->{ds});
 356         my $yyyymmdd = strftime('%Y%m%d', @ds);
 357         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 358         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 359         add_val($doc, PublicInbox::Search::DT(), $dt);
 360         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 361         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 362         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 363
 364         my $tg = term_generator($self);
 365         $tg->set_document($doc);
 366         index_headers($self, $smsg);
 367
 368         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 369                 $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 370         }
 371         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 372         index_ids($self, $doc, $eml, $mids);
 373
 374         # by default, we maintain compatibility with v1.5.0 and earlier
 375         # by writing to docdata.glass, users who never exect to downgrade can
 376         # use --skip-docdata
 377         if (!$self->{-skip_docdata}) {
 378                 # WWW doesn't need {to} or {cc}, only NNTP
 379                 $smsg->{to} = $smsg->{cc} = '';
 380                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 381                 my $data = $smsg->to_doc_data;
 382                 $doc->set_data($data);
 383         }
 384
 385         if (my $altid = $self->{-altid}) {
 386                 foreach my $alt (@$altid) {
 387                         my $pfx = $alt->{xprefix};
 388                         foreach my $mid (@$mids) {
 389                                 my $id = $alt->mid2alt($mid);
 390                                 next unless defined $id;
 391                                 $doc->add_boolean_term($pfx . $id);
 392                         }
 393                 }
 394         }
 395         $doc;
 396 }
 397
 398 sub add_xapian ($$$$) {
 399         my ($self, $eml, $smsg, $mids) = @_;
 400         begin_txn_lazy($self);
 401         my $doc = eml2doc($self, $eml, $smsg, $mids);
 402         $self->{xdb}->replace_document($smsg->{num}, $doc);
 403 }
 404
 405 sub _msgmap_init ($) {
 406         my ($self) = @_;
 407         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx}->version != 1;
 408         $self->{mm} //= eval {
 409                 require PublicInbox::Msgmap;
 410                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 411                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 412         };
 413 }
 414
 415 sub add_message {
 416         # mime = PublicInbox::Eml or Email::MIME object
 417         my ($self, $mime, $smsg, $sync) = @_;
 418         begin_txn_lazy($self);
 419         my $mids = mids_for_index($mime);
 420         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 421         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 422         $smsg->{num} //= do { # v1
 423                 _msgmap_init($self);
 424                 index_mm($self, $mime, $smsg->{blob}, $sync);
 425         };
 426
 427         # v1 and tests only:
 428         $smsg->populate($mime, $sync);
 429         $smsg->{bytes} //= length($mime->as_string);
 430
 431         eval {
 432                 # order matters, overview stores every possible piece of
 433                 # data in doc_data (deflated).  Xapian only stores a subset
 434                 # of the fields which exist in over.sqlite3.  We may stop
 435                 # storing doc_data in Xapian sometime after we get multi-inbox
 436                 # search working.
 437                 if (my $oidx = $self->{oidx}) { # v1 only
 438                         $oidx->add_overview($mime, $smsg);
 439                 }
 440                 if (need_xapian($self)) {
 441                         add_xapian($self, $mime, $smsg, $mids);
 442                 }
 443         };
 444
 445         if ($@) {
 446                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 447                 return undef;
 448         }
 449         $smsg->{num};
 450 }
 451
 452 sub _get_doc ($$) {
 453         my ($self, $docid) = @_;
 454         my $doc = eval { $self->{xdb}->get_document($docid) };
 455         $doc // do {
 456                 warn "E: $@\n" if $@;
 457                 warn "E: #$docid missing in Xapian\n";
 458                 undef;
 459         }
 460 }
 461
 462 sub add_eidx_info {
 463         my ($self, $docid, $eidx_key, $eml) = @_;
 464         begin_txn_lazy($self);
 465         my $doc = _get_doc($self, $docid) or return;
 466         term_generator($self)->set_document($doc);
 467         $doc->add_boolean_term('O'.$eidx_key) if $eidx_key ne '.';
 468         index_list_id($self, $doc, $eml);
 469         $self->{xdb}->replace_document($docid, $doc);
 470 }
 471
 472 sub remove_eidx_info {
 473         my ($self, $docid, $eidx_key, $eml) = @_;
 474         begin_txn_lazy($self);
 475         my $doc = _get_doc($self, $docid) or return;
 476         eval { $doc->remove_term('O'.$eidx_key) };
 477         warn "W: ->remove_term O$eidx_key: $@\n" if $@;
 478         for my $l ($eml ? $eml->header_raw('List-Id') : ()) {
 479                 $l =~ /<([^>]+)>/ or next;
 480                 my $lid = lc $1;
 481                 eval { $doc->remove_term('G' . $lid) };
 482                 warn "W: ->remove_term G$lid: $@\n" if $@;
 483
 484                 # nb: we don't remove the XL probabilistic terms
 485                 # since terms may overlap if cross-posted.
 486                 #
 487                 # IOW, a message which has both <foo.example.com>
 488                 # and <bar.example.com> would have overlapping
 489                 # "XLexample" and "XLcom" as terms and which we
 490                 # wouldn't know if they're safe to remove if we just
 491                 # unindex <foo.example.com> while preserving
 492                 # <bar.example.com>.
 493                 #
 494                 # In any case, this entire sub is will likely never
 495                 # be needed and users using the "l:" prefix are probably
 496                 # rarer.
 497         }
 498         $self->{xdb}->replace_document($docid, $doc);
 499 }
 500
 501 sub set_keywords {
 502         my ($self, $docid, @kw) = @_;
 503         begin_txn_lazy($self);
 504         my $doc = _get_doc($self, $docid) or return;
 505         my %keep = map { $_ => 1 } @kw;
 506         my %add = %keep;
 507         my @rm;
 508         my $end = $doc->termlist_end;
 509         for (my $cur = $doc->termlist_begin; $cur != $end; $cur++) {
 510                 $cur->skip_to('K');
 511                 last if $cur == $end;
 512                 my $kw = $cur->get_termname;
 513                 $kw =~ s/\AK//s or next;
 514                 $keep{$kw} ? delete($add{$kw}) : push(@rm, $kw);
 515         }
 516         return unless (scalar(@rm) + scalar(keys %add));
 517         $doc->remove_term('K'.$_) for @rm;
 518         $doc->add_boolean_term('K'.$_) for (keys %add);
 519         $self->{xdb}->replace_document($docid, $doc);
 520 }
 521
 522 sub add_keywords {
 523         my ($self, $docid, @kw) = @_;
 524         begin_txn_lazy($self);
 525         my $doc = _get_doc($self, $docid) or return;
 526         $doc->add_boolean_term('K'.$_) for @kw;
 527         $self->{xdb}->replace_document($docid, $doc);
 528 }
 529
 530 sub remove_keywords {
 531         my ($self, $docid, @kw) = @_;
 532         begin_txn_lazy($self);
 533         my $doc = _get_doc($self, $docid) or return;
 534         my $replace;
 535         eval {
 536                 $doc->remove_term('K'.$_);
 537                 $replace = 1
 538         } for @kw;
 539         $self->{xdb}->replace_document($docid, $doc) if $replace;
 540 }
 541
 542 sub smsg_from_doc ($) {
 543         my ($doc) = @_;
 544         my $data = $doc->get_data or return;
 545         my $smsg = bless {}, 'PublicInbox::Smsg';
 546         $smsg->{ts} = int_val($doc, PublicInbox::Search::TS());
 547         my $dt = int_val($doc, PublicInbox::Search::DT());
 548         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 549         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 550         $smsg->load_from_data($data);
 551         $smsg;
 552 }
 553
 554 sub xdb_remove {
 555         my ($self, @docids) = @_;
 556         $self->begin_txn_lazy;
 557         my $xdb = $self->{xdb} or return;
 558         for my $docid (@docids) {
 559                 eval { $xdb->delete_document($docid) };
 560                 warn "E: #$docid not in in Xapian? $@\n" if $@;
 561         }
 562 }
 563
 564 sub index_git_blob_id {
 565         my ($doc, $pfx, $objid) = @_;
 566
 567         my $len = length($objid);
 568         for (my $len = length($objid); $len >= 7; ) {
 569                 $doc->add_term($pfx.$objid);
 570                 $objid = substr($objid, 0, --$len);
 571         }
 572 }
 573
 574 # v1 only
 575 sub unindex_eml {
 576         my ($self, $oid, $eml) = @_;
 577         my $mids = mids($eml);
 578         my $nr = 0;
 579         my %tmp;
 580         for my $mid (@$mids) {
 581                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 582                 $nr += scalar @removed;
 583                 $tmp{$_}++ for @removed;
 584         }
 585         if (!$nr) {
 586                 my $m = join('> <', @$mids);
 587                 warn "W: <$m> missing for removal from overview\n";
 588         }
 589         while (my ($num, $nr) = each %tmp) {
 590                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 591         }
 592         if ($nr) {
 593                 $self->{mm}->num_delete($_) for (keys %tmp);
 594         } else { # just in case msgmap and over.sqlite3 become desynched:
 595                 $self->{mm}->mid_delete($mids->[0]);
 596         }
 597         xdb_remove($self, keys %tmp) if need_xapian($self);
 598 }
 599
 600 sub index_mm {
 601         my ($self, $mime, $oid, $sync) = @_;
 602         my $mids = mids($mime);
 603         my $mm = $self->{mm};
 604         if ($sync->{reindex}) {
 605                 my $oidx = $self->{oidx};
 606                 for my $mid (@$mids) {
 607                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 608                         return $num if defined $num;
 609                 }
 610                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 611         } else {
 612                 # fallback to num_for since filters like RubyLang set the number
 613                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 614         }
 615 }
 616
 617 sub is_bad_blob ($$$$) {
 618         my ($oid, $type, $size, $expect_oid) = @_;
 619         if ($type ne 'blob') {
 620                 carp "W: $expect_oid is not a blob (type=$type)";
 621                 return 1;
 622         }
 623         croak "BUG: $oid != $expect_oid" if $oid ne $expect_oid;
 624         $size == 0 ? 1 : 0; # size == 0 means purged
 625 }
 626
 627 sub index_both { # git->cat_async callback
 628         my ($bref, $oid, $type, $size, $sync) = @_;
 629         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 630         my ($nr, $max) = @$sync{qw(nr max)};
 631         ++$$nr;
 632         $$max -= $size;
 633         my $smsg = bless { blob => $oid }, 'PublicInbox::Smsg';
 634         $smsg->set_bytes($$bref, $size);
 635         my $self = $sync->{sidx};
 636         local $self->{current_info} = "$self->{current_info}: $oid";
 637         my $eml = PublicInbox::Eml->new($bref);
 638         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 639                 die "E: could not generate NNTP article number for $oid";
 640         add_message($self, $eml, $smsg, $sync);
 641         ++$self->{nidx};
 642         my $cur_cmt = $sync->{cur_cmt} // die 'BUG: {cur_cmt} missing';
 643         ${$sync->{latest_cmt}} = $cur_cmt;
 644 }
 645
 646 sub unindex_both { # git->cat_async callback
 647         my ($bref, $oid, $type, $size, $sync) = @_;
 648         return if is_bad_blob($oid, $type, $size, $sync->{oid});
 649         my $self = $sync->{sidx};
 650         local $self->{current_info} = "$self->{current_info}: $oid";
 651         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 652         # may be undef if leftover
 653         if (defined(my $cur_cmt = $sync->{cur_cmt})) {
 654                 ${$sync->{latest_cmt}} = $cur_cmt;
 655         }
 656         ++$self->{nidx};
 657 }
 658
 659 sub with_umask {
 660         my $self = shift;
 661         ($self->{ibx} // $self->{eidx})->with_umask(@_);
 662 }
 663
 664 # called by public-inbox-index
 665 sub index_sync {
 666         my ($self, $opt) = @_;
 667         delete $self->{lock_path} if $opt->{-skip_lock};
 668         $self->with_umask(\&_index_sync, $self, $opt);
 669         if ($opt->{reindex} && !$opt->{quit}) {
 670                 my %again = %$opt;
 671                 delete @again{qw(rethread reindex)};
 672                 index_sync($self, \%again);
 673                 $opt->{quit} = $again{quit}; # propagate to caller
 674         }
 675 }
 676
 677 sub check_size { # check_async cb for -index --max-size=...
 678         my ($oid, $type, $size, $arg, $git) = @_;
 679         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 680         if ($size <= $arg->{max_size}) {
 681                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 682         } else {
 683                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 684         }
 685 }
 686
 687 sub v1_checkpoint ($$;$) {
 688         my ($self, $sync, $stk) = @_;
 689         $self->{ibx}->git->async_wait_all;
 690
 691         # $newest may be undef
 692         my $newest = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 693         if (defined($newest)) {
 694                 my $cur = $self->{mm}->last_commit || '';
 695                 if (need_update($self, $cur, $newest)) {
 696                         $self->{mm}->last_commit($newest);
 697                 }
 698         }
 699         ${$sync->{max}} = $self->{batch_bytes};
 700
 701         $self->{mm}->{dbh}->commit;
 702         my $xdb = need_xapian($self) ? $self->{xdb} : undef;
 703         if ($newest && $xdb) {
 704                 my $cur = $xdb->get_metadata('last_commit');
 705                 if (need_update($self, $cur, $newest)) {
 706                         $xdb->set_metadata('last_commit', $newest);
 707                 }
 708         }
 709         if ($stk) { # all done if $stk is passed
 710                 # let SearchView know a full --reindex was done so it can
 711                 # generate ->has_threadid-dependent links
 712                 if ($xdb && $sync->{reindex} && !ref($sync->{reindex})) {
 713                         my $n = $xdb->get_metadata('has_threadid');
 714                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 715                 }
 716                 $self->{oidx}->rethread_done($sync->{-opt}); # all done
 717         }
 718         commit_txn_lazy($self);
 719         $sync->{ibx}->git->cleanup;
 720         my $nr = ${$sync->{nr}};
 721         idx_release($self, $nr);
 722         # let another process do some work...
 723         if (my $pr = $sync->{-opt}->{-progress}) {
 724                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 725         }
 726         if (!$stk && !$sync->{quit}) { # more to come
 727                 begin_txn_lazy($self);
 728                 $self->{mm}->{dbh}->begin_work;
 729         }
 730 }
 731
 732 # only for v1
 733 sub process_stack {
 734         my ($self, $sync, $stk) = @_;
 735         my $git = $sync->{ibx}->git;
 736         my $max = $self->{batch_bytes};
 737         my $nr = 0;
 738         $sync->{nr} = \$nr;
 739         $sync->{max} = \$max;
 740         $sync->{sidx} = $self;
 741         $sync->{latest_cmt} = \(my $latest_cmt);
 742
 743         $self->{mm}->{dbh}->begin_work;
 744         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 745                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 746                 for my $oid (@leftovers) {
 747                         last if $sync->{quit};
 748                         $oid = unpack('H*', $oid);
 749                         $git->cat_async($oid, \&unindex_both, $sync);
 750                 }
 751         }
 752         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 753                 $sync->{index_oid} = \&index_both;
 754         }
 755         while (my ($f, $at, $ct, $oid, $cur_cmt) = $stk->pop_rec) {
 756                 my $arg = { %$sync, cur_cmt => $cur_cmt, oid => $oid };
 757                 last if $sync->{quit};
 758                 if ($f eq 'm') {
 759                         $arg->{autime} = $at;
 760                         $arg->{cotime} = $ct;
 761                         if ($sync->{max_size}) {
 762                                 $git->check_async($oid, \&check_size, $arg);
 763                         } else {
 764                                 $git->cat_async($oid, \&index_both, $arg);
 765                         }
 766                         v1_checkpoint($self, $sync) if $max <= 0;
 767                 } elsif ($f eq 'd') {
 768                         $git->cat_async($oid, \&unindex_both, $arg);
 769                 }
 770         }
 771         v1_checkpoint($self, $sync, $sync->{quit} ? undef : $stk);
 772 }
 773
 774 sub log2stack ($$$) {
 775         my ($sync, $git, $range) = @_;
 776         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 777         my ($add, $del);
 778         if ($sync->{ibx}->version == 1) {
 779                 my $path = $hex.'{2}/'.$hex.'{38}';
 780                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 781                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 782         } else {
 783                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 784                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 785         }
 786
 787         # Count the new files so they can be added newest to oldest
 788         # and still have numbers increasing from oldest to newest
 789         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 790                                 --no-notes --no-color --no-renames --no-abbrev),
 791                                 $range);
 792         my ($at, $ct, $stk, $cmt);
 793         while (<$fh>) {
 794                 return if $sync->{quit};
 795                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 796                         ($at, $ct, $cmt) = ($1 + 0, $2 + 0, $3);
 797                         $stk //= PublicInbox::IdxStack->new($cmt);
 798                 } elsif (/$del/) {
 799                         my $oid = $1;
 800                         if ($D) { # reindex case
 801                                 $D->{pack('H*', $oid)}++;
 802                         } else { # non-reindex case:
 803                                 $stk->push_rec('d', $at, $ct, $oid, $cmt);
 804                         }
 805                 } elsif (/$add/) {
 806                         my $oid = $1;
 807                         if ($D) {
 808                                 my $oid_bin = pack('H*', $oid);
 809                                 my $nr = --$D->{$oid_bin};
 810                                 delete($D->{$oid_bin}) if $nr <= 0;
 811                                 # nr < 0 (-1) means it never existed
 812                                 next if $nr >= 0;
 813                         }
 814                         $stk->push_rec('m', $at, $ct, $oid, $cmt);
 815                 }
 816         }
 817         close $fh or die "git log failed: \$?=$?";
 818         $stk //= PublicInbox::IdxStack->new;
 819         $stk->read_prepare;
 820 }
 821
 822 sub prepare_stack ($$) {
 823         my ($sync, $range) = @_;
 824         my $git = $sync->{ibx}->git;
 825
 826         if (index($range, '..') < 0) {
 827                 # don't show annoying git errors to users who run -index
 828                 # on empty inboxes
 829                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 830                 return PublicInbox::IdxStack->new->read_prepare if $?;
 831         }
 832         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 833         log2stack($sync, $git, $range);
 834 }
 835
 836 # --is-ancestor requires git 1.8.0+
 837 sub is_ancestor ($$$) {
 838         my ($git, $cur, $tip) = @_;
 839         return 0 unless $git->check($cur);
 840         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 841                 qw(merge-base --is-ancestor), $cur, $tip ];
 842         my $pid = spawn($cmd);
 843         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 844         $? == 0;
 845 }
 846
 847 sub need_update ($$$) {
 848         my ($self, $cur, $new) = @_;
 849         my $git = $self->{ibx}->git;
 850         return 1 if $cur && !is_ancestor($git, $cur, $new);
 851         my $range = $cur eq '' ? $new : "$cur..$new";
 852         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 853         ($n eq '' || $n > 0);
 854 }
 855
 856 # The last git commit we indexed with Xapian or SQLite (msgmap)
 857 # This needs to account for cases where Xapian or SQLite is
 858 # out-of-date with respect to the other.
 859 sub _last_x_commit {
 860         my ($self, $mm) = @_;
 861         my $lm = $mm->last_commit || '';
 862         my $lx = '';
 863         if (need_xapian($self)) {
 864                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 865         } else {
 866                 $lx = $lm;
 867         }
 868         # Use last_commit from msgmap if it is older or unset
 869         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 870                 $lx = $lm;
 871         }
 872         $lx;
 873 }
 874
 875 sub reindex_from ($$) {
 876         my ($reindex, $last_commit) = @_;
 877         return $last_commit unless $reindex;
 878         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 879 }
 880
 881 sub quit_cb ($) {
 882         my ($sync) = @_;
 883         sub {
 884                 # we set {-opt}->{quit} too, so ->index_sync callers
 885                 # can abort multi-inbox loops this way
 886                 $sync->{quit} = $sync->{-opt}->{quit} = 1;
 887                 warn "gracefully quitting\n";
 888         }
 889 }
 890
 891 # indexes all unindexed messages (v1 only)
 892 sub _index_sync {
 893         my ($self, $opt) = @_;
 894         my $tip = $opt->{ref} || 'HEAD';
 895         my $ibx = $self->{ibx};
 896         local $self->{current_info} = "$ibx->{inboxdir}";
 897         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 898         $ibx->git->batch_prepare;
 899         my $pr = $opt->{-progress};
 900         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 901         my $quit = quit_cb($sync);
 902         local $SIG{QUIT} = $quit;
 903         local $SIG{INT} = $quit;
 904         local $SIG{TERM} = $quit;
 905         my $xdb = $self->begin_txn_lazy;
 906         $self->{oidx}->rethread_prepare($opt);
 907         my $mm = _msgmap_init($self);
 908         if ($sync->{reindex}) {
 909                 my $last = $mm->last_commit;
 910                 if ($last) {
 911                         $tip = $last;
 912                 } else {
 913                         # somebody just blindly added --reindex when indexing
 914                         # for the first time, allow it:
 915                         undef $sync->{reindex};
 916                 }
 917         }
 918         my $last_commit = _last_x_commit($self, $mm);
 919         my $lx = reindex_from($sync->{reindex}, $last_commit);
 920         my $range = $lx eq '' ? $tip : "$lx..$tip";
 921         $pr->("counting changes\n\t$range ... ") if $pr;
 922         my $stk = prepare_stack($sync, $range);
 923         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 924         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 925         process_stack($self, $sync, $stk) if !$sync->{quit};
 926 }
 927
 928 sub DESTROY {
 929         # order matters for unlocking
 930         $_[0]->{xdb} = undef;
 931         $_[0]->{lockfh} = undef;
 932 }
 933
 934 sub _begin_txn {
 935         my ($self) = @_;
 936         my $xdb = $self->{xdb} || idx_acquire($self);
 937         $self->{oidx}->begin_lazy if $self->{oidx};
 938         $xdb->begin_transaction if $xdb;
 939         $self->{txn} = 1;
 940         $xdb;
 941 }
 942
 943 sub begin_txn_lazy {
 944         my ($self) = @_;
 945         $self->with_umask(\&_begin_txn, $self) if !$self->{txn};
 946 }
 947
 948 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 949 # This metadata is read by Admin::detect_indexlevel:
 950 sub set_metadata_once {
 951         my ($self) = @_;
 952
 953         return if $self->{shard}; # only continue if undef or 0, not >0
 954         my $xdb = $self->{xdb};
 955
 956         if (delete($self->{-set_has_threadid_once})) {
 957                 $xdb->set_metadata('has_threadid', '1');
 958         }
 959         if (delete($self->{-set_indexlevel_once})) {
 960                 my $level = $xdb->get_metadata('indexlevel');
 961                 if (!$level || $level ne 'medium') {
 962                         $xdb->set_metadata('indexlevel', 'medium');
 963                 }
 964         }
 965         if (delete($self->{-set_skip_docdata_once})) {
 966                 $xdb->get_metadata('skip_docdata') or
 967                         $xdb->set_metadata('skip_docdata', '1');
 968         }
 969 }
 970
 971 sub _commit_txn {
 972         my ($self) = @_;
 973         if (my $eidx = $self->{eidx}) {
 974                 $eidx->git->async_wait_all;
 975                 $eidx->{transact_bytes} = 0;
 976         }
 977         if (my $xdb = $self->{xdb}) {
 978                 set_metadata_once($self);
 979                 $xdb->commit_transaction;
 980         }
 981         $self->{oidx}->commit_lazy if $self->{oidx};
 982 }
 983
 984 sub commit_txn_lazy {
 985         my ($self) = @_;
 986         delete($self->{txn}) and
 987                 $self->with_umask(\&_commit_txn, $self);
 988 }
 989
 990 sub eidx_shard_new {
 991         my ($class, $eidx, $shard) = @_;
 992         my $self = bless {
 993                 eidx => $eidx,
 994                 xpfx => $eidx->{xpfx},
 995                 indexlevel => $eidx->{indexlevel},
 996                 -skip_docdata => 1,
 997                 shard => $shard,
 998                 creat => 1,
 999         }, $class;
1000         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
1001         $self;
1002 }
1003
1004 # ensure there's no stale Xapian docs by treating $over as canonical
1005 sub over_check {
1006         my ($self, $over) = @_;
1007         begin_txn_lazy($self);
1008         my $sth = $over->dbh->prepare(<<'');
1009 SELECT COUNT(*) FROM over WHERE num = ?
1010
1011         my $xdb = $self->{xdb};
1012         my $cur = $xdb->postlist_begin('');
1013         my $end = $xdb->postlist_end('');
1014         my $xdir = $self->xdir;
1015         for (; $cur != $end; $cur++) {
1016                 my $docid = $cur->get_docid;
1017                 $sth->execute($docid);
1018                 my $x = $sth->fetchrow_array;
1019                 next if $x > 0;
1020                 warn "I: removing $xdir #$docid, not in `over'\n";
1021                 $xdb->delete_document($docid);
1022         }
1023 }
1024
1025 1;