lib/PublicInbox/SearchIdxShard.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # used to interface with a single Xapian shard in V2 repos.
   5 # See L<public-inbox-v2-format(5)> for more info on how we shard Xapian
   6 package PublicInbox::SearchIdxShard;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::SearchIdx);
  10 use IO::Handle (); # autoflush
  11 use PublicInbox::Eml;
  12
  13 sub new {
  14         my ($class, $v2w, $shard) = @_;
  15         my $ibx = $v2w->{ibx};
  16         my $self = $class->SUPER::new($ibx, 1, $shard);
  17         # create the DB before forking:
  18         $self->idx_acquire;
  19         $self->set_metadata_once;
  20         $self->idx_release;
  21         $self->spawn_worker($v2w, $shard) if $v2w->{parallel};
  22         $self;
  23 }
  24
  25 sub spawn_worker {
  26         my ($self, $v2w, $shard) = @_;
  27         my ($r, $w);
  28         pipe($r, $w) or die "pipe failed: $!\n";
  29         $w->autoflush(1);
  30         my $pid = fork;
  31         defined $pid or die "fork failed: $!\n";
  32         if ($pid == 0) {
  33                 my $bnote = $v2w->atfork_child;
  34                 close $w or die "failed to close: $!";
  35
  36                 # F_SETPIPE_SZ = 1031 on Linux; increasing the pipe size here
  37                 # speeds V2Writable batch imports across 8 cores by nearly 20%
  38                 fcntl($r, 1031, 1048576) if $^O eq 'linux';
  39
  40                 eval { shard_worker_loop($self, $v2w, $r, $shard, $bnote) };
  41                 die "worker $shard died: $@\n" if $@;
  42                 die "unexpected MM $self->{mm}" if $self->{mm};
  43                 exit;
  44         }
  45         $self->{pid} = $pid;
  46         $self->{w} = $w;
  47         close $r or die "failed to close: $!";
  48 }
  49
  50 sub shard_worker_loop ($$$$$) {
  51         my ($self, $v2w, $r, $shard, $bnote) = @_;
  52         $0 = "pi-v2-shard[$shard]";
  53         $self->begin_txn_lazy;
  54         while (my $line = readline($r)) {
  55                 $v2w->{current_info} = "[$shard] $line";
  56                 if ($line eq "commit\n") {
  57                         $self->commit_txn_lazy;
  58                 } elsif ($line eq "close\n") {
  59                         $self->idx_release;
  60                 } elsif ($line eq "barrier\n") {
  61                         $self->commit_txn_lazy;
  62                         # no need to lock < 512 bytes is atomic under POSIX
  63                         print $bnote "barrier $shard\n" or
  64                                         die "write failed for barrier $!\n";
  65                 } elsif ($line =~ /\AD ([a-f0-9]{40,}) ([0-9]+)\n\z/s) {
  66                         $self->remove_by_oid($1, $2 + 0);
  67                 } else {
  68                         chomp $line;
  69                         # n.b. $mid may contain spaces(!)
  70                         my ($to_read, $bytes, $num, $blob, $ds, $ts, $mid) =
  71                                                         split(/ /, $line, 7);
  72                         $self->begin_txn_lazy;
  73                         my $n = read($r, my $msg, $to_read) or die "read: $!\n";
  74                         $n == $to_read or die "short read: $n != $to_read\n";
  75                         my $mime = PublicInbox::Eml->new(\$msg);
  76                         my $smsg = bless {
  77                                 bytes => $bytes,
  78                                 num => $num + 0,
  79                                 blob => $blob,
  80                                 mid => $mid,
  81                                 ds => $ds,
  82                                 ts => $ts,
  83                         }, 'PublicInbox::Smsg';
  84                         $self->add_message($mime, $smsg);
  85                 }
  86         }
  87         $self->worker_done;
  88 }
  89
  90 # called by V2Writable
  91 sub index_raw {
  92         my ($self, $msgref, $eml, $smsg) = @_;
  93         if (my $w = $self->{w}) {
  94                 # mid must be last, it can contain spaces (but not LF)
  95                 print $w join(' ', @$smsg{qw(raw_bytes bytes
  96                                                 num blob ds ts mid)}),
  97                         "\n", $$msgref or die "failed to write shard $!\n";
  98         } else {
  99                 if ($eml) {
 100                         undef $$msgref;
 101                 } else { # --xapian-only + --sequential-shard:
 102                         $eml = PublicInbox::Eml->new($msgref);
 103                 }
 104                 $self->begin_txn_lazy;
 105                 $self->add_message($eml, $smsg);
 106         }
 107 }
 108
 109 sub atfork_child {
 110         close $_[0]->{w} or die "failed to close write pipe: $!\n";
 111 }
 112
 113 # called by V2Writable:
 114 sub remote_barrier {
 115         my ($self) = @_;
 116         if (my $w = $self->{w}) {
 117                 print $w "barrier\n" or die "failed to print: $!";
 118         } else {
 119                 $self->commit_txn_lazy;
 120         }
 121 }
 122
 123 1;