lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::MID qw/mid_clean/;
  12 use PublicInbox::Address;
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_term('T' . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get_val ($$) {
  28         my ($doc, $col) = @_;
  29         Search::Xapian::sortable_unserialise($doc->get_value($col));
  30 }
  31
  32 sub load_expand {
  33         my ($self) = @_;
  34         my $doc = $self->{doc};
  35         my $data = $doc->get_data or return;
  36         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  37         utf8::decode($data);
  38         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  39         $self->{subject} = $subj;
  40         $self->{from} = $from;
  41         $self->{references} = $refs;
  42         $self->{to} = $to;
  43         $self->{cc} = $cc;
  44         $self->{blob} = $blob;
  45         $self;
  46 }
  47
  48 sub load_doc {
  49         my ($class, $doc) = @_;
  50         my $data = $doc->get_data or return;
  51         my $ts = get_val($doc, &PublicInbox::Search::TS);
  52         utf8::decode($data);
  53         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  54         bless {
  55                 doc => $doc,
  56                 subject => $subj,
  57                 ts => $ts,
  58                 from => $from,
  59                 references => $refs,
  60                 to => $to,
  61                 cc => $cc,
  62                 blob => $blob,
  63         }, $class;
  64 }
  65
  66 # :bytes and :lines metadata in RFC 3977
  67 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  68 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  69 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  70
  71 sub __hdr ($$) {
  72         my ($self, $field) = @_;
  73         my $val = $self->{$field};
  74         return $val if defined $val;
  75
  76         my $mime = $self->{mime} or return;
  77         $val = $mime->header($field);
  78         $val = '' unless defined $val;
  79         $val =~ tr/\n/ /;
  80         $val =~ tr/\r//d;
  81         $self->{$field} = $val;
  82 }
  83
  84 sub subject ($) { __hdr($_[0], 'subject') }
  85 sub to ($) { __hdr($_[0], 'to') }
  86 sub cc ($) { __hdr($_[0], 'cc') }
  87
  88 # no strftime, that is locale-dependent and not for RFC822
  89 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  90 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  91
  92 sub date ($) {
  93         my ($self) = @_;
  94         my $ts = $self->{ts};
  95         return unless defined $ts;
  96         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  97         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  98                                 $mday, $year+1900, $hour, $min, $sec);
  99
 100 }
 101
 102 sub from ($) {
 103         my ($self) = @_;
 104         my $from = __hdr($self, 'from');
 105         if (defined $from && !defined $self->{from_name}) {
 106                 my @n = PublicInbox::Address::names($from);
 107                 $self->{from_name} = join(', ', @n);
 108         }
 109         $from;
 110 }
 111
 112 sub from_name {
 113         my ($self) = @_;
 114         my $from_name = $self->{from_name};
 115         return $from_name if defined $from_name;
 116         $self->from;
 117         $self->{from_name};
 118 }
 119
 120 sub ts {
 121         my ($self) = @_;
 122         $self->{ts} ||= eval { str2time($self->{mime}->header('Date')) } || 0;
 123 }
 124
 125 sub to_doc_data {
 126         my ($self, $blob) = @_;
 127         my @rows = ($self->subject, $self->from, $self->references,
 128                         $self->to, $self->cc);
 129         push @rows, $blob if defined $blob;
 130         join("\n", @rows);
 131 }
 132
 133 sub references {
 134         my ($self) = @_;
 135         my $x = $self->{references};
 136         defined $x ? $x : '';
 137 }
 138
 139 sub _get_term_val ($$$) {
 140         my ($self, $pfx, $re) = @_;
 141         my $doc = $self->{doc};
 142         my $end = $doc->termlist_end;
 143         my $i = $doc->termlist_begin;
 144         $i->skip_to($pfx);
 145         if ($i != $end) {
 146                 my $val = $i->get_termname;
 147                 $val =~ s/$re// and return $val;
 148         }
 149         undef;
 150 }
 151
 152 sub mid ($;$) {
 153         my ($self, $mid) = @_;
 154
 155         if (defined $mid) {
 156                 $self->{mid} = $mid;
 157         } elsif (my $rv = $self->{mid}) {
 158                 $rv;
 159         } else {
 160                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 161                                 $self->_extract_mid;
 162         }
 163 }
 164
 165 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 166
 167 sub thread_id {
 168         my ($self) = @_;
 169         my $tid = $self->{thread};
 170         return $tid if defined $tid;
 171         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 172 }
 173
 174 # XXX: consider removing this, we can phrase match subject
 175 sub path {
 176         my ($self) = @_;
 177         my $path = $self->{path};
 178         return $path if defined $path;
 179         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 180 }
 181
 182 1;