lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::Eml;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  62         $ibx->umask_prepare;
  63         if ($version == 1) {
  64                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  65                 my $dir = $self->xdir;
  66                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  67                 $self->{index_max_size} = $ibx->{index_max_size};
  68         } elsif ($version == 2) {
  69                 defined $shard or die "shard is required for v2\n";
  70                 # shard is a number
  71                 $self->{shard} = $shard;
  72                 $self->{lock_path} = undef;
  73         } else {
  74                 die "unsupported inbox version=$version\n";
  75         }
  76         $self->{creat} = ($creat || 0) == 1;
  77         $self;
  78 }
  79
  80 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  81
  82 sub _xdb_release {
  83         my ($self) = @_;
  84         if (need_xapian($self)) {
  85                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  86                 $xdb->close;
  87         }
  88         $self->lock_release if $self->{creat};
  89         undef;
  90 }
  91
  92 sub load_xapian_writable () {
  93         return 1 if $X->{WritableDatabase};
  94         PublicInbox::Search::load_xapian() or return;
  95         my $xap = $PublicInbox::Search::Xap;
  96         for (qw(Document TermGenerator WritableDatabase)) {
  97                 $X->{$_} = $xap.'::'.$_;
  98         }
  99         eval 'require '.$X->{WritableDatabase} or die;
 100         *sortable_serialise = $xap.'::sortable_serialise';
 101         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 102         $DB_OPEN = eval($xap.'::DB_OPEN()');
 103         1;
 104 }
 105
 106 sub _xdb_acquire {
 107         my ($self) = @_;
 108         my $flag;
 109         my $dir = $self->xdir;
 110         if (need_xapian($self)) {
 111                 croak 'already acquired' if $self->{xdb};
 112                 load_xapian_writable();
 113                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 114         }
 115         if ($self->{creat}) {
 116                 require File::Path;
 117                 $self->lock_acquire;
 118
 119                 # don't create empty Xapian directories if we don't need Xapian
 120                 my $is_shard = defined($self->{shard});
 121                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 122                         File::Path::mkpath($dir);
 123                 }
 124         }
 125         return unless defined $flag;
 126         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 127         if ($@) {
 128                 die "Failed opening $dir: ", $@;
 129         }
 130         $self->{xdb} = $xdb;
 131 }
 132
 133 sub add_val ($$$) {
 134         my ($doc, $col, $num) = @_;
 135         $num = sortable_serialise($num);
 136         $doc->add_value($col, $num);
 137 }
 138
 139 sub term_generator ($) { # write-only
 140         my ($self) = @_;
 141
 142         $self->{term_generator} //= do {
 143                 my $tg = $X->{TermGenerator}->new;
 144                 $tg->set_stemmer($self->stemmer);
 145                 $tg;
 146         }
 147 }
 148
 149 sub index_text ($$$$) {
 150         my ($self, $text, $wdf_inc, $prefix) = @_;
 151         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 152
 153         if ($self->{indexlevel} eq 'full') {
 154                 $tg->index_text($text, $wdf_inc, $prefix);
 155                 $tg->increase_termpos;
 156         } else {
 157                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 158         }
 159 }
 160
 161 sub index_users ($$) {
 162         my ($self, $smsg) = @_;
 163
 164         my $from = $smsg->from;
 165         my $to = $smsg->to;
 166         my $cc = $smsg->cc;
 167
 168         index_text($self, $from, 1, 'A'); # A - author
 169         index_text($self, $to, 1, 'XTO') if $to ne '';
 170         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 171 }
 172
 173 sub index_diff_inc ($$$$) {
 174         my ($self, $text, $pfx, $xnq) = @_;
 175         if (@$xnq) {
 176                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 177                 @$xnq = ();
 178         }
 179         index_text($self, $text, 1, $pfx);
 180 }
 181
 182 sub index_old_diff_fn {
 183         my ($self, $seen, $fa, $fb, $xnq) = @_;
 184
 185         # no renames or space support for traditional diffs,
 186         # find the number of leading common paths to strip:
 187         my @fa = split('/', $fa);
 188         my @fb = split('/', $fb);
 189         while (scalar(@fa) && scalar(@fb)) {
 190                 $fa = join('/', @fa);
 191                 $fb = join('/', @fb);
 192                 if ($fa eq $fb) {
 193                         unless ($seen->{$fa}++) {
 194                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 195                         }
 196                         return 1;
 197                 }
 198                 shift @fa;
 199                 shift @fb;
 200         }
 201         0;
 202 }
 203
 204 sub index_diff ($$$) {
 205         my ($self, $txt, $doc) = @_;
 206         my %seen;
 207         my $in_diff;
 208         my @xnq;
 209         my $xnq = \@xnq;
 210         foreach (split(/\n/, $txt)) {
 211                 if ($in_diff && s/^ //) { # diff context
 212                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 213                 } elsif (/^-- $/) { # email signature begins
 214                         $in_diff = undef;
 215                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 216                         # wait until "---" and "+++" to capture filenames
 217                         $in_diff = 1;
 218                 # traditional diff:
 219                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 220                         my ($opt, $fa, $fb) = ($1, $2, $3);
 221                         push @xnq, $_;
 222                         # only support unified:
 223                         next unless $opt =~ /[uU]/;
 224                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 225                                                         $xnq);
 226                 } elsif (m!^--- ("?[^/]+/.+)!) {
 227                         my $fn = $1;
 228                         $fn = (split('/', git_unquote($fn), 2))[1];
 229                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 230                         $in_diff = 1;
 231                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 232                         my $fn = $1;
 233                         $fn = (split('/', git_unquote($fn), 2))[1];
 234                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 235                         $in_diff = 1;
 236                 } elsif (/^--- (\S+)/) {
 237                         $in_diff = $1;
 238                         push @xnq, $_;
 239                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 240                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 241                                                         $1, $xnq);
 242                 } elsif ($in_diff && s/^\+//) { # diff added
 243                         index_diff_inc($self, $_, 'XDFB', $xnq);
 244                 } elsif ($in_diff && s/^-//) { # diff removed
 245                         index_diff_inc($self, $_, 'XDFA', $xnq);
 246                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 247                         my ($ba, $bb) = ($1, $2);
 248                         index_git_blob_id($doc, 'XDFPRE', $ba);
 249                         index_git_blob_id($doc, 'XDFPOST', $bb);
 250                         $in_diff = 1;
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 252                         # traditional diff w/o -p
 253                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 254                         # hunk header context
 255                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 256                 # ignore the following lines:
 257                 } elsif (/^(?:dis)similarity index/ ||
 258                                 /^(?:old|new) mode/ ||
 259                                 /^(?:deleted|new) file mode/ ||
 260                                 /^(?:copy|rename) (?:from|to) / ||
 261                                 /^(?:dis)?similarity index / ||
 262                                 /^\\ No newline at end of file/ ||
 263                                 /^Binary files .* differ/) {
 264                         push @xnq, $_;
 265                 } elsif ($_ eq '') {
 266                         # possible to be in diff context, some mail may be
 267                         # stripped by MUA or even GNU diff(1).  "git apply"
 268                         # treats a bare "\n" as diff context, too
 269                 } else {
 270                         push @xnq, $_;
 271                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 272                         $in_diff = undef;
 273                 }
 274         }
 275
 276         index_text($self, join("\n", @xnq), 1, 'XNQ');
 277 }
 278
 279 sub index_xapian { # msg_iter callback
 280         my $part = $_[0]->[0]; # ignore $depth and $idx
 281         my ($self, $doc) = @{$_[1]};
 282         my $ct = $part->content_type || 'text/plain';
 283         my $fn = $part->filename;
 284         if (defined $fn && $fn ne '') {
 285                 index_text($self, $fn, 1, 'XFN');
 286         }
 287         if ($part->{is_submsg}) {
 288                 my $mids = mids_for_index($part);
 289                 index_ids($self, $doc, $part, $mids);
 290                 my $smsg = PublicInbox::Smsg->new($part);
 291                 index_users($self, $smsg);
 292                 index_text($self, $smsg->subject, 1, 'S') if $smsg->subject;
 293         }
 294
 295         my ($s, undef) = msg_part_text($part, $ct);
 296         defined $s or return;
 297         $_[0]->[0] = $part = undef; # free memory
 298
 299         # split off quoted and unquoted blocks:
 300         my @sections = PublicInbox::MsgIter::split_quotes($s);
 301         undef $s; # free memory
 302         for my $txt (@sections) {
 303                 if ($txt =~ /\A>/) {
 304                         index_text($self, $txt, 0, 'XQUOT');
 305                 } else {
 306                         # does it look like a diff?
 307                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 308                                 index_diff($self, $txt, $doc);
 309                         } else {
 310                                 index_text($self, $txt, 1, 'XNQ');
 311                         }
 312                 }
 313                 undef $txt; # free memory
 314         }
 315 }
 316
 317 sub index_ids ($$$$) {
 318         my ($self, $doc, $hdr, $mids) = @_;
 319         for my $mid (@$mids) {
 320                 index_text($self, $mid, 1, 'XM');
 321
 322                 # because too many Message-IDs are prefixed with
 323                 # "Pine.LNX."...
 324                 if ($mid =~ /\w{12,}/) {
 325                         my @long = ($mid =~ /(\w{3,}+)/g);
 326                         index_text($self, join(' ', @long), 1, 'XM');
 327                 }
 328         }
 329         $doc->add_boolean_term('Q' . $_) for @$mids;
 330         for my $l ($hdr->header_raw('List-Id')) {
 331                 $l =~ /<([^>]+)>/ or next;
 332                 my $lid = $1;
 333                 $doc->add_boolean_term('G' . $lid);
 334                 index_text($self, $lid, 1, 'XL'); # probabilistic
 335         }
 336 }
 337
 338 sub add_xapian ($$$$) {
 339         my ($self, $mime, $smsg, $mids) = @_;
 340         $smsg->{mime} = $mime; # XXX dangerous
 341         my $hdr = $mime->header_obj;
 342         my $doc = $X->{Document}->new;
 343         my $subj = $smsg->subject;
 344         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 345         my @ds = gmtime($smsg->{ds});
 346         my $yyyymmdd = strftime('%Y%m%d', @ds);
 347         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 348         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 349         add_val($doc, PublicInbox::Search::DT(), $dt);
 350
 351         my $tg = term_generator($self);
 352         $tg->set_document($doc);
 353         index_text($self, $subj, 1, 'S') if $subj;
 354         index_users($self, $smsg);
 355
 356         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 357         index_ids($self, $doc, $hdr, $mids);
 358         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 359         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 360         my $data = $smsg->to_doc_data;
 361         $doc->set_data($data);
 362         if (my $altid = $self->{-altid}) {
 363                 foreach my $alt (@$altid) {
 364                         my $pfx = $alt->{xprefix};
 365                         foreach my $mid (@$mids) {
 366                                 my $id = $alt->mid2alt($mid);
 367                                 next unless defined $id;
 368                                 $doc->add_boolean_term($pfx . $id);
 369                         }
 370                 }
 371         }
 372         $self->{xdb}->replace_document($smsg->{num}, $doc);
 373 }
 374
 375 sub _msgmap_init ($) {
 376         my ($self) = @_;
 377         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 378         $self->{mm} //= eval {
 379                 require PublicInbox::Msgmap;
 380                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 381         };
 382 }
 383
 384 sub add_message {
 385         # mime = PublicInbox::Eml or Email::MIME object
 386         my ($self, $mime, $smsg) = @_;
 387         my $hdr = $mime->header_obj;
 388         my $mids = mids_for_index($hdr);
 389         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 390         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 391         $smsg->{num} //= do { # v1
 392                 _msgmap_init($self);
 393                 index_mm($self, $mime);
 394         };
 395
 396         # v1 and tests only:
 397         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 398         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 399
 400         eval {
 401                 # order matters, overview stores every possible piece of
 402                 # data in doc_data (deflated).  Xapian only stores a subset
 403                 # of the fields which exist in over.sqlite3.  We may stop
 404                 # storing doc_data in Xapian sometime after we get multi-inbox
 405                 # search working.
 406                 if (my $over = $self->{over}) { # v1 only
 407                         $over->add_overview($mime, $smsg);
 408                 }
 409                 if (need_xapian($self)) {
 410                         add_xapian($self, $mime, $smsg, $mids);
 411                 }
 412         };
 413
 414         if ($@) {
 415                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 416                 return undef;
 417         }
 418         $smsg->{num};
 419 }
 420
 421 # returns begin and end PostingIterator
 422 sub find_doc_ids {
 423         my ($self, $termval) = @_;
 424         my $db = $self->{xdb};
 425
 426         ($db->postlist_begin($termval), $db->postlist_end($termval));
 427 }
 428
 429 # v1 only
 430 sub batch_do {
 431         my ($self, $termval, $cb) = @_;
 432         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 433         while (1) {
 434                 my ($head, $tail) = $self->find_doc_ids($termval);
 435                 return if $head == $tail;
 436                 my @ids;
 437                 for (; $head != $tail && @ids < $batch_size; $head++) {
 438                         push @ids, $head->get_docid;
 439                 }
 440                 $cb->(\@ids);
 441         }
 442 }
 443
 444 # v1 only, where $mid is unique
 445 sub remove_message {
 446         my ($self, $mid) = @_;
 447         $mid = mid_clean($mid);
 448
 449         if (my $over = $self->{over}) {
 450                 my $nr = eval { $over->remove_oid(undef, $mid) };
 451                 if ($@) {
 452                         warn "failed to remove <$mid> from overview: $@\n";
 453                 } elsif ($nr == 0) {
 454                         warn "<$mid> missing for removal from overview\n";
 455                 }
 456         }
 457         return unless need_xapian($self);
 458         my $db = $self->{xdb};
 459         my $nr = 0;
 460         eval {
 461                 batch_do($self, 'Q' . $mid, sub {
 462                         my ($ids) = @_;
 463                         $db->delete_document($_) for @$ids;
 464                         $nr += scalar @$ids;
 465                 });
 466         };
 467         if ($@) {
 468                 warn "failed to remove <$mid> from Xapian: $@\n";
 469         } elsif ($nr == 0) {
 470                 warn "<$mid> missing for removal from Xapian\n";
 471         }
 472 }
 473
 474 # MID is a hint in V2
 475 sub remove_by_oid {
 476         my ($self, $oid, $mid) = @_;
 477
 478         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 479
 480         return unless need_xapian($self);
 481         my $db = $self->{xdb};
 482
 483         # XXX careful, we cannot use batch_do here since we conditionally
 484         # delete documents based on other factors, so we cannot call
 485         # find_doc_ids twice.
 486         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 487         return if $head == $tail;
 488
 489         # there is only ONE element in @delete unless we
 490         # have bugs in our v2writable deduplication check
 491         my @delete;
 492         for (; $head != $tail; $head++) {
 493                 my $docid = $head->get_docid;
 494                 my $doc = $db->get_document($docid);
 495                 my $smsg = PublicInbox::Smsg->wrap($mid);
 496                 $smsg->load_expand($doc);
 497                 if ($smsg->{blob} eq $oid) {
 498                         push(@delete, $docid);
 499                 }
 500         }
 501         $db->delete_document($_) foreach @delete;
 502         scalar(@delete);
 503 }
 504
 505 sub index_git_blob_id {
 506         my ($doc, $pfx, $objid) = @_;
 507
 508         my $len = length($objid);
 509         for (my $len = length($objid); $len >= 7; ) {
 510                 $doc->add_term($pfx.$objid);
 511                 $objid = substr($objid, 0, --$len);
 512         }
 513 }
 514
 515 sub unindex_blob {
 516         my ($self, $mime) = @_;
 517         my $mid = eval { mid_mime($mime) };
 518         $self->remove_message($mid) if defined $mid;
 519 }
 520
 521 sub index_mm {
 522         my ($self, $mime) = @_;
 523         my $mid = mid_mime($mime);
 524         my $mm = $self->{mm};
 525         my $num;
 526
 527         if (defined $self->{regen_down}) {
 528                 $num = $mm->num_for($mid) and return $num;
 529
 530                 while (($num = $self->{regen_down}--) > 0) {
 531                         if ($mm->mid_set($num, $mid) != 0) {
 532                                 return $num;
 533                         }
 534                 }
 535         } elsif (defined $self->{regen_up}) {
 536                 $num = $mm->num_for($mid) and return $num;
 537
 538                 # this is to fixup old bugs due to add-remove-add
 539                 while (($num = ++$self->{regen_up})) {
 540                         if ($mm->mid_set($num, $mid) != 0) {
 541                                 return $num;
 542                         }
 543                 }
 544         }
 545
 546         $num = $mm->mid_insert($mid) and return $num;
 547
 548         # fallback to num_for since filters like RubyLang set the number
 549         $mm->num_for($mid);
 550 }
 551
 552 sub unindex_mm {
 553         my ($self, $mime) = @_;
 554         $self->{mm}->mid_delete(mid_mime($mime));
 555 }
 556
 557 sub index_both {
 558         my ($self, $mime, $smsg) = @_;
 559         my $num = index_mm($self, $mime);
 560         $smsg->{num} = $num;
 561         add_message($self, $mime, $smsg);
 562 }
 563
 564 sub unindex_both {
 565         my ($self, $mime) = @_;
 566         unindex_blob($self, $mime);
 567         unindex_mm($self, $mime);
 568 }
 569
 570 sub do_cat_mail {
 571         my ($git, $blob, $sizeref) = @_;
 572         my $str = $git->cat_file($blob, $sizeref) or
 573                 die "BUG: $blob not found in $git->{git_dir}";
 574         PublicInbox::Eml->new($str);
 575 }
 576
 577 # called by public-inbox-index
 578 sub index_sync {
 579         my ($self, $opts) = @_;
 580         delete $self->{lock_path} if $opts->{-skip_lock};
 581         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 582 }
 583
 584 sub batch_adjust ($$$$$) {
 585         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 586         $$max -= $bytes;
 587         if ($$max <= 0) {
 588                 $$max = BATCH_BYTES;
 589                 $batch_cb->($nr, $latest);
 590         }
 591 }
 592
 593 sub too_big ($$$) {
 594         my ($self, $git, $oid) = @_;
 595         my $max_size = $self->{index_max_size} or return;
 596         my (undef, undef, $size) = $git->check($oid);
 597         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 598         return if $size <= $max_size;
 599         warn "W: skipping $oid ($size > $max_size)\n";
 600         1;
 601 }
 602
 603 # only for v1
 604 sub read_log {
 605         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 606         my $hex = '[a-f0-9]';
 607         my $h40 = $hex .'{40}';
 608         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 609         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 610         my $git = $self->{git};
 611         my $latest;
 612         my $bytes;
 613         my $max = BATCH_BYTES;
 614         local $/ = "\n";
 615         my %D;
 616         my $line;
 617         my $newest;
 618         my $nr = 0;
 619         while (defined($line = <$log>)) {
 620                 if ($line =~ /$addmsg/o) {
 621                         my $blob = $1;
 622                         if (delete $D{$blob}) {
 623                                 if (defined $self->{regen_down}) {
 624                                         my $num = $self->{regen_down}--;
 625                                         $self->{mm}->num_highwater($num);
 626                                 }
 627                                 next;
 628                         }
 629                         next if too_big($self, $git, $blob);
 630                         my $mime = do_cat_mail($git, $blob, \$bytes);
 631                         my $smsg = bless {}, 'PublicInbox::Smsg';
 632                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 633                         $smsg->{blob} = $blob;
 634                         $smsg->{bytes} = $bytes;
 635                         $add_cb->($self, $mime, $smsg);
 636                 } elsif ($line =~ /$delmsg/o) {
 637                         my $blob = $1;
 638                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 639                 } elsif ($line =~ /^commit ($h40)/o) {
 640                         $latest = $1;
 641                         $newest ||= $latest;
 642                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 643                         $self->{autime} = $1;
 644                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 645                         $self->{cotime} = $1;
 646                 }
 647         }
 648         close($log) or die "git log failed: \$?=$?";
 649         # get the leftovers
 650         foreach my $blob (keys %D) {
 651                 my $mime = do_cat_mail($git, $blob, \$bytes);
 652                 $del_cb->($self, $mime);
 653         }
 654         $batch_cb->($nr, $latest, $newest);
 655 }
 656
 657 sub _git_log {
 658         my ($self, $opts, $range) = @_;
 659         my $git = $self->{git};
 660
 661         if (index($range, '..') < 0) {
 662                 # don't show annoying git errors to users who run -index
 663                 # on empty inboxes
 664                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 665                 if ($?) {
 666                         open my $fh, '<', '/dev/null' or
 667                                 die "failed to open /dev/null: $!\n";
 668                         return $fh;
 669                 }
 670         }
 671
 672         # Count the new files so they can be added newest to oldest
 673         # and still have numbers increasing from oldest to newest
 674         my $fcount = 0;
 675         my $pr = $opts->{-progress};
 676         $pr->("counting changes\n\t$range ... ") if $pr;
 677         # can't use 'rev-list --count' if we use --diff-filter
 678         my $fh = $git->popen(qw(log --pretty=tformat:%h
 679                              --no-notes --no-color --no-renames
 680                              --diff-filter=AM), $range);
 681         ++$fcount while <$fh>;
 682         close $fh or die "git log failed: \$?=$?";
 683         my $high = $self->{mm}->num_highwater;
 684         $pr->("$fcount\n") if $pr; # continue previous line
 685         $self->{ntodo} = $fcount;
 686
 687         if (index($range, '..') < 0) {
 688                 if ($high && $high == $fcount) {
 689                         # fix up old bugs in full indexes which caused messages to
 690                         # not appear in Msgmap
 691                         $self->{regen_up} = $high;
 692                 } else {
 693                         # normal regen is for for fresh data
 694                         $self->{regen_down} = $fcount;
 695                 }
 696         } else {
 697                 # Give oldest messages the smallest numbers
 698                 $self->{regen_down} = $high + $fcount;
 699         }
 700
 701         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 702                                 --raw -r --no-abbrev/, $range);
 703 }
 704
 705 # --is-ancestor requires git 1.8.0+
 706 sub is_ancestor ($$$) {
 707         my ($git, $cur, $tip) = @_;
 708         return 0 unless $git->check($cur);
 709         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 710                 qw(merge-base --is-ancestor), $cur, $tip ];
 711         my $pid = spawn($cmd);
 712         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 713         $? == 0;
 714 }
 715
 716 sub need_update ($$$) {
 717         my ($self, $cur, $new) = @_;
 718         my $git = $self->{git};
 719         return 1 if $cur && !is_ancestor($git, $cur, $new);
 720         my $range = $cur eq '' ? $new : "$cur..$new";
 721         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 722         ($n eq '' || $n > 0);
 723 }
 724
 725 # The last git commit we indexed with Xapian or SQLite (msgmap)
 726 # This needs to account for cases where Xapian or SQLite is
 727 # out-of-date with respect to the other.
 728 sub _last_x_commit {
 729         my ($self, $mm) = @_;
 730         my $lm = $mm->last_commit || '';
 731         my $lx = '';
 732         if (need_xapian($self)) {
 733                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 734         } else {
 735                 $lx = $lm;
 736         }
 737         # Use last_commit from msgmap if it is older or unset
 738         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 739                 $lx = $lm;
 740         }
 741         $lx;
 742 }
 743
 744 sub reindex_from ($$) {
 745         my ($reindex, $last_commit) = @_;
 746         return $last_commit unless $reindex;
 747         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 748 }
 749
 750 # indexes all unindexed messages (v1 only)
 751 sub _index_sync {
 752         my ($self, $opts) = @_;
 753         my $tip = $opts->{ref} || 'HEAD';
 754         my ($last_commit, $lx, $xlog);
 755         my $git = $self->{git};
 756         $git->batch_prepare;
 757         my $pr = $opts->{-progress};
 758
 759         my $xdb = $self->begin_txn_lazy;
 760         my $mm = _msgmap_init($self);
 761         do {
 762                 if ($xlog) {
 763                         close($xlog) or die "git log failed: \$?=$?";
 764                         $xlog = undef;
 765                 }
 766                 $last_commit = _last_x_commit($self, $mm);
 767                 $lx = reindex_from($opts->{reindex}, $last_commit);
 768
 769                 $self->{over}->rollback_lazy;
 770                 $self->{over}->disconnect;
 771                 $git->cleanup;
 772                 delete $self->{txn};
 773                 $xdb->cancel_transaction if $xdb;
 774                 $xdb = _xdb_release($self);
 775
 776                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 777                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 778                 $xlog = _git_log($self, $opts, $range);
 779
 780                 $xdb = $self->begin_txn_lazy;
 781         } while (_last_x_commit($self, $mm) ne $last_commit);
 782
 783         my $dbh = $mm->{dbh} if $mm;
 784         my $cb = sub {
 785                 my ($nr, $commit, $newest) = @_;
 786                 if ($dbh) {
 787                         if ($newest) {
 788                                 my $cur = $mm->last_commit || '';
 789                                 if (need_update($self, $cur, $newest)) {
 790                                         $mm->last_commit($newest);
 791                                 }
 792                         }
 793                         $dbh->commit;
 794                 }
 795                 if ($newest && need_xapian($self)) {
 796                         my $cur = $xdb->get_metadata('last_commit');
 797                         if (need_update($self, $cur, $newest)) {
 798                                 $xdb->set_metadata('last_commit', $newest);
 799                         }
 800                 }
 801                 $self->commit_txn_lazy;
 802                 $git->cleanup;
 803                 $xdb = _xdb_release($self);
 804                 # let another process do some work... <
 805                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 806                 if (!$newest) {
 807                         $xdb = $self->begin_txn_lazy;
 808                         $dbh->begin_work if $dbh;
 809                 }
 810         };
 811
 812         $dbh->begin_work;
 813         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 814 }
 815
 816 sub DESTROY {
 817         # order matters for unlocking
 818         $_[0]->{xdb} = undef;
 819         $_[0]->{lockfh} = undef;
 820 }
 821
 822 # remote_* subs are only used by SearchIdxPart
 823 sub remote_commit {
 824         my ($self) = @_;
 825         if (my $w = $self->{w}) {
 826                 print $w "commit\n" or die "failed to write commit: $!";
 827         } else {
 828                 $self->commit_txn_lazy;
 829         }
 830 }
 831
 832 sub remote_close {
 833         my ($self) = @_;
 834         if (my $w = delete $self->{w}) {
 835                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 836                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 837                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 838                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 839                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 840         } else {
 841                 die "transaction in progress $self\n" if $self->{txn};
 842                 $self->_xdb_release if $self->{xdb};
 843         }
 844 }
 845
 846 sub remote_remove {
 847         my ($self, $oid, $mid) = @_;
 848         if (my $w = $self->{w}) {
 849                 # triggers remove_by_oid in a shard
 850                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 851         } else {
 852                 $self->begin_txn_lazy;
 853                 $self->remove_by_oid($oid, $mid);
 854         }
 855 }
 856
 857 sub begin_txn_lazy {
 858         my ($self) = @_;
 859         return if $self->{txn};
 860
 861         $self->{-inbox}->with_umask(sub {
 862                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 863                 $self->{over}->begin_lazy if $self->{over};
 864                 $xdb->begin_transaction if $xdb;
 865                 $self->{txn} = 1;
 866                 $xdb;
 867         });
 868 }
 869
 870 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 871 # This metadata is read by Admin::detect_indexlevel:
 872 sub set_indexlevel {
 873         my ($self) = @_;
 874
 875         if (!$self->{shard} && # undef or 0, not >0
 876                         delete($self->{-set_indexlevel_once})) {
 877                 my $xdb = $self->{xdb};
 878                 my $level = $xdb->get_metadata('indexlevel');
 879                 if (!$level || $level ne 'medium') {
 880                         $xdb->set_metadata('indexlevel', 'medium');
 881                 }
 882         }
 883 }
 884
 885 sub commit_txn_lazy {
 886         my ($self) = @_;
 887         delete $self->{txn} or return;
 888         $self->{-inbox}->with_umask(sub {
 889                 if (my $xdb = $self->{xdb}) {
 890                         set_indexlevel($self);
 891                         $xdb->commit_transaction;
 892                 }
 893                 $self->{over}->commit_lazy if $self->{over};
 894         });
 895 }
 896
 897 sub worker_done {
 898         my ($self) = @_;
 899         if (need_xapian($self)) {
 900                 die "$$ $0 xdb not released\n" if $self->{xdb};
 901         }
 902         die "$$ $0 still in transaction\n" if $self->{txn};
 903 }
 904
 905 1;