lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 # There may be many of these objects loaded in memory at once
   7 # for large threads in our WWW UI.
   8 package PublicInbox::SearchMsg;
   9 use strict;
  10 use warnings;
  11 use PublicInbox::MID qw/mid_clean mid_mime/;
  12 use PublicInbox::Address;
  13 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  14 use Time::Local qw(timegm);
  15
  16 sub new {
  17         my ($class, $mime) = @_;
  18         my $doc = Search::Xapian::Document->new;
  19         bless { doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get {
  28         my ($class, $head, $db, $mid) = @_;
  29         my $doc_id = $head->get_docid;
  30         my $doc = $db->get_document($doc_id);
  31         load_expand(wrap($class, $doc, $mid))
  32 }
  33
  34 sub get_val ($$) {
  35         my ($doc, $col) = @_;
  36         Search::Xapian::sortable_unserialise($doc->get_value($col));
  37 }
  38
  39 sub to_doc_data {
  40         my ($self, $oid, $mid0) = @_;
  41         $oid = '' unless defined $oid;
  42         join("\n",
  43                 $self->subject,
  44                 $self->from,
  45                 $self->references,
  46                 $self->to,
  47                 $self->cc,
  48                 $oid,
  49                 $mid0,
  50                 $self->{bytes} || '',
  51                 $self->{lines} || ''
  52         );
  53 }
  54
  55 sub load_from_data ($$) {
  56         my ($self) = $_[0]; # data = $_[1]
  57         (
  58                 $self->{subject},
  59                 $self->{from},
  60                 $self->{references},
  61
  62                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  63                 # some NNTP clients will use that for message displays.
  64                 $self->{to},
  65                 $self->{cc},
  66
  67                 $self->{blob},
  68                 $self->{mid},
  69                 $self->{bytes},
  70                 $self->{lines}
  71         ) = split(/\n/, $_[1]);
  72 }
  73
  74 sub load_expand {
  75         my ($self) = @_;
  76         my $doc = $self->{doc};
  77         my $data = $doc->get_data or return;
  78         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  79         my $dt = get_val($doc, PublicInbox::Search::DT());
  80         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  81         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  82         utf8::decode($data);
  83         load_from_data($self, $data);
  84         $self;
  85 }
  86
  87 sub load_doc {
  88         my ($class, $doc) = @_;
  89         my $self = bless { doc => $doc }, $class;
  90         $self->load_expand;
  91 }
  92
  93 # :bytes and :lines metadata in RFC 3977
  94 sub bytes ($) { $_[0]->{bytes} }
  95 sub lines ($) { $_[0]->{lines} }
  96
  97 sub __hdr ($$) {
  98         my ($self, $field) = @_;
  99         my $val = $self->{$field};
 100         return $val if defined $val;
 101
 102         my $mime = $self->{mime} or return;
 103         $val = $mime->header($field);
 104         $val = '' unless defined $val;
 105         $val =~ tr/\t\n/  /;
 106         $val =~ tr/\r//d;
 107         $self->{$field} = $val;
 108 }
 109
 110 sub subject ($) { __hdr($_[0], 'subject') }
 111 sub to ($) { __hdr($_[0], 'to') }
 112 sub cc ($) { __hdr($_[0], 'cc') }
 113
 114 # no strftime, that is locale-dependent and not for RFC822
 115 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 116 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 117
 118 sub date ($) {
 119         my ($self) = @_;
 120         my $ds = $self->{ds};
 121         return unless defined $ds;
 122         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 123         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 124                                 $mday, $year+1900, $hour, $min, $sec);
 125
 126 }
 127
 128 sub from ($) {
 129         my ($self) = @_;
 130         my $from = __hdr($self, 'from');
 131         if (defined $from && !defined $self->{from_name}) {
 132                 my @n = PublicInbox::Address::names($from);
 133                 $self->{from_name} = join(', ', @n);
 134         }
 135         $from;
 136 }
 137
 138 sub from_name {
 139         my ($self) = @_;
 140         my $from_name = $self->{from_name};
 141         return $from_name if defined $from_name;
 142         $self->from;
 143         $self->{from_name};
 144 }
 145
 146 sub ts {
 147         my ($self) = @_;
 148         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 149 }
 150
 151 sub ds {
 152         my ($self) = @_;
 153         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 154 }
 155
 156 sub references {
 157         my ($self) = @_;
 158         my $x = $self->{references};
 159         defined $x ? $x : '';
 160 }
 161
 162 sub _get_term_val ($$$) {
 163         my ($self, $pfx, $re) = @_;
 164         my $doc = $self->{doc};
 165         my $end = $doc->termlist_end;
 166         my $i = $doc->termlist_begin;
 167         $i->skip_to($pfx);
 168         if ($i != $end) {
 169                 my $val = $i->get_termname;
 170                 $val =~ s/$re// and return $val;
 171         }
 172         undef;
 173 }
 174
 175 sub mid ($;$) {
 176         my ($self, $mid) = @_;
 177
 178         if (defined $mid) {
 179                 $self->{mid} = $mid;
 180         } elsif (my $rv = $self->{mid}) {
 181                 $rv;
 182         } elsif ($self->{doc}) {
 183                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 184         } else {
 185                 $self->_extract_mid; # v1 w/o Xapian
 186         }
 187 }
 188
 189 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 190
 191 1;