lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::MID qw/mid_clean/;
  12 use PublicInbox::Address;
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get_val ($$) {
  28         my ($doc, $col) = @_;
  29         Search::Xapian::sortable_unserialise($doc->get_value($col));
  30 }
  31
  32 sub load_doc {
  33         my ($class, $doc) = @_;
  34         my $data = $doc->get_data or return;
  35         my $ts = get_val($doc, &PublicInbox::Search::TS);
  36         utf8::decode($data);
  37         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  38         bless {
  39                 doc => $doc,
  40                 subject => $subj,
  41                 ts => $ts,
  42                 from => $from,
  43                 references => $refs,
  44                 to => $to,
  45                 cc => $cc,
  46                 blob => $blob,
  47         }, $class;
  48 }
  49
  50 # :bytes and :lines metadata in RFC 3977
  51 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  52 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  53 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  54
  55 sub __hdr ($$) {
  56         my ($self, $field) = @_;
  57         my $val = $self->{$field};
  58         return $val if defined $val;
  59
  60         my $mime = $self->{mime} or return;
  61         $val = $mime->header($field);
  62         $val = '' unless defined $val;
  63         $val =~ tr/\n/ /;
  64         $val =~ tr/\r//d;
  65         $self->{$field} = $val;
  66 }
  67
  68 sub subject ($) { __hdr($_[0], 'subject') }
  69 sub to ($) { __hdr($_[0], 'to') }
  70 sub cc ($) { __hdr($_[0], 'cc') }
  71
  72 # no strftime, that is locale-dependent and not for RFC822
  73 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  74 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  75
  76 sub date ($) {
  77         my ($self) = @_;
  78         my $ts = $self->{ts};
  79         return unless defined $ts;
  80         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  81         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  82                                 $mday, $year+1900, $hour, $min, $sec);
  83
  84 }
  85
  86 sub from ($) {
  87         my ($self) = @_;
  88         my $from = __hdr($self, 'from');
  89         if (defined $from && !defined $self->{from_name}) {
  90                 my @n = PublicInbox::Address::names($from);
  91                 $self->{from_name} = join(', ', @n);
  92         }
  93         $from;
  94 }
  95
  96 sub from_name {
  97         my ($self) = @_;
  98         my $from_name = $self->{from_name};
  99         return $from_name if defined $from_name;
 100         $self->from;
 101         $self->{from_name};
 102 }
 103
 104 sub ts {
 105         my ($self) = @_;
 106         $self->{ts} ||= eval { str2time($self->{mime}->header('Date')) } || 0;
 107 }
 108
 109 sub to_doc_data {
 110         my ($self, $blob) = @_;
 111         my @rows = ($self->subject, $self->from, $self->references,
 112                         $self->to, $self->cc);
 113         push @rows, $blob if defined $blob;
 114         join("\n", @rows);
 115 }
 116
 117 sub references {
 118         my ($self) = @_;
 119         my $x = $self->{references};
 120         defined $x ? $x : '';
 121 }
 122
 123 sub _get_term_val ($$$) {
 124         my ($self, $pfx, $re) = @_;
 125         my $doc = $self->{doc};
 126         my $end = $doc->termlist_end;
 127         my $i = $doc->termlist_begin;
 128         $i->skip_to($pfx);
 129         if ($i != $end) {
 130                 my $val = $i->get_termname;
 131                 $val =~ s/$re// and return $val;
 132         }
 133         undef;
 134 }
 135
 136 sub mid ($;$) {
 137         my ($self, $mid) = @_;
 138
 139         if (defined $mid) {
 140                 $self->{mid} = $mid;
 141         } elsif (my $rv = $self->{mid}) {
 142                 $rv;
 143         } else {
 144                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 145                                 $self->_extract_mid;
 146         }
 147 }
 148
 149 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 150
 151 sub thread_id {
 152         my ($self) = @_;
 153         my $tid = $self->{thread};
 154         return $tid if defined $tid;
 155         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 156 }
 157
 158 # XXX: consider removing this, we can phrase match subject
 159 sub path {
 160         my ($self) = @_;
 161         my $path = $self->{path};
 162         return $path if defined $path;
 163         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 164 }
 165
 166 1;