lib/PublicInbox/SearchIdxSkeleton.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::SearchIdxSkeleton;
   4 use strict;
   5 use warnings;
   6 use base qw(PublicInbox::SearchIdx);
   7 use Storable qw(freeze thaw);
   8
   9 sub new {
  10         my ($class, $v2writable) = @_;
  11         my $self = $class->SUPER::new($v2writable->{-inbox}, 1, 'skel');
  12         # create the DB:
  13         $self->_xdb_acquire;
  14         $self->_xdb_release;
  15
  16         my ($r, $w);
  17         pipe($r, $w) or die "pipe failed: $!\n";
  18         binmode $r, ':raw';
  19         binmode $w, ':raw';
  20         my $pid = fork;
  21         defined $pid or die "fork failed: $!\n";
  22         if ($pid == 0) {
  23                 $v2writable->atfork_child;
  24                 $v2writable = undef;
  25                 close $w;
  26                 eval { skeleton_worker_loop($self, $r) };
  27                 die "skeleton worker died: $@\n" if $@;
  28                 exit;
  29         }
  30         $self->{w} = $w;
  31         $self->{pid} = $pid;
  32         close $r;
  33
  34         $w->autoflush(1);
  35
  36         # lock on only exists in parent, not in worker
  37         my $l = $self->{lock_path} = $self->xdir . '/pi-v2-skeleton.lock';
  38         open my $fh, '>>', $l or die "failed to create $l: $!\n";
  39         $self;
  40 }
  41
  42 sub skeleton_worker_loop {
  43         my ($self, $r) = @_;
  44         $0 = 'pi-v2-skeleton';
  45         my $msg;
  46         my $xdb = $self->_xdb_acquire;
  47         $xdb->begin_transaction;
  48         my $txn = 1;
  49         while (my $line = $r->getline) {
  50                 if ($line eq "commit\n") {
  51                         $xdb->commit_transaction if $txn;
  52                         $txn = undef;
  53                 } elsif ($line eq "close\n") {
  54                         $self->_xdb_release;
  55                         $xdb = $txn = undef;
  56                 } else {
  57                         read($r, $msg, $line) or die "read failed: $!\n";
  58                         $msg = thaw($msg); # should raise on error
  59                         defined $msg or die "failed to thaw buffer\n";
  60                         if (!$txn) {
  61                                 $xdb->begin_transaction;
  62                                 $txn = 1;
  63                         }
  64                         eval { index_skeleton_real($self, $msg) };
  65                         warn "failed to index message <$msg->[-1]>: $@\n" if $@;
  66                 }
  67         }
  68 }
  69
  70 # called by a partition worker
  71 sub index_skeleton {
  72         my ($self, $values) = @_;
  73         my $w = $self->{w};
  74         my $err;
  75         my $str = freeze($values);
  76         $str = length($str) . "\n" . $str;
  77
  78         # multiple processes write to the same pipe, so use flock
  79         $self->_lock_acquire;
  80         print $w $str or $err = $!;
  81         $self->_lock_release;
  82
  83         die "print failed: $err\n" if $err;
  84 }
  85
  86 # values: [ TS, NUM, BYTES, LINES, MID, XPATH, doc_data ]
  87 sub index_skeleton_real ($$) {
  88         my ($self, $values) = @_;
  89         my $doc_data = pop @$values;
  90         my $xpath = pop @$values;
  91         my $mid = pop @$values;
  92         my $ts = $values->[PublicInbox::Search::TS];
  93         my $smsg = $self->lookup_message($mid);
  94         my ($old_tid, $doc_id);
  95         if ($smsg) {
  96                 # convert a ghost to a regular message
  97                 # it will also clobber any existing regular message
  98                 $doc_id = $smsg->{doc_id};
  99                 $old_tid = $smsg->thread_id;
 100         } else {
 101                 $smsg = PublicInbox::SearchMsg->new(undef);
 102                 $smsg->{mid} = $mid;
 103         }
 104         my $doc = $smsg->{doc};
 105         $doc->add_term('XPATH' . $xpath) if defined $xpath;
 106         $doc->add_term('XMID' . $mid);
 107         PublicInbox::SearchIdx::add_values($doc, $values);
 108         $doc->set_data($doc_data);
 109         $smsg->{ts} = $ts;
 110         $smsg->load_from_data($doc_data);
 111         my @refs = ($smsg->references =~ /<([^>]+)>/g);
 112         $self->link_message($smsg, \@refs, $old_tid);
 113         my $db = $self->{xdb};
 114         if (defined $doc_id) {
 115                 $db->replace_document($doc_id, $doc);
 116         } else {
 117                 $doc_id = $db->add_document($doc);
 118         }
 119 }
 120
 121 1;