lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use base qw(PublicInbox::Search);
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids references/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 require PublicInbox::Git;
  20
  21 use constant {
  22         PERM_UMASK => 0,
  23         OLD_PERM_GROUP => 1,
  24         OLD_PERM_EVERYBODY => 2,
  25         PERM_GROUP => 0660,
  26         PERM_EVERYBODY => 0664,
  27         BATCH_BYTES => 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my %GIT_ESC = (
  32         a => "\a",
  33         b => "\b",
  34         f => "\f",
  35         n => "\n",
  36         r => "\r",
  37         t => "\t",
  38         v => "\013",
  39 );
  40
  41 sub git_unquote ($) {
  42         my ($s) = @_;
  43         return $s unless ($s =~ /\A"(.*)"\z/);
  44         $s = $1;
  45         $s =~ s/\\([abfnrtv])/$GIT_ESC{$1}/g;
  46         $s =~ s/\\([0-7]{1,3})/chr(oct($1))/ge;
  47         $s;
  48 }
  49
  50 sub new {
  51         my ($class, $ibx, $creat, $part) = @_;
  52         my $mainrepo = $ibx; # for "public-inbox-index" w/o entry in config
  53         my $git_dir = $mainrepo;
  54         my ($altid, $git);
  55         my $version = 1;
  56         if (ref $ibx) {
  57                 $mainrepo = $ibx->{mainrepo};
  58                 $altid = $ibx->{altid};
  59                 $version = $ibx->{version} || 1;
  60                 if ($altid) {
  61                         require PublicInbox::AltId;
  62                         $altid = [ map {
  63                                 PublicInbox::AltId->new($ibx, $_);
  64                         } @$altid ];
  65                 }
  66                 $git = $ibx->git;
  67         } else {
  68                 $git = PublicInbox::Git->new($git_dir); # v1 only
  69         }
  70         require Search::Xapian::WritableDatabase;
  71         my $self = bless {
  72                 mainrepo => $mainrepo,
  73                 git => $git,
  74                 -altid => $altid,
  75                 version => $version,
  76         }, $class;
  77         my $perm = $self->_git_config_perm;
  78         my $umask = _umask_for($perm);
  79         $self->{umask} = $umask;
  80         if ($version == 1) {
  81                 $self->{lock_path} = "$mainrepo/ssoma.lock";
  82         } elsif ($version == 2) {
  83                 defined $part or die "partition is required for v2\n";
  84                 # partition is a number or "all"
  85                 $self->{partition} = $part;
  86                 $self->{lock_path} = undef;
  87                 $self->{msgmap_path} = "$mainrepo/msgmap.sqlite3";
  88         } else {
  89                 die "unsupported inbox version=$version\n";
  90         }
  91         $self->{creat} = ($creat || 0) == 1;
  92         $self;
  93 }
  94
  95 sub _xdb_release {
  96         my ($self) = @_;
  97         my $xdb = delete $self->{xdb} or croak 'not acquired';
  98         $xdb->close;
  99         _lock_release($self) if $self->{creat};
 100         undef;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         croak 'already acquired' if $self->{xdb};
 106         my $dir = $self->xdir;
 107         my $flag = Search::Xapian::DB_OPEN;
 108         if ($self->{creat}) {
 109                 require File::Path;
 110                 _lock_acquire($self);
 111                 File::Path::mkpath($dir);
 112                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
 113         }
 114         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
 115 }
 116
 117 # we only acquire the flock if creating or reindexing;
 118 # PublicInbox::Import already has the lock on its own.
 119 sub _lock_acquire {
 120         my ($self) = @_;
 121         croak 'already locked' if $self->{lockfh};
 122         my $lock_path = $self->{lock_path} or return;
 123         sysopen(my $lockfh, $lock_path, O_WRONLY|O_CREAT) or
 124                 die "failed to open lock $lock_path: $!\n";
 125         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
 126         $self->{lockfh} = $lockfh;
 127 }
 128
 129 sub _lock_release {
 130         my ($self) = @_;
 131         return unless $self->{lock_path};
 132         my $lockfh = delete $self->{lockfh} or croak 'not locked';
 133         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
 134         close $lockfh or die "close failed: $!\n";
 135 }
 136
 137 sub add_val ($$$) {
 138         my ($doc, $col, $num) = @_;
 139         $num = Search::Xapian::sortable_serialise($num);
 140         $doc->add_value($col, $num);
 141 }
 142
 143 sub add_values ($$) {
 144         my ($doc, $values) = @_;
 145
 146         my $ts = $values->[PublicInbox::Search::TS];
 147         add_val($doc, PublicInbox::Search::TS, $ts);
 148
 149         my $num = $values->[PublicInbox::Search::NUM];
 150         defined($num) and add_val($doc, PublicInbox::Search::NUM, $num);
 151
 152         my $bytes = $values->[PublicInbox::Search::BYTES];
 153         defined($bytes) and add_val($doc, PublicInbox::Search::BYTES, $bytes);
 154
 155         my $lines = $values->[PublicInbox::Search::LINES];
 156         add_val($doc, PublicInbox::Search::LINES, $lines);
 157
 158         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 159         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 160 }
 161
 162 sub index_users ($$) {
 163         my ($tg, $smsg) = @_;
 164
 165         my $from = $smsg->from;
 166         my $to = $smsg->to;
 167         my $cc = $smsg->cc;
 168
 169         $tg->index_text($from, 1, 'A'); # A - author
 170         $tg->increase_termpos;
 171         $tg->index_text($to, 1, 'XTO') if $to ne '';
 172         $tg->increase_termpos;
 173         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 174         $tg->increase_termpos;
 175 }
 176
 177 sub index_diff_inc ($$$$) {
 178         my ($tg, $text, $pfx, $xnq) = @_;
 179         if (@$xnq) {
 180                 $tg->index_text(join("\n", @$xnq), 1, 'XNQ');
 181                 $tg->increase_termpos;
 182                 @$xnq = ();
 183         }
 184         $tg->index_text($text, 1, $pfx);
 185         $tg->increase_termpos;
 186 }
 187
 188 sub index_old_diff_fn {
 189         my ($tg, $seen, $fa, $fb, $xnq) = @_;
 190
 191         # no renames or space support for traditional diffs,
 192         # find the number of leading common paths to strip:
 193         my @fa = split('/', $fa);
 194         my @fb = split('/', $fb);
 195         while (scalar(@fa) && scalar(@fb)) {
 196                 $fa = join('/', @fa);
 197                 $fb = join('/', @fb);
 198                 if ($fa eq $fb) {
 199                         unless ($seen->{$fa}++) {
 200                                 index_diff_inc($tg, $fa, 'XDFN', $xnq);
 201                         }
 202                         return 1;
 203                 }
 204                 shift @fa;
 205                 shift @fb;
 206         }
 207         0;
 208 }
 209
 210 sub index_diff ($$$) {
 211         my ($tg, $lines, $doc) = @_;
 212         my %seen;
 213         my $in_diff;
 214         my @xnq;
 215         my $xnq = \@xnq;
 216         foreach (@$lines) {
 217                 if ($in_diff && s/^ //) { # diff context
 218                         index_diff_inc($tg, $_, 'XDFCTX', $xnq);
 219                 } elsif (/^-- $/) { # email signature begins
 220                         $in_diff = undef;
 221                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 222                         my ($fa, $fb) = ($1, $2);
 223                         my $fn = (split('/', git_unquote($fa), 2))[1];
 224                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 225                         $fn = (split('/', git_unquote($fb), 2))[1];
 226                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 # traditional diff:
 229                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 230                         my ($opt, $fa, $fb) = ($1, $2, $3);
 231                         push @xnq, $_;
 232                         # only support unified:
 233                         next unless $opt =~ /[uU]/;
 234                         $in_diff = index_old_diff_fn($tg, \%seen, $fa, $fb,
 235                                                         $xnq);
 236                 } elsif (m!^--- ("?a/.+)!) {
 237                         my $fn = (split('/', git_unquote($1), 2))[1];
 238                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 239                         $in_diff = 1;
 240                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 241                         my $fn = (split('/', git_unquote($1), 2))[1];
 242                         $seen{$fn}++ or index_diff_inc($tg, $fn, 'XDFN', $xnq);
 243                         $in_diff = 1;
 244                 } elsif (/^--- (\S+)/) {
 245                         $in_diff = $1;
 246                         push @xnq, $_;
 247                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 248                         $in_diff = index_old_diff_fn($tg, \%seen, $in_diff, $1,
 249                                                         $xnq);
 250                 } elsif ($in_diff && s/^\+//) { # diff added
 251                         index_diff_inc($tg, $_, 'XDFB', $xnq);
 252                 } elsif ($in_diff && s/^-//) { # diff removed
 253                         index_diff_inc($tg, $_, 'XDFA', $xnq);
 254                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 255                         my ($ba, $bb) = ($1, $2);
 256                         index_git_blob_id($doc, 'XDFPRE', $ba);
 257                         index_git_blob_id($doc, 'XDFPOST', $bb);
 258                         $in_diff = 1;
 259                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 260                         # traditional diff w/o -p
 261                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 262                         # hunk header context
 263                         index_diff_inc($tg, $1, 'XDFHH', $xnq);
 264                 # ignore the following lines:
 265                 } elsif (/^(?:dis)similarity index/ ||
 266                                 /^(?:old|new) mode/ ||
 267                                 /^(?:deleted|new) file mode/ ||
 268                                 /^(?:copy|rename) (?:from|to) / ||
 269                                 /^(?:dis)?similarity index / ||
 270                                 /^\\ No newline at end of file/ ||
 271                                 /^Binary files .* differ/) {
 272                         push @xnq, $_;
 273                 } elsif ($_ eq '') {
 274                         $in_diff = undef;
 275                 } else {
 276                         push @xnq, $_;
 277                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 278                         $in_diff = undef;
 279                 }
 280         }
 281
 282         $tg->index_text(join("\n", @xnq), 1, 'XNQ');
 283         $tg->increase_termpos;
 284 }
 285
 286 sub index_body ($$$) {
 287         my ($tg, $lines, $doc) = @_;
 288         my $txt = join("\n", @$lines);
 289         if ($doc) {
 290                 # does it look like a diff?
 291                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 292                         $txt = undef;
 293                         index_diff($tg, $lines, $doc);
 294                 } else {
 295                         $tg->index_text($txt, 1, 'XNQ');
 296                 }
 297         } else {
 298                 $tg->index_text($txt, 0, 'XQUOT');
 299         }
 300         $tg->increase_termpos;
 301         @$lines = ();
 302 }
 303
 304 sub add_message {
 305         # mime = Email::MIME object
 306         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 307         my $doc_id;
 308         my $mids = mids($mime->header_obj);
 309         my $skel = $self->{skeleton};
 310
 311         eval {
 312                 my $smsg = PublicInbox::SearchMsg->new($mime);
 313                 my $doc = $smsg->{doc};
 314                 my $subj = $smsg->subject;
 315                 my $xpath;
 316                 if ($subj ne '') {
 317                         $xpath = $self->subject_path($subj);
 318                         $xpath = id_compress($xpath);
 319                 }
 320
 321                 my $lines = $mime->body_raw =~ tr!\n!\n!;
 322                 my @values = ($smsg->ts, $num, $bytes, $lines);
 323                 add_values($doc, \@values);
 324
 325                 my $tg = $self->term_generator;
 326
 327                 $tg->set_document($doc);
 328                 $tg->index_text($subj, 1, 'S') if $subj;
 329                 $tg->increase_termpos;
 330
 331                 index_users($tg, $smsg);
 332
 333                 msg_iter($mime, sub {
 334                         my ($part, $depth, @idx) = @{$_[0]};
 335                         my $ct = $part->content_type || 'text/plain';
 336                         my $fn = $part->filename;
 337                         if (defined $fn && $fn ne '') {
 338                                 $tg->index_text($fn, 1, 'XFN');
 339                         }
 340
 341                         return if $ct =~ m!\btext/x?html\b!i;
 342
 343                         my $s = eval { $part->body_str };
 344                         if ($@) {
 345                                 if ($ct =~ m!\btext/plain\b!i) {
 346                                         # Try to assume UTF-8 because Alpine
 347                                         # seems to do wacky things and set
 348                                         # charset=X-UNKNOWN
 349                                         $part->charset_set('UTF-8');
 350                                         $s = eval { $part->body_str };
 351                                         $s = $part->body if $@;
 352                                 }
 353                         }
 354                         defined $s or return;
 355
 356                         my (@orig, @quot);
 357                         my $body = $part->body;
 358                         my @lines = split(/\n/, $body);
 359                         while (defined(my $l = shift @lines)) {
 360                                 if ($l =~ /^>/) {
 361                                         index_body($tg, \@orig, $doc) if @orig;
 362                                         push @quot, $l;
 363                                 } else {
 364                                         index_body($tg, \@quot, 0) if @quot;
 365                                         push @orig, $l;
 366                                 }
 367                         }
 368                         index_body($tg, \@quot, 0) if @quot;
 369                         index_body($tg, \@orig, $doc) if @orig;
 370                 });
 371
 372                 # populates smsg->references for smsg->to_doc_data
 373                 my $refs = parse_references($smsg);
 374                 $mid0 = $mids->[0] unless defined $mid0;
 375                 my $data = $smsg->to_doc_data($oid, $mid0);
 376                 foreach my $mid (@$mids) {
 377                         $tg->index_text($mid, 1, 'XM');
 378                 }
 379                 $doc->set_data($data);
 380                 if (my $altid = $self->{-altid}) {
 381                         foreach my $alt (@$altid) {
 382                                 my $pfx = $alt->{xprefix};
 383                                 foreach my $mid (@$mids) {
 384                                         my $id = $alt->mid2alt($mid);
 385                                         next unless defined $id;
 386                                         $doc->add_boolean_term($pfx . $id);
 387                                 }
 388                         }
 389                 }
 390
 391                 if ($skel) {
 392                         push @values, $mids, $xpath, $data;
 393                         $skel->index_skeleton(\@values);
 394                         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 395                         $doc_id = $self->{xdb}->add_document($doc);
 396                 } else {
 397                         $doc_id = link_and_save($self, $doc, $mids, $refs,
 398                                                 $num, $xpath);
 399                 }
 400         };
 401
 402         if ($@) {
 403                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 404                 return undef;
 405         }
 406         $doc_id;
 407 }
 408
 409 # returns deleted doc_id on success, undef on missing
 410 sub remove_message {
 411         my ($self, $mid) = @_;
 412         my $db = $self->{xdb};
 413         my $doc_id;
 414         $mid = mid_clean($mid);
 415
 416         eval {
 417                 my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 418                 if ($head->equal($tail)) {
 419                         warn "cannot remove non-existent <$mid>\n";
 420                 }
 421                 for (; $head != $tail; $head->inc) {
 422                         my $docid = $head->get_docid;
 423                         $db->delete_document($docid);
 424                 }
 425         };
 426
 427         if ($@) {
 428                 warn "failed to remove message <$mid>: $@\n";
 429                 return undef;
 430         }
 431         $doc_id;
 432 }
 433
 434 sub term_generator { # write-only
 435         my ($self) = @_;
 436
 437         my $tg = $self->{term_generator};
 438         return $tg if $tg;
 439
 440         $tg = Search::Xapian::TermGenerator->new;
 441         $tg->set_stemmer($self->stemmer);
 442
 443         $self->{term_generator} = $tg;
 444 }
 445
 446 # increments last_thread_id counter
 447 # returns a 64-bit integer represented as a decimal string
 448 sub next_thread_id {
 449         my ($self) = @_;
 450         my $db = $self->{xdb};
 451         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 452
 453         $db->set_metadata('last_thread_id', ++$last_thread_id);
 454
 455         $last_thread_id;
 456 }
 457
 458 sub parse_references ($) {
 459         my ($smsg) = @_;
 460         my $mime = $smsg->{mime};
 461         my $hdr = $mime->header_obj;
 462         my $refs = references($hdr);
 463         return $refs if scalar(@$refs) == 0;
 464
 465         # prevent circular references via References here:
 466         my %mids = map { $_ => 1 } @{mids($hdr)};
 467         my @keep;
 468         foreach my $ref (@$refs) {
 469                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 470                         warn "References: <$ref> too long, ignoring\n";
 471                         next;
 472                 }
 473                 next if $mids{$ref};
 474                 push @keep, $ref;
 475         }
 476         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 477         \@keep;
 478 }
 479
 480 sub link_doc {
 481         my ($self, $doc, $refs, $old_tid) = @_;
 482         my $tid;
 483
 484         if (@$refs) {
 485                 # first ref *should* be the thread root,
 486                 # but we can never trust clients to do the right thing
 487                 my $ref = shift @$refs;
 488                 $tid = resolve_mid_to_tid($self, $ref);
 489                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 490
 491                 # the rest of the refs should point to this tid:
 492                 foreach $ref (@$refs) {
 493                         my $ptid = resolve_mid_to_tid($self, $ref);
 494                         merge_threads($self, $tid, $ptid);
 495                 }
 496         } else {
 497                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 498         }
 499         $doc->add_boolean_term('G' . $tid);
 500         $tid;
 501 }
 502
 503 sub link_and_save {
 504         my ($self, $doc, $mids, $refs, $num, $xpath) = @_;
 505         my $db = $self->{xdb};
 506         my $old_tid;
 507         my $doc_id;
 508         $doc->add_boolean_term('XNUM' . $num) if defined $num;
 509         $doc->add_boolean_term('XPATH' . $xpath) if defined $xpath;
 510         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 511
 512         my $vivified = 0;
 513         foreach my $mid (@$mids) {
 514                 $self->each_smsg_by_mid($mid, sub {
 515                         my ($cur) = @_;
 516                         my $type = $cur->type;
 517                         my $cur_tid = $cur->thread_id;
 518                         $old_tid = $cur_tid unless defined $old_tid;
 519                         if ($type eq 'mail') {
 520                                 # do not break existing mail messages,
 521                                 # just merge the threads
 522                                 merge_threads($self, $old_tid, $cur_tid);
 523                                 return 1;
 524                         }
 525                         if ($type ne 'ghost') {
 526                                 die "<$mid> has a bad type: $type\n";
 527                         }
 528                         my $tid = link_doc($self, $doc, $refs, $old_tid);
 529                         $old_tid = $tid unless defined $old_tid;
 530                         $doc_id = $cur->{doc_id};
 531                         $self->{xdb}->replace_document($doc_id, $doc);
 532                         ++$vivified;
 533                         1;
 534                 });
 535         }
 536         # not really important, but we return any vivified ghost docid, here:
 537         return $doc_id if defined $doc_id;
 538         link_doc($self, $doc, $refs, $old_tid);
 539         $self->{xdb}->add_document($doc);
 540 }
 541
 542 sub index_git_blob_id {
 543         my ($doc, $pfx, $objid) = @_;
 544
 545         my $len = length($objid);
 546         for (my $len = length($objid); $len >= 7; ) {
 547                 $doc->add_term($pfx.$objid);
 548                 $objid = substr($objid, 0, --$len);
 549         }
 550 }
 551
 552 sub unindex_blob {
 553         my ($self, $mime) = @_;
 554         my $mid = eval { mid_clean(mid_mime($mime)) };
 555         $self->remove_message($mid) if defined $mid;
 556 }
 557
 558 sub index_mm {
 559         my ($self, $mime) = @_;
 560         my $mid = mid_clean(mid_mime($mime));
 561         my $mm = $self->{mm};
 562         my $num = $mm->mid_insert($mid);
 563         return $num if defined $num;
 564
 565         # fallback to num_for since filters like RubyLang set the number
 566         $mm->num_for($mid);
 567 }
 568
 569 sub unindex_mm {
 570         my ($self, $mime) = @_;
 571         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 572 }
 573
 574 sub index_mm2 {
 575         my ($self, $mime, $bytes, $blob) = @_;
 576         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 577         add_message($self, $mime, $bytes, $num, $blob);
 578 }
 579
 580 sub unindex_mm2 {
 581         my ($self, $mime) = @_;
 582         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 583         unindex_blob($self, $mime);
 584 }
 585
 586 sub index_both {
 587         my ($self, $mime, $bytes, $blob) = @_;
 588         my $num = index_mm($self, $mime);
 589         add_message($self, $mime, $bytes, $num, $blob);
 590 }
 591
 592 sub unindex_both {
 593         my ($self, $mime) = @_;
 594         unindex_blob($self, $mime);
 595         unindex_mm($self, $mime);
 596 }
 597
 598 sub do_cat_mail {
 599         my ($git, $blob, $sizeref) = @_;
 600         my $mime = eval {
 601                 my $str = $git->cat_file($blob, $sizeref);
 602                 # fixup bugs from import:
 603                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 604                 PublicInbox::MIME->new($str);
 605         };
 606         $@ ? undef : $mime;
 607 }
 608
 609 sub index_sync {
 610         my ($self, $opts) = @_;
 611         with_umask($self, sub { $self->_index_sync($opts) });
 612 }
 613
 614 sub batch_adjust ($$$$) {
 615         my ($max, $bytes, $batch_cb, $latest) = @_;
 616         $$max -= $bytes;
 617         if ($$max <= 0) {
 618                 $$max = BATCH_BYTES;
 619                 $batch_cb->($latest, 1);
 620         }
 621 }
 622
 623 # only for v1
 624 sub rlog {
 625         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 626         my $hex = '[a-f0-9]';
 627         my $h40 = $hex .'{40}';
 628         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 629         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 630         my $git = $self->{git};
 631         my $latest;
 632         my $bytes;
 633         my $max = BATCH_BYTES;
 634         local $/ = "\n";
 635         my $line;
 636         while (defined($line = <$log>)) {
 637                 if ($line =~ /$addmsg/o) {
 638                         my $blob = $1;
 639                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 640                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 641                         $add_cb->($self, $mime, $bytes, $blob);
 642                 } elsif ($line =~ /$delmsg/o) {
 643                         my $blob = $1;
 644                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 645                         batch_adjust(\$max, $bytes, $batch_cb, $latest);
 646                         $del_cb->($self, $mime);
 647                 } elsif ($line =~ /^commit ($h40)/o) {
 648                         $latest = $1;
 649                 }
 650         }
 651         $batch_cb->($latest, 0);
 652 }
 653
 654 sub _msgmap_init {
 655         my ($self) = @_;
 656         $self->{mm} ||= eval {
 657                 require PublicInbox::Msgmap;
 658                 my $msgmap_path = $self->{msgmap_path};
 659                 if (defined $msgmap_path) { # v2
 660                         PublicInbox::Msgmap->new_file($msgmap_path, 1);
 661                 } else {
 662                         PublicInbox::Msgmap->new($self->{mainrepo}, 1);
 663                 }
 664         };
 665 }
 666
 667 sub _git_log {
 668         my ($self, $range) = @_;
 669         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 670                                 --raw -r --no-abbrev/, $range);
 671 }
 672
 673 # indexes all unindexed messages
 674 sub _index_sync {
 675         my ($self, $opts) = @_;
 676         my $tip = $opts->{ref} || 'HEAD';
 677         my $reindex = $opts->{reindex};
 678         my ($mkey, $last_commit, $lx, $xlog);
 679         $self->{git}->batch_prepare;
 680         my $xdb = _xdb_acquire($self);
 681         $xdb->begin_transaction;
 682         do {
 683                 $xlog = undef;
 684                 $mkey = 'last_commit';
 685                 $last_commit = $xdb->get_metadata('last_commit');
 686                 $lx = $last_commit;
 687                 if ($reindex) {
 688                         $lx = '';
 689                         $mkey = undef if $last_commit ne '';
 690                 }
 691                 $xdb->cancel_transaction;
 692                 $xdb = _xdb_release($self);
 693
 694                 # ensure we leak no FDs to "git log"
 695                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 696                 $xlog = _git_log($self, $range);
 697
 698                 $xdb = _xdb_acquire($self);
 699                 $xdb->begin_transaction;
 700         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 701
 702         my $mm = _msgmap_init($self);
 703         my $dbh = $mm->{dbh} if $mm;
 704         my $mm_only;
 705         my $cb = sub {
 706                 my ($commit, $more) = @_;
 707                 if ($dbh) {
 708                         $mm->last_commit($commit) if $commit;
 709                         $dbh->commit;
 710                 }
 711                 if (!$mm_only) {
 712                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 713                         $xdb->commit_transaction;
 714                         $xdb = _xdb_release($self);
 715                 }
 716                 # let another process do some work... <
 717                 if ($more) {
 718                         if (!$mm_only) {
 719                                 $xdb = _xdb_acquire($self);
 720                                 $xdb->begin_transaction;
 721                         }
 722                         $dbh->begin_work if $dbh;
 723                 }
 724         };
 725
 726         if ($mm) {
 727                 $dbh->begin_work;
 728                 my $lm = $mm->last_commit || '';
 729                 if ($lm eq $lx) {
 730                         # Common case is the indexes are synced,
 731                         # we only need to run git-log once:
 732                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 733                 } else {
 734                         # Uncommon case, msgmap and xapian are out-of-sync
 735                         # do not care for performance (but git is fast :>)
 736                         # This happens if we have to reindex Xapian since
 737                         # msgmap is a frozen format and our Xapian format
 738                         # is evolving.
 739                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 740
 741                         # first, ensure msgmap is up-to-date:
 742                         my $mkey_prev = $mkey;
 743                         $mkey = undef; # ignore xapian, for now
 744                         my $mlog = _git_log($self, $r);
 745                         $mm_only = 1;
 746                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 747                         $mm_only = $mlog = undef;
 748
 749                         # now deal with Xapian
 750                         $mkey = $mkey_prev;
 751                         $dbh = undef;
 752                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 753                 }
 754         } else {
 755                 # user didn't install DBD::SQLite and DBI
 756                 rlog($self, $xlog, *add_message, *unindex_blob, $cb);
 757         }
 758 }
 759
 760 # this will create a ghost as necessary
 761 sub resolve_mid_to_tid {
 762         my ($self, $mid) = @_;
 763         my $tid;
 764         $self->each_smsg_by_mid($mid, sub {
 765                 my ($smsg) = @_;
 766                 my $cur_tid = $smsg->thread_id;
 767                 if (defined $tid) {
 768                         merge_threads($self, $tid, $cur_tid);
 769                 } else {
 770                         $tid = $smsg->thread_id;
 771                 }
 772                 1;
 773         });
 774         return $tid if defined $tid;
 775
 776         $self->create_ghost($mid)->thread_id;
 777 }
 778
 779 sub create_ghost {
 780         my ($self, $mid) = @_;
 781
 782         my $tid = $self->next_thread_id;
 783         my $doc = Search::Xapian::Document->new;
 784         $doc->add_boolean_term('Q' . $mid);
 785         $doc->add_boolean_term('G' . $tid);
 786         $doc->add_boolean_term('T' . 'ghost');
 787
 788         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 789         $self->{xdb}->add_document($doc);
 790
 791         $smsg;
 792 }
 793
 794 sub merge_threads {
 795         my ($self, $winner_tid, $loser_tid) = @_;
 796         return if $winner_tid == $loser_tid;
 797         my $db = $self->{xdb};
 798
 799         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 800         while (1) {
 801                 my ($head, $tail) = $self->find_doc_ids('G' . $loser_tid);
 802                 return if $head == $tail;
 803                 my @ids;
 804                 for (; $head != $tail && @ids < $batch_size; $head->inc) {
 805                         push @ids, $head->get_docid;
 806                 }
 807                 foreach my $docid (@ids) {
 808                         my $doc = $db->get_document($docid);
 809                         $doc->remove_term('G' . $loser_tid);
 810                         $doc->add_boolean_term('G' . $winner_tid);
 811                         $db->replace_document($docid, $doc);
 812                 }
 813         }
 814 }
 815
 816 sub _read_git_config_perm {
 817         my ($self) = @_;
 818         my @cmd = qw(config);
 819         if ($self->{version} == 2) {
 820                 push @cmd, "--file=$self->{mainrepo}/all.git/config";
 821         }
 822         my $fh = $self->{git}->popen(@cmd, 'core.sharedRepository');
 823         local $/ = "\n";
 824         my $perm = <$fh>;
 825         chomp $perm if defined $perm;
 826         $perm;
 827 }
 828
 829 sub _git_config_perm {
 830         my $self = shift;
 831         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 832         return PERM_GROUP if (!defined($perm) || $perm eq '');
 833         return PERM_UMASK if ($perm eq 'umask');
 834         return PERM_GROUP if ($perm eq 'group');
 835         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 836                 return PERM_EVERYBODY;
 837         }
 838         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 839         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 840
 841         my $i = oct($perm);
 842         return PERM_UMASK if ($i == PERM_UMASK);
 843         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 844         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 845
 846         if (($i & 0600) != 0600) {
 847                 die "core.sharedRepository mode invalid: ".
 848                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 849         }
 850         ($i & 0666);
 851 }
 852
 853 sub _umask_for {
 854         my ($perm) = @_; # _git_config_perm return value
 855         my $rv = $perm;
 856         return umask if $rv == 0;
 857
 858         # set +x bit if +r or +w were set
 859         $rv |= 0100 if ($rv & 0600);
 860         $rv |= 0010 if ($rv & 0060);
 861         $rv |= 0001 if ($rv & 0006);
 862         (~$rv & 0777);
 863 }
 864
 865 sub with_umask {
 866         my ($self, $cb) = @_;
 867         my $old = umask $self->{umask};
 868         my $rv = eval { $cb->() };
 869         my $err = $@;
 870         umask $old;
 871         die $err if $err;
 872         $rv;
 873 }
 874
 875 sub DESTROY {
 876         # order matters for unlocking
 877         $_[0]->{xdb} = undef;
 878         $_[0]->{lockfh} = undef;
 879 }
 880
 881 # remote_* subs are only used by SearchIdxPart and SearchIdxSkeleton
 882 sub remote_commit {
 883         my ($self) = @_;
 884         print { $self->{w} } "commit\n" or die "failed to write commit: $!";
 885 }
 886
 887 sub remote_close {
 888         my ($self) = @_;
 889         my $pid = delete $self->{pid} or die "no process to wait on\n";
 890         my $w = delete $self->{w} or die "no pipe to write to\n";
 891         print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 892         close $w or die "failed to close pipe for pid:$pid: $!\n";
 893         waitpid($pid, 0) == $pid or die "remote process did not finish";
 894         $? == 0 or die ref($self)." pid:$pid exited with: $?";
 895 }
 896
 897 1;