lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use PublicInbox::Address;
  14 use Encode qw/find_encoding/;
  15 my $enc_utf8 = find_encoding('UTF-8');
  16 our $PFX2TERM_RE = undef;
  17 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  18 use POSIX qw(strftime);
  19
  20 sub new {
  21         my ($class, $mime) = @_;
  22         my $doc = Search::Xapian::Document->new;
  23         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  24
  25         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  26 }
  27
  28 sub wrap {
  29         my ($class, $doc, $mid) = @_;
  30         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  31 }
  32
  33 sub get_val ($$) {
  34         my ($doc, $col) = @_;
  35         Search::Xapian::sortable_unserialise($doc->get_value($col));
  36 }
  37
  38 sub load_doc {
  39         my ($class, $doc) = @_;
  40         my $data = $doc->get_data;
  41         my $ts = get_val($doc, &PublicInbox::Search::TS);
  42         $data = $enc_utf8->decode($data);
  43         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  44         bless {
  45                 doc => $doc,
  46                 subject => $subj,
  47                 ts => $ts,
  48                 from => $from,
  49                 references => $refs,
  50                 to => $to,
  51                 cc => $cc,
  52         }, $class;
  53 }
  54
  55 # :bytes and :lines metadata in RFC 3977
  56 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  57 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  58 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  59
  60 sub __hdr ($$) {
  61         my ($self, $field) = @_;
  62         my $val = $self->{$field};
  63         return $val if defined $val;
  64
  65         my $mime = $self->{mime} or return;
  66         $val = $mime->header($field);
  67         $val = '' unless defined $val;
  68         $val =~ tr/\n/ /;
  69         $val =~ tr/\r//d;
  70         $self->{$field} = $val;
  71 }
  72
  73 sub subject ($) { __hdr($_[0], 'subject') }
  74 sub to ($) { __hdr($_[0], 'to') }
  75 sub cc ($) { __hdr($_[0], 'cc') }
  76
  77 sub date ($) {
  78         my ($self) = @_;
  79         my $date = __hdr($self, 'date');
  80         return $date if defined $date;
  81         my $ts = $self->{ts};
  82         return unless defined $ts;
  83         $self->{date} = strftime('%a, %d %b %Y %T %z', gmtime($ts));
  84 }
  85
  86 sub from ($) {
  87         my ($self) = @_;
  88         my $from = __hdr($self, 'from');
  89         if (defined $from && !defined $self->{from_name}) {
  90                 $self->{from_name} = PublicInbox::Address::from_name($from);
  91         }
  92         $from;
  93 }
  94
  95 sub from_name {
  96         my ($self) = @_;
  97         my $from_name = $self->{from_name};
  98         return $from_name if defined $from_name;
  99         $self->from;
 100         $self->{from_name};
 101 }
 102
 103 sub ts {
 104         my ($self) = @_;
 105         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 106 }
 107
 108 sub to_doc_data {
 109         my ($self) = @_;
 110         join("\n", $self->subject, $self->from, $self->references,
 111                 $self->to, $self->cc);
 112 }
 113
 114 sub references {
 115         my ($self) = @_;
 116         my $x = $self->{references};
 117         defined $x ? $x : '';
 118 }
 119
 120 sub ensure_metadata {
 121         my ($self) = @_;
 122         my $doc = $self->{doc};
 123         my $end = $doc->termlist_end;
 124
 125         unless (defined $PFX2TERM_RE) {
 126                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 127                 $PFX2TERM_RE = qr/\A($or)/;
 128         }
 129
 130         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 131                 # ideally we'd move this out of the loop:
 132                 my $i = $doc->termlist_begin;
 133
 134                 $i->skip_to($pfx);
 135                 if ($i != $end) {
 136                         my $val = $i->get_termname;
 137
 138                         if ($val =~ s/$PFX2TERM_RE//o) {
 139                                 $self->{$field} = $val;
 140                         }
 141                 }
 142         }
 143 }
 144
 145 # for threading only
 146 sub mini_mime {
 147         my ($self) = @_;
 148         $self->ensure_metadata;
 149         my @h = (
 150                 'Subject' => $self->subject,
 151                 'X-PI-From' => $self->from_name,
 152                 # prevent Email::Simple::Creator from running,
 153                 # this header is useless for threading as we use X-PI-TS
 154                 # for sorting and display:
 155                 'Date' => EPOCH_822,
 156                 'Message-ID' => "<$self->{mid}>",
 157                 'X-PI-TS' => $self->ts,
 158         );
 159         if (my $refs = $self->{references}) {
 160                 push @h, References => $refs;
 161         }
 162         my $mime = Email::MIME->create(header => \@h);
 163         my $h = $mime->header_obj;
 164
 165         # set these headers manually since Encode::encode('MIME-Q', ...)
 166         # will add spaces to long values when using header_str above.
 167
 168         # drop useless headers Email::MIME set for us
 169         $h->header_set('Date');
 170         $h->header_set('MIME-Version');
 171         $mime;
 172 }
 173
 174 sub mid ($;$) {
 175         my ($self, $mid) = @_;
 176
 177         if (defined $mid) {
 178                 $self->{mid} = $mid;
 179         } elsif (my $rv = $self->{mid}) {
 180                 $rv;
 181         } else {
 182                 $self->ensure_metadata; # needed for ghosts
 183                 $self->{mid} ||= $self->_extract_mid;
 184         }
 185 }
 186
 187 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 188
 189 sub mime {
 190         my ($self, $mime) = @_;
 191         if (defined $mime) {
 192                 $self->{mime} = $mime;
 193         } else {
 194                 # TODO load from git
 195                 $self->{mime};
 196         }
 197 }
 198
 199 sub doc_id {
 200         my ($self, $doc_id) = @_;
 201         if (defined $doc_id) {
 202                 $self->{doc_id} = $doc_id;
 203         } else {
 204                 # TODO load from xapian
 205                 $self->{doc_id};
 206         }
 207 }
 208
 209 sub thread_id {
 210         my ($self) = @_;
 211         my $tid = $self->{thread};
 212         return $tid if defined $tid;
 213         $self->ensure_metadata;
 214         $self->{thread};
 215 }
 216
 217 sub path {
 218         my ($self) = @_;
 219         my $path = $self->{path};
 220         return $path if defined $path;
 221         $self->ensure_metadata;
 222         $self->{path};
 223 }
 224
 225 1;