lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 # There may be many of these objects loaded in memory at once
   7 # for large threads in our WWW UI.
   8 package PublicInbox::SearchMsg;
   9 use strict;
  10 use warnings;
  11 use base qw(Exporter);
  12 our @EXPORT_OK = qw(subject_normalized);
  13 use PublicInbox::MID qw/mid_clean mid_mime/;
  14 use PublicInbox::Address;
  15 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  16 use Time::Local qw(timegm);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         bless { mime => $mime }, $class;
  21 }
  22
  23 sub wrap {
  24         my ($class, $mid) = @_;
  25         bless { mid => $mid }, $class;
  26 }
  27
  28 sub get {
  29         my ($class, $head, $db, $mid) = @_;
  30         my $doc_id = $head->get_docid;
  31         load_expand(wrap($class, $mid), $db->get_document($doc_id));
  32 }
  33
  34 sub get_val ($$) {
  35         my ($doc, $col) = @_;
  36         Search::Xapian::sortable_unserialise($doc->get_value($col));
  37 }
  38
  39 sub to_doc_data {
  40         my ($self, $oid, $mid0) = @_;
  41         $oid = '' unless defined $oid;
  42         join("\n",
  43                 $self->subject,
  44                 $self->from,
  45                 $self->references,
  46                 $self->to,
  47                 $self->cc,
  48                 $oid,
  49                 $mid0,
  50                 $self->{bytes} || '',
  51                 $self->{lines} || ''
  52         );
  53 }
  54
  55 sub load_from_data ($$) {
  56         my ($self) = $_[0]; # data = $_[1]
  57         (
  58                 $self->{subject},
  59                 $self->{from},
  60                 $self->{references},
  61
  62                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  63                 # some NNTP clients will use that for message displays.
  64                 # NNTP only, and only stored in Over(view), not Xapian
  65                 $self->{to},
  66                 $self->{cc},
  67
  68                 $self->{blob},
  69                 $self->{mid},
  70
  71                 # NNTP only
  72                 $self->{bytes},
  73                 $self->{lines}
  74         ) = split(/\n/, $_[1]);
  75 }
  76
  77 sub load_expand {
  78         my ($self, $doc) = @_;
  79         my $data = $doc->get_data or return;
  80         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  81         my $dt = get_val($doc, PublicInbox::Search::DT());
  82         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  83         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  84         utf8::decode($data);
  85         load_from_data($self, $data);
  86         $self;
  87 }
  88
  89 sub psgi_cull ($) {
  90         my ($self) = @_;
  91         from_name($self); # fill in {from_name} so we can delete {from}
  92
  93         # drop NNTP-only fields which aren't relevant to PSGI results:
  94         # saves ~80K on a 200 item search result:
  95         delete @$self{qw(from ts to cc bytes lines)};
  96         $self;
  97 }
  98
  99 # Only called by PSGI interface, not NNTP
 100 sub load_doc {
 101         my ($class, $doc) = @_;
 102         my $self = bless {}, $class;
 103         psgi_cull(load_expand($self, $doc));
 104 }
 105
 106 # :bytes and :lines metadata in RFC 3977
 107 sub bytes ($) { $_[0]->{bytes} }
 108 sub lines ($) { $_[0]->{lines} }
 109
 110 sub __hdr ($$) {
 111         my ($self, $field) = @_;
 112         my $val = $self->{$field};
 113         return $val if defined $val;
 114
 115         my $mime = $self->{mime} or return;
 116         $val = $mime->header($field);
 117         $val = '' unless defined $val;
 118         $val =~ tr/\t\n/  /;
 119         $val =~ tr/\r//d;
 120         $self->{$field} = $val;
 121 }
 122
 123 sub subject ($) { __hdr($_[0], 'subject') }
 124 sub to ($) { __hdr($_[0], 'to') }
 125 sub cc ($) { __hdr($_[0], 'cc') }
 126
 127 # no strftime, that is locale-dependent and not for RFC822
 128 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 129 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 130
 131 sub date ($) {
 132         my ($self) = @_;
 133         my $ds = $self->{ds};
 134         return unless defined $ds;
 135         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 136         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 137                                 $mday, $year+1900, $hour, $min, $sec);
 138
 139 }
 140
 141 sub from ($) {
 142         my ($self) = @_;
 143         my $from = __hdr($self, 'from');
 144         if (defined $from && !defined $self->{from_name}) {
 145                 my @n = PublicInbox::Address::names($from);
 146                 $self->{from_name} = join(', ', @n);
 147         }
 148         $from;
 149 }
 150
 151 sub from_name {
 152         my ($self) = @_;
 153         my $from_name = $self->{from_name};
 154         return $from_name if defined $from_name;
 155         $self->from;
 156         $self->{from_name};
 157 }
 158
 159 sub ts {
 160         my ($self) = @_;
 161         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 162 }
 163
 164 sub ds {
 165         my ($self) = @_;
 166         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 167 }
 168
 169 sub references {
 170         my ($self) = @_;
 171         my $x = $self->{references};
 172         defined $x ? $x : '';
 173 }
 174
 175 sub mid ($;$) {
 176         my ($self, $mid) = @_;
 177
 178         if (defined $mid) {
 179                 $self->{mid} = $mid;
 180         } elsif (defined(my $rv = $self->{mid})) {
 181                 $rv;
 182         } else {
 183                 die "NO {mime} for mid\n" unless $self->{mime};
 184                 $self->_extract_mid; # v1 w/o Xapian
 185         }
 186 }
 187
 188 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 189
 190 our $REPLY_RE = qr/^re:\s+/i;
 191
 192 sub subject_normalized ($) {
 193         my ($subj) = @_;
 194         $subj =~ s/\A\s+//s; # no leading space
 195         $subj =~ s/\s+\z//s; # no trailing space
 196         $subj =~ s/\s+/ /gs; # no redundant spaces
 197         $subj =~ s/\.+\z//; # no trailing '.'
 198         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 199         $subj;
 200 }
 201
 202 1;