lib/PublicInbox/SearchIdxShard.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Internal interface for a single Xapian shard in V2 inboxes.
   5 # See L<public-inbox-v2-format(5)> for more info on how we shard Xapian
   6 package PublicInbox::SearchIdxShard;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::SearchIdx);
  10 use bytes qw(length);
  11 use IO::Handle (); # autoflush
  12 use PublicInbox::Eml;
  13 use PublicInbox::Sigfd;
  14
  15 sub new {
  16         my ($class, $v2w, $shard) = @_; # v2w may be ExtSearchIdx
  17         my $ibx = $v2w->{ibx};
  18         my $self = $ibx ? $class->SUPER::new($ibx, 1, $shard)
  19                         : $class->eidx_shard_new($v2w, $shard);
  20         # create the DB before forking:
  21         $self->idx_acquire;
  22         $self->set_metadata_once;
  23         $self->idx_release;
  24         $self->spawn_worker($v2w, $shard) if $v2w->{parallel};
  25         $self;
  26 }
  27
  28 sub spawn_worker {
  29         my ($self, $v2w, $shard) = @_;
  30         my ($r, $w);
  31         pipe($r, $w) or die "pipe failed: $!\n";
  32         $w->autoflush(1);
  33         my $oldset = PublicInbox::Sigfd::block_signals();
  34         my $pid = fork;
  35         defined $pid or die "fork failed: $!\n";
  36         if ($pid == 0) {
  37                 # these signals are localized in parent
  38                 $SIG{$_} = 'IGNORE' for (qw(TERM INT QUIT));
  39                 PublicInbox::Sigfd::sig_setmask($oldset);
  40                 my $bnote = $v2w->atfork_child;
  41                 close $w or die "failed to close: $!";
  42
  43                 # F_SETPIPE_SZ = 1031 on Linux; increasing the pipe size here
  44                 # speeds V2Writable batch imports across 8 cores by nearly 20%
  45                 fcntl($r, 1031, 1048576) if $^O eq 'linux';
  46
  47                 eval { shard_worker_loop($self, $v2w, $r, $shard, $bnote) };
  48                 die "worker $shard died: $@\n" if $@;
  49                 die "unexpected MM $self->{mm}" if $self->{mm};
  50                 exit;
  51         }
  52         PublicInbox::Sigfd::sig_setmask($oldset);
  53         $self->{pid} = $pid;
  54         $self->{w} = $w;
  55         close $r or die "failed to close: $!";
  56 }
  57
  58 sub eml ($$) {
  59         my ($r, $len) = @_;
  60         my $n = read($r, my $bref, $len) or die "read: $!\n";
  61         $n == $len or die "short read: $n != $len\n";
  62         PublicInbox::Eml->new(\$bref);
  63 }
  64
  65 # this reads all the writes to $self->{w} from the parent process
  66 sub shard_worker_loop ($$$$$) {
  67         my ($self, $v2w, $r, $shard, $bnote) = @_;
  68         $0 = "shard[$shard]";
  69         $self->begin_txn_lazy;
  70         while (my $line = readline($r)) {
  71                 $v2w->{current_info} = "[$shard] $line";
  72                 if ($line eq "commit\n") {
  73                         $self->commit_txn_lazy;
  74                 } elsif ($line eq "close\n") {
  75                         $self->idx_release;
  76                 } elsif ($line eq "barrier\n") {
  77                         $self->commit_txn_lazy;
  78                         # no need to lock < 512 bytes is atomic under POSIX
  79                         print $bnote "barrier $shard\n" or
  80                                         die "write failed for barrier $!\n";
  81                 } elsif ($line =~ /\AD ([a-f0-9]{40,}) ([0-9]+)\n\z/s) {
  82                         $self->remove_by_oid($1, $2 + 0);
  83                 } elsif ($line =~ s/\A\+X //) {
  84                         my ($len, $docid, $oid, $eidx_key) =
  85                                                         split(/ /, $line, 4);
  86                         $self->add_eidx_info($docid, $oid, $eidx_key,
  87                                                         eml($r, $len));
  88                 } elsif ($line =~ s/\A-X //) {
  89                         my ($len, $docid, $oid, $eidx_key) =
  90                                                         split(/ /, $line, 4);
  91                         $self->remove_eidx_info($docid, $oid, $eidx_key,
  92                                                         eml($r, $len));
  93                 } else {
  94                         chomp $line;
  95                         my $eidx_key;
  96                         if ($line =~ s/\AX=(.+)\0//) {
  97                                 $eidx_key = $1;
  98                                 $v2w->{current_info} =~ s/\0/\\0 /;
  99                         }
 100                         # n.b. $mid may contain spaces(!)
 101                         my ($len, $bytes, $num, $oid, $ds, $ts, $tid, $mid)
 102                                 = split(/ /, $line, 8);
 103                         $self->begin_txn_lazy;
 104                         my $smsg = bless {
 105                                 bytes => $bytes,
 106                                 num => $num + 0,
 107                                 blob => $oid,
 108                                 mid => $mid,
 109                                 tid => $tid,
 110                                 ds => $ds,
 111                                 ts => $ts,
 112                         }, 'PublicInbox::Smsg';
 113                         $smsg->{eidx_key} = $eidx_key if defined($eidx_key);
 114                         $self->add_message(eml($r, $len), $smsg);
 115                 }
 116         }
 117         $self->worker_done;
 118 }
 119
 120 sub index_raw {
 121         my ($self, $msgref, $eml, $smsg, $ibx) = @_;
 122         if (my $w = $self->{w}) {
 123                 my @ekey = $ibx ? ('X='.$ibx->eidx_key."\0") : ();
 124                 $msgref //= \($eml->as_string);
 125                 $smsg->{raw_bytes} //= length($$msgref);
 126                 # mid must be last, it can contain spaces (but not LF)
 127                 print $w @ekey, join(' ', @$smsg{qw(raw_bytes bytes
 128                                                 num blob ds ts tid mid)}),
 129                         "\n", $$msgref or die "failed to write shard $!\n";
 130         } else {
 131                 if ($eml) {
 132                         undef($$msgref) if $msgref;
 133                 } else { # --xapian-only + --sequential-shard:
 134                         $eml = PublicInbox::Eml->new($msgref);
 135                 }
 136                 $self->begin_txn_lazy;
 137                 $smsg->{eidx_key} = $ibx->eidx_key if $ibx;
 138                 $self->add_message($eml, $smsg);
 139         }
 140 }
 141
 142 sub shard_add_eidx_info {
 143         my ($self, $docid, $oid, $xibx, $eml) = @_;
 144         my $eidx_key = $xibx->eidx_key;
 145         if (my $w = $self->{w}) {
 146                 my $hdr = $eml->header_obj->as_string;
 147                 my $len = length($hdr);
 148                 print $w "+X $len $docid $oid $eidx_key\n", $hdr or
 149                         die "failed to write shard: $!";
 150         } else {
 151                 $self->add_eidx_info($docid, $oid, $eidx_key, $eml);
 152         }
 153 }
 154
 155 sub shard_remove_eidx_info {
 156         my ($self, $docid, $oid, $xibx, $eml) = @_;
 157         my $eidx_key = $xibx->eidx_key;
 158         if (my $w = $self->{w}) {
 159                 my $hdr = $eml->header_obj->as_string;
 160                 my $len = length($hdr);
 161                 print $w "-X $len $docid $oid $eidx_key\n", $hdr or
 162                         die "failed to write shard: $!";
 163         } else {
 164                 $self->remove_eidx_info($docid, $oid, $eidx_key, $eml);
 165         }
 166 }
 167
 168 sub atfork_child {
 169         close $_[0]->{w} or die "failed to close write pipe: $!\n";
 170 }
 171
 172 sub shard_barrier {
 173         my ($self) = @_;
 174         if (my $w = $self->{w}) {
 175                 print $w "barrier\n" or die "failed to print: $!";
 176         } else {
 177                 $self->commit_txn_lazy;
 178         }
 179 }
 180
 181 sub shard_commit {
 182         my ($self) = @_;
 183         if (my $w = $self->{w}) {
 184                 print $w "commit\n" or die "failed to write commit: $!";
 185         } else {
 186                 $self->commit_txn_lazy;
 187         }
 188 }
 189
 190 sub shard_close {
 191         my ($self) = @_;
 192         if (my $w = delete $self->{w}) {
 193                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 194                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 195                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 196                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 197                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 198         } else {
 199                 die "transaction in progress $self\n" if $self->{txn};
 200                 $self->idx_release if $self->{xdb};
 201         }
 202 }
 203
 204 sub shard_remove {
 205         my ($self, $oid, $num) = @_;
 206         if (my $w = $self->{w}) { # triggers remove_by_oid in a shard child
 207                 print $w "D $oid $num\n" or die "failed to write remove $!";
 208         } else { # same process
 209                 $self->remove_by_oid($oid, $num);
 210         }
 211 }
 212
 213 1;