lib/PublicInbox/SearchIdxShard.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Internal interface for a single Xapian shard in V2 inboxes.
   5 # See L<public-inbox-v2-format(5)> for more info on how we shard Xapian
   6 package PublicInbox::SearchIdxShard;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::SearchIdx);
  10 use bytes qw(length);
  11 use IO::Handle (); # autoflush
  12 use PublicInbox::Eml;
  13 use PublicInbox::Sigfd;
  14
  15 sub new {
  16         my ($class, $v2w, $shard) = @_; # v2w may be ExtSearchIdx
  17         my $ibx = $v2w->{ibx};
  18         my $self = $ibx ? $class->SUPER::new($ibx, 1, $shard)
  19                         : $class->eidx_shard_new($v2w, $shard);
  20         # create the DB before forking:
  21         $self->idx_acquire;
  22         $self->set_metadata_once;
  23         $self->idx_release;
  24         $self->spawn_worker($v2w, $shard) if $v2w->{parallel};
  25         $self;
  26 }
  27
  28 sub spawn_worker {
  29         my ($self, $v2w, $shard) = @_;
  30         my ($r, $w);
  31         pipe($r, $w) or die "pipe failed: $!\n";
  32         $w->autoflush(1);
  33         my $oldset = PublicInbox::Sigfd::block_signals();
  34         my $pid = fork;
  35         defined $pid or die "fork failed: $!\n";
  36         if ($pid == 0) {
  37                 # these signals are localized in parent
  38                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
  39                 PublicInbox::Sigfd::sig_setmask($oldset);
  40                 my $bnote = $v2w->atfork_child;
  41                 close $w or die "failed to close: $!";
  42
  43                 # F_SETPIPE_SZ = 1031 on Linux; increasing the pipe size here
  44                 # speeds V2Writable batch imports across 8 cores by nearly 20%
  45                 fcntl($r, 1031, 1048576) if $^O eq 'linux';
  46
  47                 eval { shard_worker_loop($self, $v2w, $r, $shard, $bnote) };
  48                 die "worker $shard died: $@\n" if $@;
  49                 die "unexpected MM $self->{mm}" if $self->{mm};
  50                 exit;
  51         }
  52         PublicInbox::Sigfd::sig_setmask($oldset);
  53         $self->{pid} = $pid;
  54         $self->{w} = $w;
  55         close $r or die "failed to close: $!";
  56 }
  57
  58 sub eml ($$) {
  59         my ($r, $len) = @_;
  60         return if $len == 0;
  61         my $n = read($r, my $bref, $len) or die "read: $!\n";
  62         $n == $len or die "short read: $n != $len\n";
  63         PublicInbox::Eml->new(\$bref);
  64 }
  65
  66 # this reads all the writes to $self->{w} from the parent process
  67 sub shard_worker_loop ($$$$$) {
  68         my ($self, $v2w, $r, $shard, $bnote) = @_;
  69         $0 = "shard[$shard]";
  70         $self->begin_txn_lazy;
  71         while (my $line = readline($r)) {
  72                 chomp $line;
  73                 $v2w->{current_info} = "[$shard] $line";
  74                 if ($line eq 'commit') {
  75                         $self->commit_txn_lazy;
  76                 } elsif ($line eq 'close') {
  77                         $self->idx_release;
  78                 } elsif ($line eq 'barrier') {
  79                         $self->commit_txn_lazy;
  80                         # no need to lock < 512 bytes is atomic under POSIX
  81                         print $bnote "barrier $shard\n" or
  82                                         die "write failed for barrier $!\n";
  83                 } elsif ($line =~ /\AD ([0-9]+)\z/s) {
  84                         $self->remove_by_docid($1 + 0);
  85                 } elsif ($line =~ s/\A\+X //) {
  86                         my ($len, $docid, $eidx_key) = split(/ /, $line, 3);
  87                         $self->add_eidx_info($docid, $eidx_key, eml($r, $len));
  88                 } elsif ($line =~ s/\A-X //) {
  89                         my ($len, $docid, $eidx_key) = split(/ /, $line, 3);
  90                         $self->remove_eidx_info($docid, $eidx_key,
  91                                                         eml($r, $len));
  92                 } elsif ($line =~ s/\AO ([^\n]+)//) {
  93                         my $over_fn = $1;
  94                         $over_fn =~ tr/\0/\n/;
  95                         $self->over_check(PublicInbox::Over->new($over_fn));
  96                 } else {
  97                         my $eidx_key;
  98                         if ($line =~ s/\AX=(.+)\0//) {
  99                                 $eidx_key = $1;
 100                                 $v2w->{current_info} =~ s/\0/\\0 /;
 101                         }
 102                         # n.b. $mid may contain spaces(!)
 103                         my ($len, $bytes, $num, $oid, $ds, $ts, $tid, $mid)
 104                                 = split(/ /, $line, 8);
 105                         $self->begin_txn_lazy;
 106                         my $smsg = bless {
 107                                 bytes => $bytes,
 108                                 num => $num + 0,
 109                                 blob => $oid,
 110                                 mid => $mid,
 111                                 tid => $tid,
 112                                 ds => $ds,
 113                                 ts => $ts,
 114                         }, 'PublicInbox::Smsg';
 115                         $smsg->{eidx_key} = $eidx_key if defined($eidx_key);
 116                         $self->add_message(eml($r, $len), $smsg);
 117                 }
 118         }
 119         $self->worker_done;
 120 }
 121
 122 sub index_raw {
 123         my ($self, $msgref, $eml, $smsg, $eidx_key) = @_;
 124         if (my $w = $self->{w}) {
 125                 my @ekey = defined($eidx_key) ? ("X=$eidx_key\0") : ();
 126                 $msgref //= \($eml->as_string);
 127                 $smsg->{raw_bytes} //= length($$msgref);
 128                 # mid must be last, it can contain spaces (but not LF)
 129                 print $w @ekey, join(' ', @$smsg{qw(raw_bytes bytes
 130                                                 num blob ds ts tid mid)}),
 131                         "\n", $$msgref or die "failed to write shard $!\n";
 132         } else {
 133                 if ($eml) {
 134                         undef($$msgref) if $msgref;
 135                 } else { # --xapian-only + --sequential-shard:
 136                         $eml = PublicInbox::Eml->new($msgref);
 137                 }
 138                 $self->begin_txn_lazy;
 139                 $smsg->{eidx_key} = $eidx_key if defined $eidx_key;
 140                 $self->add_message($eml, $smsg);
 141         }
 142 }
 143
 144 sub shard_add_eidx_info {
 145         my ($self, $docid, $eidx_key, $eml) = @_;
 146         if (my $w = $self->{w}) {
 147                 my $hdr = $eml->header_obj->as_string;
 148                 my $len = length($hdr);
 149                 print $w "+X $len $docid $eidx_key\n", $hdr or
 150                         die "failed to write shard: $!";
 151         } else {
 152                 $self->add_eidx_info($docid, $eidx_key, $eml);
 153         }
 154 }
 155
 156 sub shard_remove_eidx_info {
 157         my ($self, $docid, $eidx_key, $eml) = @_;
 158         if (my $w = $self->{w}) {
 159                 my $hdr = $eml ? $eml->header_obj->as_string : '';
 160                 my $len = length($hdr);
 161                 print $w "-X $len $docid $eidx_key\n", $hdr or
 162                         die "failed to write shard: $!";
 163         } else {
 164                 $self->remove_eidx_info($docid, $eidx_key, $eml);
 165         }
 166 }
 167
 168 sub atfork_child {
 169         close $_[0]->{w} or die "failed to close write pipe: $!\n";
 170 }
 171
 172 sub shard_barrier {
 173         my ($self) = @_;
 174         if (my $w = $self->{w}) {
 175                 print $w "barrier\n" or die "failed to print: $!";
 176         } else {
 177                 $self->commit_txn_lazy;
 178         }
 179 }
 180
 181 sub shard_commit {
 182         my ($self) = @_;
 183         if (my $w = $self->{w}) {
 184                 print $w "commit\n" or die "failed to write commit: $!";
 185         } else {
 186                 $self->commit_txn_lazy;
 187         }
 188 }
 189
 190 sub shard_close {
 191         my ($self) = @_;
 192         if (my $w = delete $self->{w}) {
 193                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 194                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 195                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 196                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 197                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 198         } else {
 199                 die "transaction in progress $self\n" if $self->{txn};
 200                 $self->idx_release if $self->{xdb};
 201         }
 202 }
 203
 204 sub shard_remove {
 205         my ($self, $num) = @_;
 206         if (my $w = $self->{w}) { # triggers remove_by_docid in a shard child
 207                 print $w "D $num\n" or die "failed to write remove $!";
 208         } else { # same process
 209                 $self->remove_by_docid($num);
 210         }
 211 }
 212
 213 sub shard_over_check {
 214         my ($self, $over) = @_;
 215         if (my $w = $self->{w}) { # triggers remove_by_docid in a shard child
 216                 my ($over_fn) = $over->{dbh}->sqlite_db_filename;
 217                 $over_fn =~ tr/\n/\0/;
 218                 print $w "O $over_fn\n" or die "failed to write over $!";
 219         } else {
 220                 $self->over_check($over);
 221         }
 222 }
 223
 224 1;