lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use v5.10.1;
  12 use parent qw(PublicInbox::Search PublicInbox::Lock Exporter);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw(mids_for_index mids);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::IdxStack;
  18 use Carp qw(croak);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::OverIdx;
  22 use PublicInbox::Spawn qw(spawn nodatacow_dir);
  23 use PublicInbox::Git qw(git_unquote);
  24 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  25 our @EXPORT_OK = qw(crlf_adjust log2stack is_ancestor check_size);
  26 my $X = \%PublicInbox::Search::X;
  27 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  28 our $DB_NO_SYNC = 0;
  29 our $BATCH_BYTES = $ENV{XAPIAN_FLUSH_THRESHOLD} ? 0x7fffffff : 1_000_000;
  30 use constant DEBUG => !!$ENV{DEBUG};
  31
  32 my $xapianlevels = qr/\A(?:full|medium)\z/;
  33 my $hex = '[a-f0-9]';
  34 my $OID = $hex .'{40,}';
  35 our $INDEXLEVELS = qr/\A(?:full|medium|basic)\z/;
  36
  37 sub new {
  38         my ($class, $ibx, $creat, $shard) = @_;
  39         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  40         my $inboxdir = $ibx->{inboxdir};
  41         my $version = $ibx->version;
  42         my $indexlevel = 'full';
  43         my $altid = $ibx->{altid};
  44         if ($altid) {
  45                 require PublicInbox::AltId;
  46                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  47         }
  48         if ($ibx->{indexlevel}) {
  49                 if ($ibx->{indexlevel} =~ $INDEXLEVELS) {
  50                         $indexlevel = $ibx->{indexlevel};
  51                 } else {
  52                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  53                 }
  54         }
  55         $ibx = PublicInbox::InboxWritable->new($ibx);
  56         my $self = bless {
  57                 ibx => $ibx,
  58                 xpfx => $inboxdir, # for xpfx_init
  59                 -altid => $altid,
  60                 ibx_ver => $version,
  61                 indexlevel => $indexlevel,
  62         }, $class;
  63         $self->xpfx_init;
  64         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  65         if ($ibx->{-skip_docdata}) {
  66                 $self->{-set_skip_docdata_once} = 1;
  67                 $self->{-skip_docdata} = 1;
  68         }
  69         $ibx->umask_prepare;
  70         if ($version == 1) {
  71                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  72                 my $dir = $self->xdir;
  73                 $self->{oidx} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  74                 $self->{oidx}->{-no_fsync} = 1 if $ibx->{-no_fsync};
  75         } elsif ($version == 2) {
  76                 defined $shard or die "shard is required for v2\n";
  77                 # shard is a number
  78                 $self->{shard} = $shard;
  79                 $self->{lock_path} = undef;
  80         } else {
  81                 die "unsupported inbox version=$version\n";
  82         }
  83         $self->{creat} = ($creat || 0) == 1;
  84         $self;
  85 }
  86
  87 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  88
  89 sub idx_release {
  90         my ($self, $wake) = @_;
  91         if (need_xapian($self)) {
  92                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  93                 $xdb->close;
  94         }
  95         $self->lock_release($wake) if $self->{creat};
  96         undef;
  97 }
  98
  99 sub load_xapian_writable () {
 100         return 1 if $X->{WritableDatabase};
 101         PublicInbox::Search::load_xapian() or return;
 102         my $xap = $PublicInbox::Search::Xap;
 103         for (qw(Document TermGenerator WritableDatabase)) {
 104                 $X->{$_} = $xap.'::'.$_;
 105         }
 106         eval 'require '.$X->{WritableDatabase} or die;
 107         *sortable_serialise = $xap.'::sortable_serialise';
 108         *sortable_unserialise = $xap.'::sortable_unserialise';
 109         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 110         $DB_OPEN = eval($xap.'::DB_OPEN()');
 111         my $ver = (eval($xap.'::major_version()') << 16) |
 112                 (eval($xap.'::minor_version()') << 8);
 113         $DB_NO_SYNC = 0x4 if $ver >= 0x10400;
 114         1;
 115 }
 116
 117 sub idx_acquire {
 118         my ($self) = @_;
 119         my $flag;
 120         my $dir = $self->xdir;
 121         if (need_xapian($self)) {
 122                 croak 'already acquired' if $self->{xdb};
 123                 load_xapian_writable();
 124                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 125         }
 126         if ($self->{creat}) {
 127                 require File::Path;
 128                 $self->lock_acquire;
 129
 130                 # don't create empty Xapian directories if we don't need Xapian
 131                 my $is_shard = defined($self->{shard});
 132                 if (!-d $dir && (!$is_shard ||
 133                                 ($is_shard && need_xapian($self)))) {
 134                         File::Path::mkpath($dir);
 135                         nodatacow_dir($dir);
 136                         $self->{-set_has_threadid_once} = 1;
 137                 }
 138         }
 139         return unless defined $flag;
 140         $flag |= $DB_NO_SYNC if $self->{ibx}->{-no_fsync};
 141         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 142         croak "Failed opening $dir: $@" if $@;
 143         $self->{xdb} = $xdb;
 144 }
 145
 146 sub add_val ($$$) {
 147         my ($doc, $col, $num) = @_;
 148         $num = sortable_serialise($num);
 149         $doc->add_value($col, $num);
 150 }
 151
 152 sub term_generator ($) { # write-only
 153         my ($self) = @_;
 154
 155         $self->{term_generator} //= do {
 156                 my $tg = $X->{TermGenerator}->new;
 157                 $tg->set_stemmer($self->stemmer);
 158                 $tg;
 159         }
 160 }
 161
 162 sub index_text ($$$$) {
 163         my ($self, $text, $wdf_inc, $prefix) = @_;
 164         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 165
 166         if ($self->{indexlevel} eq 'full') {
 167                 $tg->index_text($text, $wdf_inc, $prefix);
 168                 $tg->increase_termpos;
 169         } else {
 170                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 171         }
 172 }
 173
 174 sub index_headers ($$) {
 175         my ($self, $smsg) = @_;
 176         my @x = (from => 'A', # Author
 177                 subject => 'S', to => 'XTO', cc => 'XCC');
 178         while (my ($field, $pfx) = splice(@x, 0, 2)) {
 179                 my $val = $smsg->{$field};
 180                 index_text($self, $val, 1, $pfx) if $val ne '';
 181         }
 182 }
 183
 184 sub index_diff_inc ($$$$) {
 185         my ($self, $text, $pfx, $xnq) = @_;
 186         if (@$xnq) {
 187                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 188                 @$xnq = ();
 189         }
 190         index_text($self, $text, 1, $pfx);
 191 }
 192
 193 sub index_old_diff_fn {
 194         my ($self, $seen, $fa, $fb, $xnq) = @_;
 195
 196         # no renames or space support for traditional diffs,
 197         # find the number of leading common paths to strip:
 198         my @fa = split('/', $fa);
 199         my @fb = split('/', $fb);
 200         while (scalar(@fa) && scalar(@fb)) {
 201                 $fa = join('/', @fa);
 202                 $fb = join('/', @fb);
 203                 if ($fa eq $fb) {
 204                         unless ($seen->{$fa}++) {
 205                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 206                         }
 207                         return 1;
 208                 }
 209                 shift @fa;
 210                 shift @fb;
 211         }
 212         0;
 213 }
 214
 215 sub index_diff ($$$) {
 216         my ($self, $txt, $doc) = @_;
 217         my %seen;
 218         my $in_diff;
 219         my @xnq;
 220         my $xnq = \@xnq;
 221         foreach (split(/\n/, $txt)) {
 222                 if ($in_diff && s/^ //) { # diff context
 223                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 224                 } elsif (/^-- $/) { # email signature begins
 225                         $in_diff = undef;
 226                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 227                         # wait until "---" and "+++" to capture filenames
 228                         $in_diff = 1;
 229                 # traditional diff:
 230                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 231                         my ($opt, $fa, $fb) = ($1, $2, $3);
 232                         push @xnq, $_;
 233                         # only support unified:
 234                         next unless $opt =~ /[uU]/;
 235                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 236                                                         $xnq);
 237                 } elsif (m!^--- ("?[^/]+/.+)!) {
 238                         my $fn = $1;
 239                         $fn = (split('/', git_unquote($fn), 2))[1];
 240                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 241                         $in_diff = 1;
 242                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 243                         my $fn = $1;
 244                         $fn = (split('/', git_unquote($fn), 2))[1];
 245                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 246                         $in_diff = 1;
 247                 } elsif (/^--- (\S+)/) {
 248                         $in_diff = $1;
 249                         push @xnq, $_;
 250                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 251                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 252                                                         $1, $xnq);
 253                 } elsif ($in_diff && s/^\+//) { # diff added
 254                         index_diff_inc($self, $_, 'XDFB', $xnq);
 255                 } elsif ($in_diff && s/^-//) { # diff removed
 256                         index_diff_inc($self, $_, 'XDFA', $xnq);
 257                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 258                         my ($ba, $bb) = ($1, $2);
 259                         index_git_blob_id($doc, 'XDFPRE', $ba);
 260                         index_git_blob_id($doc, 'XDFPOST', $bb);
 261                         $in_diff = 1;
 262                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 263                         # traditional diff w/o -p
 264                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 265                         # hunk header context
 266                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 267                 # ignore the following lines:
 268                 } elsif (/^(?:dis)similarity index/ ||
 269                                 /^(?:old|new) mode/ ||
 270                                 /^(?:deleted|new) file mode/ ||
 271                                 /^(?:copy|rename) (?:from|to) / ||
 272                                 /^(?:dis)?similarity index / ||
 273                                 /^\\ No newline at end of file/ ||
 274                                 /^Binary files .* differ/) {
 275                         push @xnq, $_;
 276                 } elsif ($_ eq '') {
 277                         # possible to be in diff context, some mail may be
 278                         # stripped by MUA or even GNU diff(1).  "git apply"
 279                         # treats a bare "\n" as diff context, too
 280                 } else {
 281                         push @xnq, $_;
 282                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 283                         $in_diff = undef;
 284                 }
 285         }
 286
 287         index_text($self, join("\n", @xnq), 1, 'XNQ');
 288 }
 289
 290 sub index_xapian { # msg_iter callback
 291         my $part = $_[0]->[0]; # ignore $depth and $idx
 292         my ($self, $doc) = @{$_[1]};
 293         my $ct = $part->content_type || 'text/plain';
 294         my $fn = $part->filename;
 295         if (defined $fn && $fn ne '') {
 296                 index_text($self, $fn, 1, 'XFN');
 297         }
 298         if ($part->{is_submsg}) {
 299                 my $mids = mids_for_index($part);
 300                 index_ids($self, $doc, $part, $mids);
 301                 my $smsg = bless {}, 'PublicInbox::Smsg';
 302                 $smsg->populate($part);
 303                 index_headers($self, $smsg);
 304         }
 305
 306         my ($s, undef) = msg_part_text($part, $ct);
 307         defined $s or return;
 308         $_[0]->[0] = $part = undef; # free memory
 309
 310         # split off quoted and unquoted blocks:
 311         my @sections = PublicInbox::MsgIter::split_quotes($s);
 312         undef $s; # free memory
 313         for my $txt (@sections) {
 314                 if ($txt =~ /\A>/) {
 315                         index_text($self, $txt, 0, 'XQUOT');
 316                 } else {
 317                         # does it look like a diff?
 318                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 319                                 index_diff($self, $txt, $doc);
 320                         } else {
 321                                 index_text($self, $txt, 1, 'XNQ');
 322                         }
 323                 }
 324                 undef $txt; # free memory
 325         }
 326 }
 327
 328 sub index_list_id ($$$) {
 329         my ($self, $doc, $hdr) = @_;
 330         for my $l ($hdr->header_raw('List-Id')) {
 331                 $l =~ /<([^>]+)>/ or next;
 332                 my $lid = lc $1;
 333                 $doc->add_boolean_term('G' . $lid);
 334                 index_text($self, $lid, 1, 'XL'); # probabilistic
 335         }
 336 }
 337
 338 sub index_ids ($$$$) {
 339         my ($self, $doc, $hdr, $mids) = @_;
 340         for my $mid (@$mids) {
 341                 index_text($self, $mid, 1, 'XM');
 342
 343                 # because too many Message-IDs are prefixed with
 344                 # "Pine.LNX."...
 345                 if ($mid =~ /\w{12,}/) {
 346                         my @long = ($mid =~ /(\w{3,}+)/g);
 347                         index_text($self, join(' ', @long), 1, 'XM');
 348                 }
 349         }
 350         $doc->add_boolean_term('Q' . $_) for @$mids;
 351         index_list_id($self, $doc, $hdr);
 352 }
 353
 354 sub add_xapian ($$$$) {
 355         my ($self, $eml, $smsg, $mids) = @_;
 356         my $doc = $X->{Document}->new;
 357         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 358         my @ds = gmtime($smsg->{ds});
 359         my $yyyymmdd = strftime('%Y%m%d', @ds);
 360         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 361         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 362         add_val($doc, PublicInbox::Search::DT(), $dt);
 363         add_val($doc, PublicInbox::Search::BYTES(), $smsg->{bytes});
 364         add_val($doc, PublicInbox::Search::UID(), $smsg->{num});
 365         add_val($doc, PublicInbox::Search::THREADID, $smsg->{tid});
 366
 367         my $tg = term_generator($self);
 368         $tg->set_document($doc);
 369         index_headers($self, $smsg);
 370
 371         if (defined(my $eidx_key = $smsg->{eidx_key})) {
 372                 $doc->add_boolean_term('O'.$eidx_key);
 373                 $doc->add_boolean_term('P'.
 374                                 "$eidx_key:$smsg->{num}:$smsg->{blob}");
 375         }
 376         msg_iter($eml, \&index_xapian, [ $self, $doc ]);
 377         index_ids($self, $doc, $eml, $mids);
 378
 379         # by default, we maintain compatibility with v1.5.0 and earlier
 380         # by writing to docdata.glass, users who never exect to downgrade can
 381         # use --skip-docdata
 382         if (!$self->{-skip_docdata}) {
 383                 # WWW doesn't need {to} or {cc}, only NNTP
 384                 $smsg->{to} = $smsg->{cc} = '';
 385                 PublicInbox::OverIdx::parse_references($smsg, $eml, $mids);
 386                 my $data = $smsg->to_doc_data;
 387                 $doc->set_data($data);
 388         }
 389
 390         if (my $altid = $self->{-altid}) {
 391                 foreach my $alt (@$altid) {
 392                         my $pfx = $alt->{xprefix};
 393                         foreach my $mid (@$mids) {
 394                                 my $id = $alt->mid2alt($mid);
 395                                 next unless defined $id;
 396                                 $doc->add_boolean_term($pfx . $id);
 397                         }
 398                 }
 399         }
 400         $self->{xdb}->replace_document($smsg->{num}, $doc);
 401 }
 402
 403 sub _msgmap_init ($) {
 404         my ($self) = @_;
 405         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 406         $self->{mm} //= eval {
 407                 require PublicInbox::Msgmap;
 408                 my $rw = $self->{ibx}->{-no_fsync} ? 2 : 1;
 409                 PublicInbox::Msgmap->new($self->{ibx}->{inboxdir}, $rw);
 410         };
 411 }
 412
 413 sub add_message {
 414         # mime = PublicInbox::Eml or Email::MIME object
 415         my ($self, $mime, $smsg, $sync) = @_;
 416         my $mids = mids_for_index($mime);
 417         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 418         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 419         $smsg->{num} //= do { # v1
 420                 _msgmap_init($self);
 421                 index_mm($self, $mime, $smsg->{blob}, $sync);
 422         };
 423
 424         # v1 and tests only:
 425         $smsg->populate($mime, $sync);
 426         $smsg->{bytes} //= length($mime->as_string);
 427
 428         eval {
 429                 # order matters, overview stores every possible piece of
 430                 # data in doc_data (deflated).  Xapian only stores a subset
 431                 # of the fields which exist in over.sqlite3.  We may stop
 432                 # storing doc_data in Xapian sometime after we get multi-inbox
 433                 # search working.
 434                 if (my $oidx = $self->{oidx}) { # v1 only
 435                         $oidx->add_overview($mime, $smsg);
 436                 }
 437                 if (need_xapian($self)) {
 438                         add_xapian($self, $mime, $smsg, $mids);
 439                 }
 440         };
 441
 442         if ($@) {
 443                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 444                 return undef;
 445         }
 446         $smsg->{num};
 447 }
 448
 449 sub _get_doc ($$$) {
 450         my ($self, $docid, $oid) = @_;
 451         my $doc = eval { $self->{xdb}->get_document($docid) };
 452         $doc // do {
 453                 warn "E: $@\n" if $@;
 454                 warn "E: #$docid $oid missing in Xapian\n";
 455                 undef;
 456         }
 457 }
 458
 459 sub add_xref3 {
 460         my ($self, $docid, $xnum, $oid, $eidx_key, $eml) = @_;
 461         begin_txn_lazy($self);
 462         my $doc = _get_doc($self, $docid, $oid) or return;
 463         term_generator($self)->set_document($doc);
 464         $doc->add_boolean_term('O'.$eidx_key);
 465         $doc->add_boolean_term('P'."$eidx_key:$xnum:$oid");
 466         index_list_id($self, $doc, $eml);
 467         $self->{xdb}->replace_document($docid, $doc);
 468 }
 469
 470 sub remove_xref3 {
 471         my ($self, $docid, $oid, $eidx_key, $eml) = @_;
 472         begin_txn_lazy($self);
 473         my $doc = _get_doc($self, $docid, $oid) or return;
 474         my $xref3 = PublicInbox::Smsg::xref3(undef, $doc);
 475         my %x3 = map { $_ => undef } @$xref3;
 476         for (grep(/\A\Q$eidx_key\E:[0-9]+:\Q$oid\E\z/, @$xref3)) {
 477                 delete $x3{$_};
 478                 $doc->remove_term('P' . $_);
 479         }
 480         if (scalar(keys(%x3)) == 0) {
 481                 $self->{xdb}->delete_document($docid);
 482                 if (my $del_fh = $self->{del_fh}) { # TODO
 483                         print $del_fh $docid, "\n" or die "E: print $!";
 484                 }
 485         } else {
 486                 if (!grep(/\A\Q$eidx_key\E:/, keys %x3)) {
 487                         $doc->remove_term('O'.$eidx_key);
 488                 }
 489                 for my $l ($eml->header_raw('List-Id')) {
 490                         $l =~ /<([^>]+)>/ or next;
 491                         my $lid = lc $1;
 492                         $doc->remove_term('G' . $lid);
 493
 494                         # nb: we don't remove the XL probabilistic terms
 495                         # since terms may overlap if cross-posted.
 496                         #
 497                         # IOW, a message which has both <foo.example.com>
 498                         # and <bar.example.com> would have overlapping
 499                         # "XLexample" and "XLcom" as terms and which we
 500                         # wouldn't know if they're safe to remove if we just
 501                         # unindex <foo.example.com> while preserving
 502                         # <bar.example.com>.
 503                         #
 504                         # In any case, this entire sub is will likely never
 505                         # be needed and users using the "l:" prefix are probably
 506                         # rarer.
 507                 }
 508                 $self->{xdb}->replace_document($docid, $doc);
 509         }
 510 }
 511
 512 sub get_val ($$) {
 513         my ($doc, $col) = @_;
 514         sortable_unserialise($doc->get_value($col));
 515 }
 516
 517 sub smsg_from_doc ($) {
 518         my ($doc) = @_;
 519         my $data = $doc->get_data or return;
 520         my $smsg = bless {}, 'PublicInbox::Smsg';
 521         $smsg->{ts} = get_val($doc, PublicInbox::Search::TS());
 522         my $dt = get_val($doc, PublicInbox::Search::DT());
 523         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
 524         $smsg->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
 525         $smsg->load_from_data($data);
 526         $smsg;
 527 }
 528
 529 sub xdb_remove {
 530         my ($self, $oid, @removed) = @_;
 531         my $xdb = $self->{xdb} or return;
 532         for my $num (@removed) {
 533                 my $doc = _get_doc($self, $num, $oid) or next;
 534                 my $smsg = smsg_from_doc($doc);
 535                 my $blob = $smsg->{blob}; # may be undef if --skip-docdata
 536                 if (!defined($blob) || $blob eq $oid) {
 537                         $xdb->delete_document($num);
 538                 } else {
 539                         warn "E: #$num $oid != $blob in Xapian\n";
 540                 }
 541         }
 542 }
 543
 544 sub remove_by_oid {
 545         my ($self, $oid, $num) = @_;
 546         die "BUG: remove_by_oid is v2-only\n" if $self->{oidx};
 547         $self->begin_txn_lazy;
 548         xdb_remove($self, $oid, $num) if need_xapian($self);
 549 }
 550
 551 sub index_git_blob_id {
 552         my ($doc, $pfx, $objid) = @_;
 553
 554         my $len = length($objid);
 555         for (my $len = length($objid); $len >= 7; ) {
 556                 $doc->add_term($pfx.$objid);
 557                 $objid = substr($objid, 0, --$len);
 558         }
 559 }
 560
 561 # v1 only
 562 sub unindex_eml {
 563         my ($self, $oid, $eml) = @_;
 564         my $mids = mids($eml);
 565         my $nr = 0;
 566         my %tmp;
 567         for my $mid (@$mids) {
 568                 my @removed = $self->{oidx}->remove_oid($oid, $mid);
 569                 $nr += scalar @removed;
 570                 $tmp{$_}++ for @removed;
 571         }
 572         if (!$nr) {
 573                 $mids = join('> <', @$mids);
 574                 warn "W: <$mids> missing for removal from overview\n";
 575         }
 576         while (my ($num, $nr) = each %tmp) {
 577                 warn "BUG: $num appears >1 times ($nr) for $oid\n" if $nr != 1;
 578         }
 579         if ($nr) {
 580                 $self->{mm}->num_delete($_) for (keys %tmp);
 581         } else { # just in case msgmap and over.sqlite3 become desynched:
 582                 $self->{mm}->mid_delete($mids->[0]);
 583         }
 584         xdb_remove($self, $oid, keys %tmp) if need_xapian($self);
 585 }
 586
 587 sub index_mm {
 588         my ($self, $mime, $oid, $sync) = @_;
 589         my $mids = mids($mime);
 590         my $mm = $self->{mm};
 591         if ($sync->{reindex}) {
 592                 my $oidx = $self->{oidx};
 593                 for my $mid (@$mids) {
 594                         my ($num, undef) = $oidx->num_mid0_for_oid($oid, $mid);
 595                         return $num if defined $num;
 596                 }
 597                 $mm->num_for($mids->[0]) // $mm->mid_insert($mids->[0]);
 598         } else {
 599                 # fallback to num_for since filters like RubyLang set the number
 600                 $mm->mid_insert($mids->[0]) // $mm->num_for($mids->[0]);
 601         }
 602 }
 603
 604 # returns the number of bytes to add if given a non-CRLF arg
 605 sub crlf_adjust ($) {
 606         if (index($_[0], "\r\n") < 0) {
 607                 # common case is LF-only, every \n needs an \r;
 608                 # so favor a cheap tr// over an expensive m//g
 609                 $_[0] =~ tr/\n/\n/;
 610         } else { # count number of '\n' w/o '\r', expensive:
 611                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 612         }
 613 }
 614
 615 sub index_both { # git->cat_async callback
 616         my ($bref, $oid, $type, $size, $sync) = @_;
 617         my ($nr, $max) = @$sync{qw(nr max)};
 618         ++$$nr;
 619         $$max -= $size;
 620         $size += crlf_adjust($$bref);
 621         my $smsg = bless { bytes => $size, blob => $oid }, 'PublicInbox::Smsg';
 622         my $self = $sync->{sidx};
 623         my $eml = PublicInbox::Eml->new($bref);
 624         $smsg->{num} = index_mm($self, $eml, $oid, $sync) or
 625                 die "E: could not generate NNTP article number for $oid";
 626         add_message($self, $eml, $smsg, $sync);
 627 }
 628
 629 sub unindex_both { # git->cat_async callback
 630         my ($bref, $oid, $type, $size, $self) = @_;
 631         unindex_eml($self, $oid, PublicInbox::Eml->new($bref));
 632 }
 633
 634 # called by public-inbox-index
 635 sub index_sync {
 636         my ($self, $opt) = @_;
 637         delete $self->{lock_path} if $opt->{-skip_lock};
 638         $self->{ibx}->with_umask(\&_index_sync, $self, $opt);
 639         if ($opt->{reindex}) {
 640                 my %again = %$opt;
 641                 delete @again{qw(rethread reindex)};
 642                 index_sync($self, \%again);
 643         }
 644 }
 645
 646 sub check_size { # check_async cb for -index --max-size=...
 647         my ($oid, $type, $size, $arg, $git) = @_;
 648         (($type // '') eq 'blob') or die "E: bad $oid in $git->{git_dir}";
 649         if ($size <= $arg->{max_size}) {
 650                 $git->cat_async($oid, $arg->{index_oid}, $arg);
 651         } else {
 652                 warn "W: skipping $oid ($size > $arg->{max_size})\n";
 653         }
 654 }
 655
 656 sub v1_checkpoint ($$;$) {
 657         my ($self, $sync, $stk) = @_;
 658         $self->{ibx}->git->async_wait_all;
 659
 660         # latest_cmt may be undef
 661         my $newest = $stk ? $stk->{latest_cmt} : undef;
 662         if ($newest) {
 663                 my $cur = $self->{mm}->last_commit || '';
 664                 if (need_update($self, $cur, $newest)) {
 665                         $self->{mm}->last_commit($newest);
 666                 }
 667         } else {
 668                 ${$sync->{max}} = $self->{batch_bytes};
 669         }
 670
 671         $self->{mm}->{dbh}->commit;
 672         if ($newest && need_xapian($self)) {
 673                 my $xdb = $self->{xdb};
 674                 my $cur = $xdb->get_metadata('last_commit');
 675                 if (need_update($self, $cur, $newest)) {
 676                         $xdb->set_metadata('last_commit', $newest);
 677                 }
 678
 679                 # let SearchView know a full --reindex was done so it can
 680                 # generate ->has_threadid-dependent links
 681                 if ($sync->{reindex} && !ref($sync->{reindex})) {
 682                         my $n = $xdb->get_metadata('has_threadid');
 683                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
 684                 }
 685         }
 686
 687         $self->{oidx}->rethread_done($sync->{-opt}) if $newest; # all done
 688         commit_txn_lazy($self);
 689         $self->{ibx}->git->cleanup;
 690         my $nr = ${$sync->{nr}};
 691         idx_release($self, $nr);
 692         # let another process do some work...
 693         if (my $pr = $sync->{-opt}->{-progress}) {
 694                 $pr->("indexed $nr/$sync->{ntodo}\n") if $nr;
 695         }
 696         if (!$stk) { # more to come
 697                 begin_txn_lazy($self);
 698                 $self->{mm}->{dbh}->begin_work;
 699         }
 700 }
 701
 702 # only for v1
 703 sub process_stack {
 704         my ($self, $sync, $stk) = @_;
 705         my $git = $self->{ibx}->git;
 706         my $max = $self->{batch_bytes};
 707         my $nr = 0;
 708         $sync->{nr} = \$nr;
 709         $sync->{max} = \$max;
 710         $sync->{sidx} = $self;
 711
 712         $self->{mm}->{dbh}->begin_work;
 713         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
 714                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
 715                 for my $oid (@leftovers) {
 716                         $oid = unpack('H*', $oid);
 717                         $git->cat_async($oid, \&unindex_both, $self);
 718                 }
 719         }
 720         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 721                 $sync->{index_oid} = \&index_both;
 722         }
 723         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
 724                 if ($f eq 'm') {
 725                         my $arg = { %$sync, autime => $at, cotime => $ct };
 726                         if ($sync->{max_size}) {
 727                                 $git->check_async($oid, \&check_size, $arg);
 728                         } else {
 729                                 $git->cat_async($oid, \&index_both, $arg);
 730                         }
 731                         v1_checkpoint($self, $sync) if $max <= 0;
 732                 } elsif ($f eq 'd') {
 733                         $git->cat_async($oid, \&unindex_both, $self);
 734                 }
 735         }
 736         v1_checkpoint($self, $sync, $stk);
 737 }
 738
 739 sub log2stack ($$$$) {
 740         my ($sync, $git, $range, $ibx) = @_;
 741         my $D = $sync->{D}; # OID_BIN => NR (if reindexing, undef otherwise)
 742         my ($add, $del);
 743         if ($ibx->version == 1) {
 744                 my $path = $hex.'{2}/'.$hex.'{38}';
 745                 $add = qr!\A:000000 100644 \S+ ($OID) A\t$path$!;
 746                 $del = qr!\A:100644 000000 ($OID) \S+ D\t$path$!;
 747         } else {
 748                 $del = qr!\A:\d{6} 100644 $OID ($OID) [AM]\td$!;
 749                 $add = qr!\A:\d{6} 100644 $OID ($OID) [AM]\tm$!;
 750         }
 751
 752         # Count the new files so they can be added newest to oldest
 753         # and still have numbers increasing from oldest to newest
 754         my $fh = $git->popen(qw(log --raw -r --pretty=tformat:%at-%ct-%H
 755                                 --no-notes --no-color --no-renames --no-abbrev),
 756                                 $range);
 757         my ($at, $ct, $stk);
 758         while (<$fh>) {
 759                 if (/\A([0-9]+)-([0-9]+)-($OID)$/o) {
 760                         ($at, $ct) = ($1 + 0, $2 + 0);
 761                         $stk //= PublicInbox::IdxStack->new($3);
 762                 } elsif (/$del/) {
 763                         my $oid = $1;
 764                         if ($D) { # reindex case
 765                                 $D->{pack('H*', $oid)}++;
 766                         } else { # non-reindex case:
 767                                 $stk->push_rec('d', $at, $ct, $oid);
 768                         }
 769                 } elsif (/$add/) {
 770                         my $oid = $1;
 771                         if ($D) {
 772                                 my $oid_bin = pack('H*', $oid);
 773                                 my $nr = --$D->{$oid_bin};
 774                                 delete($D->{$oid_bin}) if $nr <= 0;
 775
 776                                 # nr < 0 (-1) means it never existed
 777                                 $stk->push_rec('m', $at, $ct, $oid) if $nr < 0;
 778                         } else {
 779                                 $stk->push_rec('m', $at, $ct, $oid);
 780                         }
 781                 }
 782         }
 783         close $fh or die "git log failed: \$?=$?";
 784         $stk //= PublicInbox::IdxStack->new;
 785         $stk->read_prepare;
 786 }
 787
 788 sub prepare_stack ($$) {
 789         my ($sync, $range) = @_;
 790         my $git = $sync->{ibx}->git;
 791
 792         if (index($range, '..') < 0) {
 793                 # don't show annoying git errors to users who run -index
 794                 # on empty inboxes
 795                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 796                 return PublicInbox::IdxStack->new->read_prepare if $?;
 797         }
 798         $sync->{D} = $sync->{reindex} ? {} : undef; # OID_BIN => NR
 799         log2stack($sync, $git, $range, $sync->{ibx});
 800 }
 801
 802 # --is-ancestor requires git 1.8.0+
 803 sub is_ancestor ($$$) {
 804         my ($git, $cur, $tip) = @_;
 805         return 0 unless $git->check($cur);
 806         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 807                 qw(merge-base --is-ancestor), $cur, $tip ];
 808         my $pid = spawn($cmd);
 809         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 810         $? == 0;
 811 }
 812
 813 sub need_update ($$$) {
 814         my ($self, $cur, $new) = @_;
 815         my $git = $self->{ibx}->git;
 816         return 1 if $cur && !is_ancestor($git, $cur, $new);
 817         my $range = $cur eq '' ? $new : "$cur..$new";
 818         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 819         ($n eq '' || $n > 0);
 820 }
 821
 822 # The last git commit we indexed with Xapian or SQLite (msgmap)
 823 # This needs to account for cases where Xapian or SQLite is
 824 # out-of-date with respect to the other.
 825 sub _last_x_commit {
 826         my ($self, $mm) = @_;
 827         my $lm = $mm->last_commit || '';
 828         my $lx = '';
 829         if (need_xapian($self)) {
 830                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 831         } else {
 832                 $lx = $lm;
 833         }
 834         # Use last_commit from msgmap if it is older or unset
 835         if (!$lm || ($lx && $lm && is_ancestor($self->{ibx}->git, $lm, $lx))) {
 836                 $lx = $lm;
 837         }
 838         $lx;
 839 }
 840
 841 sub reindex_from ($$) {
 842         my ($reindex, $last_commit) = @_;
 843         return $last_commit unless $reindex;
 844         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 845 }
 846
 847 # indexes all unindexed messages (v1 only)
 848 sub _index_sync {
 849         my ($self, $opt) = @_;
 850         my $tip = $opt->{ref} || 'HEAD';
 851         my $ibx = $self->{ibx};
 852         $self->{batch_bytes} = $opt->{batch_size} // $BATCH_BYTES;
 853         $ibx->git->batch_prepare;
 854         my $pr = $opt->{-progress};
 855         my $sync = { reindex => $opt->{reindex}, -opt => $opt, ibx => $ibx };
 856         my $xdb = $self->begin_txn_lazy;
 857         $self->{oidx}->rethread_prepare($opt);
 858         my $mm = _msgmap_init($self);
 859         if ($sync->{reindex}) {
 860                 my $last = $mm->last_commit;
 861                 if ($last) {
 862                         $tip = $last;
 863                 } else {
 864                         # somebody just blindly added --reindex when indexing
 865                         # for the first time, allow it:
 866                         undef $sync->{reindex};
 867                 }
 868         }
 869         my $last_commit = _last_x_commit($self, $mm);
 870         my $lx = reindex_from($sync->{reindex}, $last_commit);
 871         my $range = $lx eq '' ? $tip : "$lx..$tip";
 872         $pr->("counting changes\n\t$range ... ") if $pr;
 873         my $stk = prepare_stack($sync, $range);
 874         $sync->{ntodo} = $stk ? $stk->num_records : 0;
 875         $pr->("$sync->{ntodo}\n") if $pr; # continue previous line
 876         process_stack($self, $sync, $stk);
 877 }
 878
 879 sub DESTROY {
 880         # order matters for unlocking
 881         $_[0]->{xdb} = undef;
 882         $_[0]->{lockfh} = undef;
 883 }
 884
 885 sub _begin_txn {
 886         my ($self) = @_;
 887         my $xdb = $self->{xdb} || idx_acquire($self);
 888         $self->{oidx}->begin_lazy if $self->{oidx};
 889         $xdb->begin_transaction if $xdb;
 890         $self->{txn} = 1;
 891         $xdb;
 892 }
 893
 894 sub begin_txn_lazy {
 895         my ($self) = @_;
 896         $self->{ibx}->with_umask(\&_begin_txn, $self) if !$self->{txn};
 897 }
 898
 899 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 900 # This metadata is read by Admin::detect_indexlevel:
 901 sub set_metadata_once {
 902         my ($self) = @_;
 903
 904         return if $self->{shard}; # only continue if undef or 0, not >0
 905         my $xdb = $self->{xdb};
 906
 907         if (delete($self->{-set_has_threadid_once})) {
 908                 $xdb->set_metadata('has_threadid', '1');
 909         }
 910         if (delete($self->{-set_indexlevel_once})) {
 911                 my $level = $xdb->get_metadata('indexlevel');
 912                 if (!$level || $level ne 'medium') {
 913                         $xdb->set_metadata('indexlevel', 'medium');
 914                 }
 915         }
 916         if (delete($self->{-set_skip_docdata_once})) {
 917                 $xdb->get_metadata('skip_docdata') or
 918                         $xdb->set_metadata('skip_docdata', '1');
 919         }
 920 }
 921
 922 sub _commit_txn {
 923         my ($self) = @_;
 924         if (my $xdb = $self->{xdb}) {
 925                 set_metadata_once($self);
 926                 $xdb->commit_transaction;
 927         }
 928         $self->{oidx}->commit_lazy if $self->{oidx};
 929 }
 930
 931 sub commit_txn_lazy {
 932         my ($self) = @_;
 933         delete($self->{txn}) and
 934                 $self->{ibx}->with_umask(\&_commit_txn, $self);
 935 }
 936
 937 sub worker_done {
 938         my ($self) = @_;
 939         if (need_xapian($self)) {
 940                 die "$$ $0 xdb not released\n" if $self->{xdb};
 941         }
 942         die "$$ $0 still in transaction\n" if $self->{txn};
 943 }
 944
 945 sub eidx_shard_new {
 946         my ($class, $eidx, $shard) = @_;
 947         my $self = bless {
 948                 xpfx => $eidx->{xpfx},
 949                 indexlevel => $eidx->{indexlevel},
 950                 -skip_docdata => 1,
 951                 shard => $shard,
 952                 creat => 1,
 953         }, $class;
 954         $self->{-set_indexlevel_once} = 1 if $self->{indexlevel} eq 'medium';
 955         $self;
 956 }
 957
 958 1;