lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use Email::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 require PublicInbox::Git;
  20 *xpfx = *PublicInbox::Search::xpfx;
  21
  22 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  23 use constant {
  24         PERM_UMASK => 0,
  25         OLD_PERM_GROUP => 1,
  26         OLD_PERM_EVERYBODY => 2,
  27         PERM_GROUP => 0660,
  28         PERM_EVERYBODY => 0664,
  29 };
  30
  31 # XXX temporary hack...
  32 my $xap_ver = ((Search::Xapian::major_version << 16) |
  33                  (Search::Xapian::minor_version << 8 ) |
  34                   Search::Xapian::revision());
  35 our $XAP_LOCK_BROKEN = $xap_ver >= 0x010216; # >= 1.2.22
  36
  37 sub new {
  38         my ($class, $git_dir, $writable) = @_;
  39         my $dir = PublicInbox::Search->xdir($git_dir);
  40         require Search::Xapian::WritableDatabase;
  41         my $flag = Search::Xapian::DB_OPEN;
  42         my $self = bless { git_dir => $git_dir }, $class;
  43         my $perm = $self->_git_config_perm;
  44         my $umask = _umask_for($perm);
  45         $self->{umask} = $umask;
  46         $self->{lock_path} = "$git_dir/ssoma.lock";
  47         $self->{git} = PublicInbox::Git->new($git_dir);
  48         $self->{xdb} = $self->with_umask(sub {
  49                 if ($writable == 1) {
  50                         require File::Path;
  51                         File::Path::mkpath($dir);
  52                         $self->{batch_size} = 100 unless $XAP_LOCK_BROKEN;
  53                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  54                         _lock_acquire($self);
  55                 }
  56                 Search::Xapian::WritableDatabase->new($dir, $flag);
  57         });
  58         $self;
  59 }
  60
  61 sub _xdb_release {
  62         my ($self) = @_;
  63         my $xdb = delete $self->{xdb};
  64         $xdb->commit_transaction;
  65         $xdb->close;
  66 }
  67
  68 sub _xdb_acquire {
  69         my ($self, $more) = @_;
  70         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  71         my $flag = Search::Xapian::DB_OPEN;
  72         my $xdb = Search::Xapian::WritableDatabase->new($dir, $flag);
  73         $xdb->begin_transaction if $more;
  74         $self->{xdb} = $xdb;
  75 }
  76
  77 sub _lock_acquire {
  78         my ($self) = @_;
  79         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  80                 die "failed to open lock $self->{lock_path}: $!\n";
  81         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  82         $self->{lockfh} = $lockfh;
  83 }
  84
  85 sub _lock_release {
  86         my ($self) = @_;
  87         my $lockfh = delete $self->{lockfh};
  88         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  89         close $lockfh or die "close failed: $!\n";
  90 }
  91
  92 sub add_val {
  93         my ($doc, $col, $num) = @_;
  94         $num = Search::Xapian::sortable_serialise($num);
  95         $doc->add_value($col, $num);
  96 }
  97
  98 sub add_message {
  99         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 100         my $db = $self->{xdb};
 101
 102         my ($doc_id, $old_tid);
 103         my $mid = mid_clean(mid_mime($mime));
 104         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
 105
 106         eval {
 107                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 108                 my $smsg = $self->lookup_message($mid);
 109                 if ($smsg) {
 110                         # convert a ghost to a regular message
 111                         # it will also clobber any existing regular message
 112                         $doc_id = $smsg->doc_id;
 113                         $old_tid = $smsg->thread_id;
 114                 }
 115                 $smsg = PublicInbox::SearchMsg->new($mime);
 116                 my $doc = $smsg->{doc};
 117                 $doc->add_term(xpfx('mid') . $mid);
 118
 119                 my $subj = $smsg->subject;
 120                 if ($subj ne '') {
 121                         my $path = $self->subject_path($subj);
 122                         $doc->add_term(xpfx('path') . id_compress($path));
 123                 }
 124
 125                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
 126
 127                 defined($num) and
 128                         add_val($doc, &PublicInbox::Search::NUM, $num);
 129
 130                 defined($bytes) and
 131                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 132
 133                 add_val($doc, &PublicInbox::Search::LINES,
 134                                 $mime->body_raw =~ tr!\n!\n!);
 135
 136                 my $tg = $self->term_generator;
 137
 138                 $tg->set_document($doc);
 139                 $tg->index_text($subj, 1, 'S') if $subj;
 140                 $tg->increase_termpos;
 141                 $tg->index_text($subj) if $subj;
 142                 $tg->increase_termpos;
 143
 144                 $tg->index_text($smsg->from);
 145                 $tg->increase_termpos;
 146
 147                 msg_iter($mime, sub {
 148                         my ($part, $depth, @idx) = @{$_[0]};
 149                         my $ct = $part->content_type || $ct_msg;
 150
 151                         # account for filter bugs...
 152                         $ct =~ m!\btext/plain\b!i or return;
 153
 154                         my (@orig, @quot);
 155                         my $body = $part->body;
 156                         $part->body_set('');
 157                         my @lines = split(/\n/, $body);
 158                         while (defined(my $l = shift @lines)) {
 159                                 if ($l =~ /^\s*>/) {
 160                                         push @quot, $l;
 161                                 } else {
 162                                         push @orig, $l;
 163                                 }
 164                         }
 165                         if (@quot) {
 166                                 $tg->index_text(join("\n", @quot), 0);
 167                                 @quot = ();
 168                                 $tg->increase_termpos;
 169                         }
 170                         if (@orig) {
 171                                 $tg->index_text(join("\n", @orig));
 172                                 @orig = ();
 173                                 $tg->increase_termpos;
 174                         }
 175                 });
 176
 177                 link_message($self, $smsg, $old_tid);
 178                 $doc->set_data($smsg->to_doc_data($blob));
 179                 if (defined $doc_id) {
 180                         $db->replace_document($doc_id, $doc);
 181                 } else {
 182                         $doc_id = $db->add_document($doc);
 183                 }
 184         };
 185
 186         if ($@) {
 187                 warn "failed to index message <$mid>: $@\n";
 188                 return undef;
 189         }
 190         $doc_id;
 191 }
 192
 193 # returns deleted doc_id on success, undef on missing
 194 sub remove_message {
 195         my ($self, $mid) = @_;
 196         my $db = $self->{xdb};
 197         my $doc_id;
 198         $mid = mid_clean($mid);
 199
 200         eval {
 201                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 202                 $db->delete_document($doc_id) if defined $doc_id;
 203         };
 204
 205         if ($@) {
 206                 warn "failed to remove message <$mid>: $@\n";
 207                 return undef;
 208         }
 209         $doc_id;
 210 }
 211
 212 sub term_generator { # write-only
 213         my ($self) = @_;
 214
 215         my $tg = $self->{term_generator};
 216         return $tg if $tg;
 217
 218         $tg = Search::Xapian::TermGenerator->new;
 219         $tg->set_stemmer($self->stemmer);
 220
 221         $self->{term_generator} = $tg;
 222 }
 223
 224 # increments last_thread_id counter
 225 # returns a 64-bit integer represented as a hex string
 226 sub next_thread_id {
 227         my ($self) = @_;
 228         my $db = $self->{xdb};
 229         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 230
 231         $db->set_metadata('last_thread_id', ++$last_thread_id);
 232
 233         $last_thread_id;
 234 }
 235
 236 sub link_message {
 237         my ($self, $smsg, $old_tid) = @_;
 238         my $doc = $smsg->{doc};
 239         my $mid = $smsg->mid;
 240         my $mime = $smsg->mime;
 241         my $hdr = $mime->header_obj;
 242         my $refs = $hdr->header_raw('References');
 243         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 244         if (my $irt = $hdr->header_raw('In-Reply-To')) {
 245                 # last References should be $irt
 246                 # we will de-dupe later
 247                 push @refs, mid_clean($irt);
 248         }
 249
 250         my $tid;
 251         if (@refs) {
 252                 my %uniq = ($mid => 1);
 253                 my @orig_refs = @refs;
 254                 @refs = ();
 255
 256                 # prevent circular references via References: here:
 257                 foreach my $ref (@orig_refs) {
 258                         if (length($ref) > MAX_MID_SIZE) {
 259                                 warn "References: <$ref> too long, ignoring\n";
 260                         }
 261                         next if $uniq{$ref};
 262                         $uniq{$ref} = 1;
 263                         push @refs, $ref;
 264                 }
 265         }
 266         if (@refs) {
 267                 $smsg->{references} = '<'.join('> <', @refs).'>';
 268
 269                 # first ref *should* be the thread root,
 270                 # but we can never trust clients to do the right thing
 271                 my $ref = shift @refs;
 272                 $tid = $self->_resolve_mid_to_tid($ref);
 273                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 274
 275                 # the rest of the refs should point to this tid:
 276                 foreach $ref (@refs) {
 277                         my $ptid = $self->_resolve_mid_to_tid($ref);
 278                         merge_threads($self, $tid, $ptid);
 279                 }
 280         } else {
 281                 $tid = $self->next_thread_id;
 282         }
 283         $doc->add_term(xpfx('thread') . $tid);
 284 }
 285
 286 sub index_blob {
 287         my ($self, $mime, $bytes, $num, $blob) = @_;
 288         $self->add_message($mime, $bytes, $num, $blob);
 289 }
 290
 291 sub unindex_blob {
 292         my ($self, $mime) = @_;
 293         my $mid = eval { mid_clean(mid_mime($mime)) };
 294         $self->remove_message($mid) if defined $mid;
 295 }
 296
 297 sub index_mm {
 298         my ($self, $mime) = @_;
 299         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 300 }
 301
 302 sub unindex_mm {
 303         my ($self, $mime) = @_;
 304         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 305 }
 306
 307 sub index_mm2 {
 308         my ($self, $mime, $bytes, $blob) = @_;
 309         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 310         index_blob($self, $mime, $bytes, $num, $blob);
 311 }
 312
 313 sub unindex_mm2 {
 314         my ($self, $mime) = @_;
 315         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 316         unindex_blob($self, $mime);
 317 }
 318
 319 sub index_both {
 320         my ($self, $mime, $bytes, $blob) = @_;
 321         my $num = index_mm($self, $mime);
 322         index_blob($self, $mime, $bytes, $num, $blob);
 323 }
 324
 325 sub unindex_both {
 326         my ($self, $mime) = @_;
 327         unindex_blob($self, $mime);
 328         unindex_mm($self, $mime);
 329 }
 330
 331 sub do_cat_mail {
 332         my ($git, $blob, $sizeref) = @_;
 333         my $mime = eval {
 334                 my $str = $git->cat_file($blob, $sizeref);
 335                 # fixup bugs from import:
 336                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 337                 Email::MIME->new($str);
 338         };
 339         $@ ? undef : $mime;
 340 }
 341
 342 sub index_sync {
 343         my ($self, $opts) = @_;
 344         with_umask($self, sub { $self->_index_sync($opts) });
 345 }
 346
 347 sub rlog {
 348         my ($self, $range, $add_cb, $del_cb, $batch_cb) = @_;
 349         my $hex = '[a-f0-9]';
 350         my $h40 = $hex .'{40}';
 351         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 352         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 353         my $git = $self->{git};
 354         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 355                                 --raw -r --no-abbrev/, $range);
 356         my $latest;
 357         my $bytes;
 358         my $max = $self->{batch_size}; # may be undef
 359         local $/ = "\n";
 360         my $line;
 361         while (defined($line = <$log>)) {
 362                 if ($line =~ /$addmsg/o) {
 363                         my $blob = $1;
 364                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 365                         $add_cb->($self, $mime, $bytes, $blob);
 366                 } elsif ($line =~ /$delmsg/o) {
 367                         my $blob = $1;
 368                         my $mime = do_cat_mail($git, $blob) or next;
 369                         $del_cb->($self, $mime);
 370                 } elsif ($line =~ /^commit ($h40)/o) {
 371                         if (defined $max && --$max <= 0) {
 372                                 $max = $self->{batch_size};
 373                                 $batch_cb->($latest, 1);
 374                         }
 375                         $latest = $1;
 376                 }
 377         }
 378         $batch_cb->($latest, 0);
 379 }
 380
 381 # indexes all unindexed messages
 382 sub _index_sync {
 383         my ($self, $opts) = @_;
 384         my $tip = $opts->{ref} || 'HEAD';
 385         my $mm = $self->{mm} = eval {
 386                 require PublicInbox::Msgmap;
 387                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 388         };
 389         my $xdb = $self->{xdb};
 390         $xdb->begin_transaction;
 391         my $reindex = $opts->{reindex};
 392         my $mkey = 'last_commit';
 393         my $last_commit = $xdb->get_metadata($mkey);
 394         my $lx = $last_commit;
 395         if ($reindex) {
 396                 $lx = '';
 397                 $mkey = undef if $last_commit ne '';
 398         }
 399         my $dbh;
 400         my $cb = sub {
 401                 my ($commit, $more) = @_;
 402                 $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 403                 if ($dbh) {
 404                         $mm->last_commit($commit) if $commit;
 405                         $dbh->commit;
 406                 }
 407                 if ($XAP_LOCK_BROKEN) {
 408                         $xdb->commit_transaction if !$more;
 409                 } else {
 410                         $xdb = undef;
 411                         _xdb_release($self);
 412                         _lock_release($self);
 413                 }
 414                 # let another process do some work...
 415                 if (!$XAP_LOCK_BROKEN) {
 416                         _lock_acquire($self);
 417                         $dbh->begin_work if $dbh && $more;
 418                         $xdb = _xdb_acquire($self, $more);
 419                 }
 420         };
 421
 422         my $range = $lx eq '' ? $tip : "$lx..$tip";
 423         if ($mm) {
 424                 $dbh = $mm->{dbh};
 425                 $dbh->begin_work;
 426                 my $lm = $mm->last_commit || '';
 427                 if ($lm eq $lx) {
 428                         # Common case is the indexes are synced,
 429                         # we only need to run git-log once:
 430                         rlog($self, $range, *index_both, *unindex_both, $cb);
 431                 } else {
 432                         # Uncommon case, msgmap and xapian are out-of-sync
 433                         # do not care for performance (but git is fast :>)
 434                         # This happens if we have to reindex Xapian since
 435                         # msgmap is a frozen format and our Xapian format
 436                         # is evolving.
 437                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 438
 439                         # first, ensure msgmap is up-to-date:
 440                         my $mkey_prev = $mkey;
 441                         $mkey = undef; # ignore xapian, for now
 442                         rlog($self, $r, *index_mm, *unindex_mm, $cb);
 443
 444                         # now deal with Xapian
 445                         $mkey = $mkey_prev;
 446                         $dbh = undef;
 447                         rlog($self, $range, *index_mm2, *unindex_mm2, $cb);
 448                 }
 449         } else {
 450                 # user didn't install DBD::SQLite and DBI
 451                 rlog($self, $range, *index_blob, *unindex_blob, $cb);
 452         }
 453 }
 454
 455 # this will create a ghost as necessary
 456 sub _resolve_mid_to_tid {
 457         my ($self, $mid) = @_;
 458
 459         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 460         $smsg->thread_id;
 461 }
 462
 463 sub create_ghost {
 464         my ($self, $mid) = @_;
 465
 466         my $tid = $self->next_thread_id;
 467         my $doc = Search::Xapian::Document->new;
 468         $doc->add_term(xpfx('mid') . $mid);
 469         $doc->add_term(xpfx('thread') . $tid);
 470         $doc->add_term(xpfx('type') . 'ghost');
 471
 472         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 473         $self->{xdb}->add_document($doc);
 474
 475         $smsg;
 476 }
 477
 478 sub merge_threads {
 479         my ($self, $winner_tid, $loser_tid) = @_;
 480         return if $winner_tid == $loser_tid;
 481         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 482         my $thread_pfx = xpfx('thread');
 483         my $db = $self->{xdb};
 484
 485         for (; $head != $tail; $head->inc) {
 486                 my $docid = $head->get_docid;
 487                 my $doc = $db->get_document($docid);
 488                 $doc->remove_term($thread_pfx . $loser_tid);
 489                 $doc->add_term($thread_pfx . $winner_tid);
 490                 $db->replace_document($docid, $doc);
 491         }
 492 }
 493
 494 sub _read_git_config_perm {
 495         my ($self) = @_;
 496         my @cmd = qw(config core.sharedRepository);
 497         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 498         local $/ = "\n";
 499         my $perm = <$fh>;
 500         chomp $perm if defined $perm;
 501         $perm;
 502 }
 503
 504 sub _git_config_perm {
 505         my $self = shift;
 506         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 507         return PERM_GROUP if (!defined($perm) || $perm eq '');
 508         return PERM_UMASK if ($perm eq 'umask');
 509         return PERM_GROUP if ($perm eq 'group');
 510         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 511                 return PERM_EVERYBODY;
 512         }
 513         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 514         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 515
 516         my $i = oct($perm);
 517         return PERM_UMASK if ($i == PERM_UMASK);
 518         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 519         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 520
 521         if (($i & 0600) != 0600) {
 522                 die "core.sharedRepository mode invalid: ".
 523                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 524         }
 525         ($i & 0666);
 526 }
 527
 528 sub _umask_for {
 529         my ($perm) = @_; # _git_config_perm return value
 530         my $rv = $perm;
 531         return umask if $rv == 0;
 532
 533         # set +x bit if +r or +w were set
 534         $rv |= 0100 if ($rv & 0600);
 535         $rv |= 0010 if ($rv & 0060);
 536         $rv |= 0001 if ($rv & 0006);
 537         (~$rv & 0777);
 538 }
 539
 540 sub with_umask {
 541         my ($self, $cb) = @_;
 542         my $old = umask $self->{umask};
 543         my $rv = eval { $cb->() };
 544         my $err = $@;
 545         umask $old;
 546         die $err if $@;
 547         $rv;
 548 }
 549
 550 sub DESTROY {
 551         # order matters for unlocking
 552         $_[0]->{xdb} = undef;
 553         $_[0]->{lockfh} = undef;
 554 }
 555
 556 1;