lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search);
  13 use PublicInbox::MID qw/mid_clean id_compress/;
  14 *xpfx = *PublicInbox::Search::xpfx;
  15
  16 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  17 use constant {
  18         PERM_UMASK => 0,
  19         OLD_PERM_GROUP => 1,
  20         OLD_PERM_EVERYBODY => 2,
  21         PERM_GROUP => 0660,
  22         PERM_EVERYBODY => 0664,
  23 };
  24
  25 sub new {
  26         my ($class, $git_dir, $writable) = @_;
  27         my $dir = $class->xdir($git_dir);
  28         require Search::Xapian::WritableDatabase;
  29         my $flag = Search::Xapian::DB_OPEN;
  30         my $self = bless { git_dir => $git_dir }, $class;
  31         my $perm = $self->_git_config_perm;
  32         my $umask = _umask_for($perm);
  33         $self->{umask} = $umask;
  34         $self->{xdb} = $self->with_umask(sub {
  35                 if ($writable == 1) {
  36                         require File::Path;
  37                         File::Path::mkpath($dir);
  38                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  39                 }
  40                 Search::Xapian::WritableDatabase->new($dir, $flag);
  41         });
  42         $self;
  43 }
  44
  45 sub add_val {
  46         my ($doc, $col, $num) = @_;
  47         $num = Search::Xapian::sortable_serialise($num);
  48         $doc->add_value($col, $num);
  49 }
  50
  51 sub add_message {
  52         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  53         my $db = $self->{xdb};
  54
  55         my $doc_id;
  56         my $mid = mid_clean($mime->header('Message-ID'));
  57         my $was_ghost = 0;
  58         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  59
  60         eval {
  61                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  62                 my $smsg = $self->lookup_message($mid);
  63                 my $doc;
  64
  65                 if ($smsg) {
  66                         $smsg->ensure_metadata;
  67                         # convert a ghost to a regular message
  68                         # it will also clobber any existing regular message
  69                         $smsg->mime($mime);
  70                         $doc = $smsg->{doc};
  71
  72                         my $type = xpfx('type');
  73                         eval {
  74                                 $doc->remove_term($type . 'ghost');
  75                                 $was_ghost = 1;
  76                         };
  77
  78                         # probably does not exist:
  79                         eval { $doc->remove_term($type . 'mail') };
  80                         $doc->add_term($type . 'mail');
  81                 }  else {
  82                         $smsg = PublicInbox::SearchMsg->new($mime);
  83                         $doc = $smsg->{doc};
  84                         $doc->add_term(xpfx('mid') . $mid);
  85                 }
  86
  87                 my $subj = $smsg->subject;
  88
  89                 if ($subj ne '') {
  90                         my $path = $self->subject_path($subj);
  91                         $doc->add_term(xpfx('path') . id_compress($path));
  92                 }
  93
  94                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  95
  96                 defined($num) and
  97                         add_val($doc, &PublicInbox::Search::NUM, $num);
  98
  99                 defined($bytes) and
 100                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 101
 102                 add_val($doc, &PublicInbox::Search::LINES,
 103                                 $mime->body_raw =~ tr!\n!\n!);
 104
 105                 my $tg = $self->term_generator;
 106
 107                 $tg->set_document($doc);
 108                 $tg->index_text($subj, 1, 'S') if $subj;
 109                 $tg->increase_termpos;
 110                 $tg->index_text($subj) if $subj;
 111                 $tg->increase_termpos;
 112
 113                 $tg->index_text($smsg->from);
 114                 $tg->increase_termpos;
 115
 116                 $mime->walk_parts(sub {
 117                         my ($part) = @_;
 118                         return if $part->subparts; # walk_parts already recurses
 119                         my $ct = $part->content_type || $ct_msg;
 120
 121                         # account for filter bugs...
 122                         $ct =~ m!\btext/plain\b!i or return;
 123
 124                         my (@orig, @quot);
 125                         my $body = $part->body;
 126                         $part->body_set('');
 127                         my @lines = split(/\n/, $body);
 128                         while (defined(my $l = shift @lines)) {
 129                                 if ($l =~ /^\s*>/) {
 130                                         push @quot, $l;
 131                                 } else {
 132                                         push @orig, $l;
 133                                 }
 134                         }
 135                         if (@quot) {
 136                                 $tg->index_text(join("\n", @quot), 0);
 137                                 @quot = ();
 138                                 $tg->increase_termpos;
 139                         }
 140                         if (@orig) {
 141                                 $tg->index_text(join("\n", @orig));
 142                                 @orig = ();
 143                                 $tg->increase_termpos;
 144                         }
 145                 });
 146
 147                 if ($was_ghost) {
 148                         $doc_id = $smsg->doc_id;
 149                         $self->link_message($smsg, 0);
 150                         $doc->set_data($smsg->to_doc_data);
 151                         $db->replace_document($doc_id, $doc);
 152                 } else {
 153                         $self->link_message($smsg, 0);
 154                         $doc->set_data($smsg->to_doc_data);
 155                         $doc_id = $db->add_document($doc);
 156                 }
 157         };
 158
 159         if ($@) {
 160                 warn "failed to index message <$mid>: $@\n";
 161                 return undef;
 162         }
 163         $doc_id;
 164 }
 165
 166 # returns deleted doc_id on success, undef on missing
 167 sub remove_message {
 168         my ($self, $mid) = @_;
 169         my $db = $self->{xdb};
 170         my $doc_id;
 171         $mid = mid_clean($mid);
 172
 173         eval {
 174                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 175                 $db->delete_document($doc_id) if defined $doc_id;
 176         };
 177
 178         if ($@) {
 179                 warn "failed to remove message <$mid>: $@\n";
 180                 return undef;
 181         }
 182         $doc_id;
 183 }
 184
 185 sub term_generator { # write-only
 186         my ($self) = @_;
 187
 188         my $tg = $self->{term_generator};
 189         return $tg if $tg;
 190
 191         $tg = Search::Xapian::TermGenerator->new;
 192         $tg->set_stemmer($self->stemmer);
 193
 194         $self->{term_generator} = $tg;
 195 }
 196
 197 # increments last_thread_id counter
 198 # returns a 64-bit integer represented as a hex string
 199 sub next_thread_id {
 200         my ($self) = @_;
 201         my $db = $self->{xdb};
 202         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 203
 204         $db->set_metadata('last_thread_id', ++$last_thread_id);
 205
 206         $last_thread_id;
 207 }
 208
 209 sub link_message {
 210         my ($self, $smsg, $is_ghost) = @_;
 211
 212         if ($is_ghost) {
 213                 $smsg->ensure_metadata;
 214         } else {
 215                 $self->link_message_to_parents($smsg);
 216         }
 217 }
 218
 219 sub link_message_to_parents {
 220         my ($self, $smsg) = @_;
 221         my $doc = $smsg->{doc};
 222         my $mid = $smsg->mid;
 223         my $mime = $smsg->mime;
 224         my $refs = $mime->header('References');
 225         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 226         if (my $irt = $mime->header('In-Reply-To')) {
 227                 # last References should be $irt
 228                 # we will de-dupe later
 229                 push @refs, mid_clean($irt);
 230         }
 231
 232         my $tid;
 233         if (@refs) {
 234                 my %uniq = ($mid => 1);
 235                 my @orig_refs = @refs;
 236                 @refs = ();
 237
 238                 # prevent circular references via References: here:
 239                 foreach my $ref (@orig_refs) {
 240                         if (length($ref) > MAX_MID_SIZE) {
 241                                 warn "References: <$ref> too long, ignoring\n";
 242                         }
 243                         next if $uniq{$ref};
 244                         $uniq{$ref} = 1;
 245                         push @refs, $ref;
 246                 }
 247         }
 248         if (@refs) {
 249                 $smsg->{references} = '<'.join('> <', @refs).'>';
 250
 251                 # first ref *should* be the thread root,
 252                 # but we can never trust clients to do the right thing
 253                 my $ref = shift @refs;
 254                 $tid = $self->_resolve_mid_to_tid($ref);
 255
 256                 # the rest of the refs should point to this tid:
 257                 foreach $ref (@refs) {
 258                         my $ptid = $self->_resolve_mid_to_tid($ref);
 259                         if ($tid ne $ptid) {
 260                                 $self->merge_threads($tid, $ptid);
 261                         }
 262                 }
 263         } else {
 264                 $tid = $self->next_thread_id;
 265         }
 266         $doc->add_term(xpfx('thread') . $tid);
 267 }
 268
 269 sub index_blob {
 270         my ($self, $git, $mime, $bytes, $num) = @_;
 271         $self->add_message($mime, $bytes, $num);
 272 }
 273
 274 sub unindex_blob {
 275         my ($self, $git, $mime) = @_;
 276         my $mid = mid_clean($mime->header('Message-ID'));
 277         $self->remove_message($mid) if defined $mid;
 278 }
 279
 280 sub index_mm {
 281         my ($self, $git, $mime) = @_;
 282         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 283 }
 284
 285 sub unindex_mm {
 286         my ($self, $git, $mime) = @_;
 287         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 288 }
 289
 290 sub index_mm2 {
 291         my ($self, $git, $mime, $bytes) = @_;
 292         my $num = $self->{mm}->num_for(mid_clean($mime->header('Message-ID')));
 293         index_blob($self, $git, $mime, $bytes, $num);
 294 }
 295
 296 sub unindex_mm2 {
 297         my ($self, $git, $mime) = @_;
 298         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 299         unindex_blob($self, $git, $mime);
 300 }
 301
 302 sub index_both {
 303         my ($self, $git, $mime, $bytes) = @_;
 304         my $num = index_mm($self, $git, $mime);
 305         index_blob($self, $git, $mime, $bytes, $num);
 306 }
 307
 308 sub unindex_both {
 309         my ($self, $git, $mime) = @_;
 310         unindex_blob($self, $git, $mime);
 311         unindex_mm($self, $git, $mime);
 312 }
 313
 314 sub do_cat_mail {
 315         my ($git, $blob, $sizeref) = @_;
 316         my $mime = eval {
 317                 my $str = $git->cat_file($blob, $sizeref);
 318                 Email::MIME->new($str);
 319         };
 320         $@ ? undef : $mime;
 321 }
 322
 323 sub index_sync {
 324         my ($self, $head) = @_;
 325         $self->with_umask(sub { $self->_index_sync($head) });
 326 }
 327
 328 sub rlog {
 329         my ($self, $range, $add_cb, $del_cb) = @_;
 330         my $hex = '[a-f0-9]';
 331         my $h40 = $hex .'{40}';
 332         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 333         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 334         my $git_dir = $self->{git_dir};
 335         require PublicInbox::GitCatFile;
 336         my $git = PublicInbox::GitCatFile->new($git_dir);
 337         my @cmd = ('git', "--git-dir=$git_dir", "log",
 338                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 339                     $range);
 340         my $latest;
 341         my $bytes;
 342         my $pid = open(my $log, '-|', @cmd) or
 343                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 344         while (my $line = <$log>) {
 345                 if ($line =~ /$addmsg/o) {
 346                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 347                         $add_cb->($self, $git, $mime, $bytes);
 348                 } elsif ($line =~ /$delmsg/o) {
 349                         my $mime = do_cat_mail($git, $1) or next;
 350                         $del_cb->($self, $git, $mime);
 351                 } elsif ($line =~ /^commit ($h40)/o) {
 352                         $latest = $1;
 353                 }
 354         }
 355         close $log;
 356         $latest;
 357 }
 358
 359 # indexes all unindexed messages
 360 sub _index_sync {
 361         my ($self, $head) = @_;
 362         my $db = $self->{xdb};
 363         $head ||= 'HEAD';
 364         my $mm = $self->{mm} = eval {
 365                 require PublicInbox::Msgmap;
 366                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 367         };
 368
 369         $db->begin_transaction;
 370         my $lx = $db->get_metadata('last_commit');
 371         my $range = $lx eq '' ? $head : "$lx..$head";
 372         if ($mm) {
 373                 $mm->{dbh}->begin_work;
 374                 my $lm = $mm->last_commit || '';
 375                 if ($lm eq $lx) {
 376                         # Common case is the indexes are synced,
 377                         # we only need to run git-log once:
 378                         $lx = $self->rlog($range, *index_both, *unindex_both);
 379                         $mm->{dbh}->commit;
 380                         if (defined $lx) {
 381                                 $db->set_metadata('last_commit', $lx);
 382                                 $mm->last_commit($lx);
 383                         }
 384                 } else {
 385                         # dumb case, msgmap and xapian are out-of-sync
 386                         # do not care for performance:
 387                         my $r = $lm eq '' ? $head : "$lm..$head";
 388                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 389                         $mm->{dbh}->commit;
 390                         $mm->last_commit($lm) if defined $lm;
 391
 392                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 393                         $db->set_metadata('last_commit', $lx) if defined $lx;
 394                 }
 395         } else {
 396                 # user didn't install DBD::SQLite and DBI
 397                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 398                 $db->set_metadata('last_commit', $lx) if defined $lx;
 399         }
 400         if ($@) {
 401                 $db->cancel_transaction;
 402                 $mm->{dbh}->rollback if $mm;
 403         } else {
 404                 $db->commit_transaction;
 405         }
 406 }
 407
 408 # this will create a ghost as necessary
 409 sub _resolve_mid_to_tid {
 410         my ($self, $mid) = @_;
 411
 412         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 413         $smsg->thread_id;
 414 }
 415
 416 sub create_ghost {
 417         my ($self, $mid, $tid) = @_;
 418
 419         $tid = $self->next_thread_id unless defined $tid;
 420
 421         my $doc = Search::Xapian::Document->new;
 422         $doc->add_term(xpfx('mid') . $mid);
 423         $doc->add_term(xpfx('thread') . $tid);
 424         $doc->add_term(xpfx('type') . 'ghost');
 425
 426         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 427         $self->link_message($smsg, 1);
 428         $self->{xdb}->add_document($doc);
 429
 430         $smsg;
 431 }
 432
 433 sub merge_threads {
 434         my ($self, $winner_tid, $loser_tid) = @_;
 435         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 436         my $thread_pfx = xpfx('thread');
 437         my $db = $self->{xdb};
 438
 439         for (; $head != $tail; $head->inc) {
 440                 my $docid = $head->get_docid;
 441                 my $doc = $db->get_document($docid);
 442                 $doc->remove_term($thread_pfx . $loser_tid);
 443                 $doc->add_term($thread_pfx . $winner_tid);
 444                 $db->replace_document($docid, $doc);
 445         }
 446 }
 447
 448 sub _read_git_config_perm {
 449         my ($self) = @_;
 450         my @cmd = ('git', "--git-dir=$self->{git_dir}",
 451                    qw(config core.sharedRepository));
 452         my $pid = open(my $fh, '-|', @cmd) or
 453                 die('open `'.join(' ', @cmd) . " pipe failed: $!\n");
 454         my $perm = <$fh>;
 455         close $fh;
 456         chomp $perm if defined $perm;
 457         $perm;
 458 }
 459
 460 sub _git_config_perm {
 461         my $self = shift;
 462         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 463         return PERM_GROUP if (!defined($perm) || $perm eq '');
 464         return PERM_UMASK if ($perm eq 'umask');
 465         return PERM_GROUP if ($perm eq 'group');
 466         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 467                 return PERM_EVERYBODY;
 468         }
 469         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 470         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 471
 472         my $i = oct($perm);
 473         return PERM_UMASK if ($i == PERM_UMASK);
 474         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 475         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 476
 477         if (($i & 0600) != 0600) {
 478                 die "core.sharedRepository mode invalid: ".
 479                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 480         }
 481         ($i & 0666);
 482 }
 483
 484 sub _umask_for {
 485         my ($perm) = @_; # _git_config_perm return value
 486         my $rv = $perm;
 487         return umask if $rv == 0;
 488
 489         # set +x bit if +r or +w were set
 490         $rv |= 0100 if ($rv & 0600);
 491         $rv |= 0010 if ($rv & 0060);
 492         $rv |= 0001 if ($rv & 0006);
 493         (~$rv & 0777);
 494 }
 495
 496 sub with_umask {
 497         my ($self, $cb) = @_;
 498         my $old = umask $self->{umask};
 499         my $rv = eval { $cb->() };
 500         my $err = $@;
 501         umask $old;
 502         die $err if $@;
 503         $rv;
 504 }
 505
 506 1;