lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 # There may be many of these objects loaded in memory at once
   7 # for large threads in our WWW UI.
   8 package PublicInbox::SearchMsg;
   9 use strict;
  10 use warnings;
  11 use base qw(Exporter);
  12 our @EXPORT_OK = qw(subject_normalized);
  13 use PublicInbox::MID qw/mid_clean mid_mime/;
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use Time::Local qw(timegm);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         bless { mime => $mime }, $class;
  21 }
  22
  23 sub wrap {
  24         my ($class, $mid) = @_;
  25         bless { mid => $mid }, $class;
  26 }
  27
  28 sub get_val ($$) {
  29         my ($doc, $col) = @_;
  30         # sortable_unserialise is defined by PublicInbox::Search::load_xapian()
  31         sortable_unserialise($doc->get_value($col));
  32 }
  33
  34 sub to_doc_data {
  35         my ($self, $oid, $mid0) = @_;
  36         $oid = '' unless defined $oid;
  37         join("\n",
  38                 $self->subject,
  39                 $self->from,
  40                 $self->references,
  41                 $self->to,
  42                 $self->cc,
  43                 $oid,
  44                 $mid0,
  45                 $self->{bytes} || '',
  46                 $self->{lines} || ''
  47         );
  48 }
  49
  50 sub load_from_data ($$) {
  51         my ($self) = $_[0]; # data = $_[1]
  52         (
  53                 $self->{subject},
  54                 $self->{from},
  55                 $self->{references},
  56
  57                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  58                 # some NNTP clients will use that for message displays.
  59                 # NNTP only, and only stored in Over(view), not Xapian
  60                 $self->{to},
  61                 $self->{cc},
  62
  63                 $self->{blob},
  64                 $self->{mid},
  65
  66                 # NNTP only
  67                 $self->{bytes},
  68                 $self->{lines}
  69         ) = split(/\n/, $_[1]);
  70 }
  71
  72 sub load_expand {
  73         my ($self, $doc) = @_;
  74         my $data = $doc->get_data or return;
  75         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  76         my $dt = get_val($doc, PublicInbox::Search::DT());
  77         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  78         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  79         utf8::decode($data);
  80         load_from_data($self, $data);
  81         $self;
  82 }
  83
  84 sub psgi_cull ($) {
  85         my ($self) = @_;
  86         from_name($self); # fill in {from_name} so we can delete {from}
  87
  88         # drop NNTP-only fields which aren't relevant to PSGI results:
  89         # saves ~80K on a 200 item search result:
  90         delete @$self{qw(from ts to cc bytes lines)};
  91         $self;
  92 }
  93
  94 # Only called by PSGI interface, not NNTP
  95 sub from_mitem {
  96         my ($mitem, $srch) = @_;
  97         return $srch->retry_reopen(\&from_mitem, $mitem) if $srch;
  98         my $self = bless {}, __PACKAGE__;
  99         psgi_cull(load_expand($self, $mitem->get_document));
 100 }
 101
 102 # :bytes and :lines metadata in RFC 3977
 103 sub bytes ($) { $_[0]->{bytes} }
 104 sub lines ($) { $_[0]->{lines} }
 105
 106 sub __hdr ($$) {
 107         my ($self, $field) = @_;
 108         my $val = $self->{$field};
 109         return $val if defined $val;
 110
 111         my $mime = $self->{mime} or return;
 112         my @raw = $mime->header($field);
 113         $val = join(', ', @raw);
 114         $val =~ tr/\t\n/  /;
 115         $val =~ tr/\r//d;
 116         $self->{$field} = $val;
 117 }
 118
 119 sub subject ($) { __hdr($_[0], 'subject') }
 120 sub to ($) { __hdr($_[0], 'to') }
 121 sub cc ($) { __hdr($_[0], 'cc') }
 122
 123 # no strftime, that is locale-dependent and not for RFC822
 124 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 125 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 126
 127 sub date ($) {
 128         my ($self) = @_;
 129         my $ds = $self->{ds};
 130         return unless defined $ds;
 131         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 132         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 133                                 $mday, $year+1900, $hour, $min, $sec);
 134
 135 }
 136
 137 sub from ($) {
 138         my ($self) = @_;
 139         my $from = __hdr($self, 'from');
 140         if (defined $from && !defined $self->{from_name}) {
 141                 my @n = PublicInbox::Address::names($from);
 142                 $self->{from_name} = join(', ', @n);
 143         }
 144         $from;
 145 }
 146
 147 sub from_name {
 148         my ($self) = @_;
 149         my $from_name = $self->{from_name};
 150         return $from_name if defined $from_name;
 151         $self->from;
 152         $self->{from_name};
 153 }
 154
 155 sub ts {
 156         my ($self) = @_;
 157         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 158 }
 159
 160 sub ds {
 161         my ($self) = @_;
 162         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 163 }
 164
 165 sub references {
 166         my ($self) = @_;
 167         my $x = $self->{references};
 168         defined $x ? $x : '';
 169 }
 170
 171 sub mid ($;$) {
 172         my ($self, $mid) = @_;
 173
 174         if (defined $mid) {
 175                 $self->{mid} = $mid;
 176         } elsif (defined(my $rv = $self->{mid})) {
 177                 $rv;
 178         } else {
 179                 die "NO {mime} for mid\n" unless $self->{mime};
 180                 $self->_extract_mid; # v1 w/o Xapian
 181         }
 182 }
 183
 184 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 185
 186 our $REPLY_RE = qr/^re:\s+/i;
 187
 188 sub subject_normalized ($) {
 189         my ($subj) = @_;
 190         $subj =~ s/\A\s+//s; # no leading space
 191         $subj =~ s/\s+\z//s; # no trailing space
 192         $subj =~ s/\s+/ /gs; # no redundant spaces
 193         $subj =~ s/\.+\z//; # no trailing '.'
 194         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 195         $subj;
 196 }
 197
 198 1;