lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use PublicInbox::Address;
  14 our $PFX2TERM_RE = undef;
  15 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  16 use POSIX qw(strftime);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         my $doc = Search::Xapian::Document->new;
  21         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  22
  23         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  24 }
  25
  26 sub wrap {
  27         my ($class, $doc, $mid) = @_;
  28         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  29 }
  30
  31 sub get_val ($$) {
  32         my ($doc, $col) = @_;
  33         Search::Xapian::sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub load_doc {
  37         my ($class, $doc) = @_;
  38         my $data = $doc->get_data or return;
  39         my $ts = get_val($doc, &PublicInbox::Search::TS);
  40         utf8::decode($data);
  41         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  42         bless {
  43                 doc => $doc,
  44                 subject => $subj,
  45                 ts => $ts,
  46                 from => $from,
  47                 references => $refs,
  48                 to => $to,
  49                 cc => $cc,
  50         }, $class;
  51 }
  52
  53 # :bytes and :lines metadata in RFC 3977
  54 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  55 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  56 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  57
  58 sub __hdr ($$) {
  59         my ($self, $field) = @_;
  60         my $val = $self->{$field};
  61         return $val if defined $val;
  62
  63         my $mime = $self->{mime} or return;
  64         $val = $mime->header($field);
  65         $val = '' unless defined $val;
  66         $val =~ tr/\n/ /;
  67         $val =~ tr/\r//d;
  68         $self->{$field} = $val;
  69 }
  70
  71 sub subject ($) { __hdr($_[0], 'subject') }
  72 sub to ($) { __hdr($_[0], 'to') }
  73 sub cc ($) { __hdr($_[0], 'cc') }
  74
  75 sub date ($) {
  76         my ($self) = @_;
  77         my $date = __hdr($self, 'date');
  78         return $date if defined $date;
  79         my $ts = $self->{ts};
  80         return unless defined $ts;
  81         $self->{date} = strftime('%a, %d %b %Y %T +0000', gmtime($ts));
  82 }
  83
  84 sub from ($) {
  85         my ($self) = @_;
  86         my $from = __hdr($self, 'from');
  87         if (defined $from && !defined $self->{from_name}) {
  88                 my @n = PublicInbox::Address::names($from);
  89                 $self->{from_name} = join(', ', @n);
  90         }
  91         $from;
  92 }
  93
  94 sub from_name {
  95         my ($self) = @_;
  96         my $from_name = $self->{from_name};
  97         return $from_name if defined $from_name;
  98         $self->from;
  99         $self->{from_name};
 100 }
 101
 102 sub ts {
 103         my ($self) = @_;
 104         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 105 }
 106
 107 sub to_doc_data {
 108         my ($self) = @_;
 109         join("\n", $self->subject, $self->from, $self->references,
 110                 $self->to, $self->cc);
 111 }
 112
 113 sub references {
 114         my ($self) = @_;
 115         my $x = $self->{references};
 116         defined $x ? $x : '';
 117 }
 118
 119 sub ensure_metadata {
 120         my ($self) = @_;
 121         my $doc = $self->{doc};
 122         my $end = $doc->termlist_end;
 123
 124         unless (defined $PFX2TERM_RE) {
 125                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 126                 $PFX2TERM_RE = qr/\A($or)/;
 127         }
 128
 129         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 130                 # ideally we'd move this out of the loop:
 131                 my $i = $doc->termlist_begin;
 132
 133                 $i->skip_to($pfx);
 134                 if ($i != $end) {
 135                         my $val = $i->get_termname;
 136
 137                         if ($val =~ s/$PFX2TERM_RE//o) {
 138                                 $self->{$field} = $val;
 139                         }
 140                 }
 141         }
 142 }
 143
 144 # for threading only
 145 sub mini_mime {
 146         my ($self) = @_;
 147         $self->ensure_metadata;
 148         my @h = (
 149                 'Subject' => $self->subject,
 150                 'X-PI-From' => $self->from_name,
 151                 # prevent Email::Simple::Creator from running,
 152                 # this header is useless for threading as we use X-PI-TS
 153                 # for sorting and display:
 154                 'Date' => EPOCH_822,
 155                 'Message-ID' => "<$self->{mid}>",
 156                 'X-PI-TS' => $self->ts,
 157         );
 158         if (my $refs = $self->{references}) {
 159                 push @h, References => $refs;
 160         }
 161         my $mime = Email::MIME->create(header => \@h);
 162         my $h = $mime->header_obj;
 163
 164         # set these headers manually since Encode::encode('MIME-Q', ...)
 165         # will add spaces to long values when using header_str above.
 166
 167         # drop useless headers Email::MIME set for us
 168         $h->header_set('Date');
 169         $h->header_set('MIME-Version');
 170         $mime;
 171 }
 172
 173 sub mid ($;$) {
 174         my ($self, $mid) = @_;
 175
 176         if (defined $mid) {
 177                 $self->{mid} = $mid;
 178         } elsif (my $rv = $self->{mid}) {
 179                 $rv;
 180         } else {
 181                 $self->ensure_metadata; # needed for ghosts
 182                 $self->{mid} ||= $self->_extract_mid;
 183         }
 184 }
 185
 186 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 187
 188 sub mime {
 189         my ($self, $mime) = @_;
 190         if (defined $mime) {
 191                 $self->{mime} = $mime;
 192         } else {
 193                 # TODO load from git
 194                 $self->{mime};
 195         }
 196 }
 197
 198 sub doc_id {
 199         my ($self, $doc_id) = @_;
 200         if (defined $doc_id) {
 201                 $self->{doc_id} = $doc_id;
 202         } else {
 203                 # TODO load from xapian
 204                 $self->{doc_id};
 205         }
 206 }
 207
 208 sub thread_id {
 209         my ($self) = @_;
 210         my $tid = $self->{thread};
 211         return $tid if defined $tid;
 212         $self->ensure_metadata;
 213         $self->{thread};
 214 }
 215
 216 sub path {
 217         my ($self) = @_;
 218         my $path = $self->{path};
 219         return $path if defined $path;
 220         $self->ensure_metadata;
 221         $self->{path};
 222 }
 223
 224 1;