lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12 use Time::Local qw(timegm);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         bless { doc => $doc, mime => $mime }, $class;
  18 }
  19
  20 sub wrap {
  21         my ($class, $doc, $mid) = @_;
  22         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  23 }
  24
  25 sub get {
  26         my ($class, $head, $db, $mid) = @_;
  27         my $doc_id = $head->get_docid;
  28         my $doc = $db->get_document($doc_id);
  29         load_expand(wrap($class, $doc, $mid))
  30 }
  31
  32 sub get_val ($$) {
  33         my ($doc, $col) = @_;
  34         Search::Xapian::sortable_unserialise($doc->get_value($col));
  35 }
  36
  37 sub to_doc_data {
  38         my ($self, $oid, $mid0) = @_;
  39         $oid = '' unless defined $oid;
  40         join("\n",
  41                 $self->subject,
  42                 $self->from,
  43                 $self->references,
  44                 $self->to,
  45                 $self->cc,
  46                 $oid,
  47                 $mid0,
  48                 $self->{bytes},
  49                 $self->{lines}
  50         );
  51 }
  52
  53
  54 sub load_from_data ($$) {
  55         my ($self) = $_[0]; # data = $_[1]
  56         (
  57                 $self->{subject},
  58                 $self->{from},
  59                 $self->{references},
  60
  61                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  62                 # some NNTP clients will use that for message displays.
  63                 $self->{to},
  64                 $self->{cc},
  65
  66                 $self->{blob},
  67                 $self->{mid},
  68                 $self->{bytes},
  69                 $self->{lines}
  70         ) = split(/\n/, $_[1]);
  71 }
  72
  73 sub load_expand {
  74         my ($self) = @_;
  75         my $doc = $self->{doc};
  76         my $data = $doc->get_data or return;
  77         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  78         my $dt = get_val($doc, PublicInbox::Search::DT());
  79         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  80         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  81         utf8::decode($data);
  82         load_from_data($self, $data);
  83         $self;
  84 }
  85
  86 sub load_doc {
  87         my ($class, $doc) = @_;
  88         my $self = bless { doc => $doc }, $class;
  89         $self->load_expand;
  90 }
  91
  92 # :bytes and :lines metadata in RFC 3977
  93 sub bytes ($) { $_[0]->{bytes} }
  94 sub lines ($) { $_[0]->{lines} }
  95 sub num ($) { $_[0]->{num} ||= _get_term_val($_[0], 'XNUM', qr/\AXNUM/) }
  96
  97 sub __hdr ($$) {
  98         my ($self, $field) = @_;
  99         my $val = $self->{$field};
 100         return $val if defined $val;
 101
 102         my $mime = $self->{mime} or return;
 103         $val = $mime->header($field);
 104         $val = '' unless defined $val;
 105         $val =~ tr/\n/ /;
 106         $val =~ tr/\r//d;
 107         $self->{$field} = $val;
 108 }
 109
 110 sub subject ($) { __hdr($_[0], 'subject') }
 111 sub to ($) { __hdr($_[0], 'to') }
 112 sub cc ($) { __hdr($_[0], 'cc') }
 113
 114 # no strftime, that is locale-dependent and not for RFC822
 115 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 116 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 117
 118 sub date ($) {
 119         my ($self) = @_;
 120         my $ds = $self->{ds};
 121         return unless defined $ds;
 122         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 123         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 124                                 $mday, $year+1900, $hour, $min, $sec);
 125
 126 }
 127
 128 sub from ($) {
 129         my ($self) = @_;
 130         my $from = __hdr($self, 'from');
 131         if (defined $from && !defined $self->{from_name}) {
 132                 my @n = PublicInbox::Address::names($from);
 133                 $self->{from_name} = join(', ', @n);
 134         }
 135         $from;
 136 }
 137
 138 sub from_name {
 139         my ($self) = @_;
 140         my $from_name = $self->{from_name};
 141         return $from_name if defined $from_name;
 142         $self->from;
 143         $self->{from_name};
 144 }
 145
 146 sub ts {
 147         my ($self) = @_;
 148         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 149 }
 150
 151 sub ds {
 152         my ($self) = @_;
 153         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 154 }
 155
 156 sub references {
 157         my ($self) = @_;
 158         my $x = $self->{references};
 159         defined $x ? $x : '';
 160 }
 161
 162 sub _get_term_val ($$$) {
 163         my ($self, $pfx, $re) = @_;
 164         my $doc = $self->{doc};
 165         my $end = $doc->termlist_end;
 166         my $i = $doc->termlist_begin;
 167         $i->skip_to($pfx);
 168         if ($i != $end) {
 169                 my $val = $i->get_termname;
 170                 $val =~ s/$re// and return $val;
 171         }
 172         undef;
 173 }
 174
 175 sub mid ($;$) {
 176         my ($self, $mid) = @_;
 177
 178         if (defined $mid) {
 179                 $self->{mid} = $mid;
 180         } elsif (my $rv = $self->{mid}) {
 181                 $rv;
 182         } elsif ($self->{doc}) {
 183                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 184         } else {
 185                 $self->_extract_mid; # v1 w/o Xapian
 186         }
 187 }
 188
 189 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 190
 191 1;