lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::MID qw/mid_clean mid_mime/;
  12 use PublicInbox::Address;
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_boolean_term('T' . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get_val ($$) {
  28         my ($doc, $col) = @_;
  29         Search::Xapian::sortable_unserialise($doc->get_value($col));
  30 }
  31
  32 sub load_from_data ($$) {
  33         my ($self) = $_[0]; # data = $_[1]
  34         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $_[1]);
  35         $self->{subject} = $subj;
  36         $self->{from} = $from;
  37         $self->{references} = $refs;
  38         $self->{to} = $to;
  39         $self->{cc} = $cc;
  40         $self->{blob} = $blob;
  41 }
  42
  43 sub load_expand {
  44         my ($self) = @_;
  45         my $doc = $self->{doc};
  46         my $data = $doc->get_data or return;
  47         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  48         utf8::decode($data);
  49         load_from_data($self, $data);
  50         $self;
  51 }
  52
  53 sub load_doc {
  54         my ($class, $doc) = @_;
  55         my $data = $doc->get_data or return;
  56         my $ts = get_val($doc, &PublicInbox::Search::TS);
  57         utf8::decode($data);
  58         my $self = bless { doc => $doc, ts => $ts }, $class;
  59         load_from_data($self, $data);
  60         $self
  61 }
  62
  63 # :bytes and :lines metadata in RFC 3977
  64 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  65 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  66 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  67
  68 sub __hdr ($$) {
  69         my ($self, $field) = @_;
  70         my $val = $self->{$field};
  71         return $val if defined $val;
  72
  73         my $mime = $self->{mime} or return;
  74         $val = $mime->header($field);
  75         $val = '' unless defined $val;
  76         $val =~ tr/\n/ /;
  77         $val =~ tr/\r//d;
  78         $self->{$field} = $val;
  79 }
  80
  81 sub subject ($) { __hdr($_[0], 'subject') }
  82 sub to ($) { __hdr($_[0], 'to') }
  83 sub cc ($) { __hdr($_[0], 'cc') }
  84
  85 # no strftime, that is locale-dependent and not for RFC822
  86 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  87 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  88
  89 sub date ($) {
  90         my ($self) = @_;
  91         my $ts = $self->{ts};
  92         return unless defined $ts;
  93         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  94         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  95                                 $mday, $year+1900, $hour, $min, $sec);
  96
  97 }
  98
  99 sub from ($) {
 100         my ($self) = @_;
 101         my $from = __hdr($self, 'from');
 102         if (defined $from && !defined $self->{from_name}) {
 103                 my @n = PublicInbox::Address::names($from);
 104                 $self->{from_name} = join(', ', @n);
 105         }
 106         $from;
 107 }
 108
 109 sub from_name {
 110         my ($self) = @_;
 111         my $from_name = $self->{from_name};
 112         return $from_name if defined $from_name;
 113         $self->from;
 114         $self->{from_name};
 115 }
 116
 117 sub ts {
 118         my ($self) = @_;
 119         $self->{ts} ||= eval { str2time($self->{mime}->header('Date')) } || 0;
 120 }
 121
 122 sub to_doc_data {
 123         my ($self, $blob) = @_;
 124         my @rows = ($self->subject, $self->from, $self->references,
 125                         $self->to, $self->cc);
 126         push @rows, $blob if defined $blob;
 127         join("\n", @rows);
 128 }
 129
 130 sub references {
 131         my ($self) = @_;
 132         my $x = $self->{references};
 133         defined $x ? $x : '';
 134 }
 135
 136 sub _get_term_val ($$$) {
 137         my ($self, $pfx, $re) = @_;
 138         my $doc = $self->{doc};
 139         my $end = $doc->termlist_end;
 140         my $i = $doc->termlist_begin;
 141         $i->skip_to($pfx);
 142         if ($i != $end) {
 143                 my $val = $i->get_termname;
 144                 $val =~ s/$re// and return $val;
 145         }
 146         undef;
 147 }
 148
 149 sub mid ($;$) {
 150         my ($self, $mid) = @_;
 151
 152         if (defined $mid) {
 153                 $self->{mid} = $mid;
 154         } elsif (my $rv = $self->{mid}) {
 155                 $rv;
 156         } else {
 157                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 158                                 $self->_extract_mid;
 159         }
 160 }
 161
 162 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 163
 164 sub thread_id {
 165         my ($self) = @_;
 166         my $tid = $self->{thread};
 167         return $tid if defined $tid;
 168         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 169 }
 170
 171 # XXX: consider removing this, we can phrase match subject
 172 sub path {
 173         my ($self) = @_;
 174         my $path = $self->{path};
 175         return $path if defined $path;
 176         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 177 }
 178
 179 sub type {
 180         my ($self) = @_;
 181         my $type = $self->{type};
 182         return $type if defined $type;
 183         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 184 }
 185
 186 1;