lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Email::Address qw//;
  11 use Email::Simple qw//;
  12 use POSIX qw//;
  13 use Date::Parse qw/str2time/;
  14 use PublicInbox::MID qw/mid_clean/;
  15 use Encode qw/find_encoding/;
  16 my $enc_utf8 = find_encoding('UTF-8');
  17 our $PFX2TERM_RE = undef;
  18 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  19 use POSIX qw(strftime);
  20
  21 sub new {
  22         my ($class, $mime) = @_;
  23         my $doc = Search::Xapian::Document->new;
  24         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  25
  26         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  27 }
  28
  29 sub wrap {
  30         my ($class, $doc, $mid) = @_;
  31         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  32 }
  33
  34 sub get_val ($$) {
  35         my ($doc, $col) = @_;
  36         Search::Xapian::sortable_unserialise($doc->get_value($col));
  37 }
  38
  39 sub load_doc {
  40         my ($class, $doc) = @_;
  41         my $data = $doc->get_data;
  42         my $ts = get_val($doc, &PublicInbox::Search::TS);
  43         $data = $enc_utf8->decode($data);
  44         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  45         bless {
  46                 doc => $doc,
  47                 subject => $subj,
  48                 ts => $ts,
  49                 from => $from,
  50                 references => $refs,
  51                 to => $to,
  52                 cc => $cc,
  53         }, $class;
  54 }
  55
  56 # :bytes and :lines metadata in RFC 3977
  57 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  58 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  59 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  60
  61 sub __hdr ($$) {
  62         my ($self, $field) = @_;
  63         my $val = $self->{$field};
  64         return $val if defined $val;
  65
  66         my $mime = $self->{mime} or return;
  67         $val = $mime->header($field);
  68         $val = '' unless defined $val;
  69         $val =~ tr/\t\r\n/ /;
  70         $self->{$field} = $val;
  71 }
  72
  73 sub subject ($) { __hdr($_[0], 'subject') }
  74 sub to ($) { __hdr($_[0], 'to') }
  75 sub cc ($) { __hdr($_[0], 'cc') }
  76
  77 sub date ($) {
  78         my ($self) = @_;
  79         my $date = __hdr($self, 'date');
  80         return $date if defined $date;
  81         my $ts = $self->{ts};
  82         return unless defined $ts;
  83         $self->{date} = strftime('%a, %d %b %Y %T %z', gmtime($ts));
  84 }
  85
  86 sub from ($) {
  87         my ($self) = @_;
  88         my $from = __hdr($self, 'from');
  89         if (defined $from && !defined $self->{from_name}) {
  90                 $from =~ tr/\t\r\n/ /;
  91                 my @from = Email::Address->parse($from);
  92                 $self->{from_name} = $from[0]->name;
  93         }
  94         $from;
  95 }
  96
  97 sub from_name {
  98         my ($self) = @_;
  99         my $from_name = $self->{from_name};
 100         return $from_name if defined $from_name;
 101         $self->from;
 102         $self->{from_name};
 103 }
 104
 105 sub ts {
 106         my ($self) = @_;
 107         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 108 }
 109
 110 sub to_doc_data {
 111         my ($self) = @_;
 112         join("\n", $self->subject, $self->from, $self->references,
 113                 $self->to, $self->cc);
 114 }
 115
 116 sub references {
 117         my ($self) = @_;
 118         my $x = $self->{references};
 119         defined $x ? $x : '';
 120 }
 121
 122 sub ensure_metadata {
 123         my ($self) = @_;
 124         my $doc = $self->{doc};
 125         my $end = $doc->termlist_end;
 126
 127         unless (defined $PFX2TERM_RE) {
 128                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 129                 $PFX2TERM_RE = qr/\A($or)/;
 130         }
 131
 132         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 133                 # ideally we'd move this out of the loop:
 134                 my $i = $doc->termlist_begin;
 135
 136                 $i->skip_to($pfx);
 137                 if ($i != $end) {
 138                         my $val = $i->get_termname;
 139
 140                         if ($val =~ s/$PFX2TERM_RE//o) {
 141                                 $self->{$field} = $val;
 142                         }
 143                 }
 144         }
 145 }
 146
 147 # for threading only
 148 sub mini_mime {
 149         my ($self) = @_;
 150         $self->ensure_metadata;
 151         my @hs = (
 152                 'Subject' => $self->subject,
 153                 'X-PI-From' => $self->from_name,
 154         );
 155
 156         my @h = (
 157                 # prevent Email::Simple::Creator from running,
 158                 # this header is useless for threading as we use X-PI-TS
 159                 # for sorting and display:
 160                 'Date' => EPOCH_822,
 161                 'Message-ID' => "<$self->{mid}>",
 162                 'X-PI-TS' => $self->ts,
 163         );
 164         if (my $refs = $self->{references}) {
 165                 push @h, References => $refs;
 166         }
 167         my $mime = Email::MIME->create(header_str => \@hs, header => \@h);
 168         my $h = $mime->header_obj;
 169
 170         # set these headers manually since Encode::encode('MIME-Q', ...)
 171         # will add spaces to long values when using header_str above.
 172
 173         # drop useless headers Email::MIME set for us
 174         $h->header_set('Date');
 175         $h->header_set('MIME-Version');
 176         $mime;
 177 }
 178
 179 sub mid ($;$) {
 180         my ($self, $mid) = @_;
 181
 182         if (defined $mid) {
 183                 $self->{mid} = $mid;
 184         } elsif (my $rv = $self->{mid}) {
 185                 $rv;
 186         } else {
 187                 $self->ensure_metadata; # needed for ghosts
 188                 $self->{mid} ||= $self->_extract_mid;
 189         }
 190 }
 191
 192 sub _extract_mid {
 193         my ($self) = @_;
 194
 195         my $mid = $self->mime->header('Message-ID');
 196         defined $mid ? mid_clean($mid) : $mid;
 197 }
 198
 199 sub mime {
 200         my ($self, $mime) = @_;
 201         if (defined $mime) {
 202                 $self->{mime} = $mime;
 203         } else {
 204                 # TODO load from git
 205                 $self->{mime};
 206         }
 207 }
 208
 209 sub doc_id {
 210         my ($self, $doc_id) = @_;
 211         if (defined $doc_id) {
 212                 $self->{doc_id} = $doc_id;
 213         } else {
 214                 # TODO load from xapian
 215                 $self->{doc_id};
 216         }
 217 }
 218
 219 sub thread_id {
 220         my ($self) = @_;
 221         my $tid = $self->{thread};
 222         return $tid if defined $tid;
 223         $self->ensure_metadata;
 224         $self->{thread};
 225 }
 226
 227 sub path {
 228         my ($self) = @_;
 229         my $path = $self->{path};
 230         return $path if defined $path;
 231         $self->ensure_metadata;
 232         $self->{path};
 233 }
 234
 235 1;