lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12
  13 sub new {
  14         my ($class, $mime) = @_;
  15         my $doc = Search::Xapian::Document->new;
  16         bless { doc => $doc, mime => $mime }, $class;
  17 }
  18
  19 sub wrap {
  20         my ($class, $doc, $mid) = @_;
  21         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  22 }
  23
  24 sub get {
  25         my ($class, $head, $db, $mid) = @_;
  26         my $doc_id = $head->get_docid;
  27         my $doc = $db->get_document($doc_id);
  28         load_expand(wrap($class, $doc, $mid))
  29 }
  30
  31 sub get_val ($$) {
  32         my ($doc, $col) = @_;
  33         Search::Xapian::sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub to_doc_data {
  37         my ($self, $oid, $mid0) = @_;
  38         $oid = '' unless defined $oid;
  39         join("\n",
  40                 $self->subject,
  41                 $self->from,
  42                 $self->references,
  43                 $self->to,
  44                 $self->cc,
  45                 $oid,
  46                 $mid0,
  47                 $self->ds,
  48                 $self->{bytes},
  49                 $self->{lines}
  50         );
  51 }
  52
  53
  54 sub load_from_data ($$) {
  55         my ($self) = $_[0]; # data = $_[1]
  56         (
  57                 $self->{subject},
  58                 $self->{from},
  59                 $self->{references},
  60
  61                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  62                 # some NNTP clients will use that for message displays.
  63                 $self->{to},
  64                 $self->{cc},
  65
  66                 $self->{blob},
  67                 $self->{mid},
  68                 $self->{ds},
  69                 $self->{bytes},
  70                 $self->{lines}
  71         ) = split(/\n/, $_[1]);
  72 }
  73
  74 sub load_expand {
  75         my ($self) = @_;
  76         my $doc = $self->{doc};
  77         my $data = $doc->get_data or return;
  78         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  79         utf8::decode($data);
  80         load_from_data($self, $data);
  81         $self;
  82 }
  83
  84 sub load_doc {
  85         my ($class, $doc) = @_;
  86         my $self = bless { doc => $doc }, $class;
  87         $self->load_expand;
  88 }
  89
  90 # :bytes and :lines metadata in RFC 3977
  91 sub bytes ($) { $_[0]->{bytes} }
  92 sub lines ($) { $_[0]->{lines} }
  93 sub num ($) { $_[0]->{num} ||= _get_term_val($_[0], 'XNUM', qr/\AXNUM/) }
  94
  95 sub __hdr ($$) {
  96         my ($self, $field) = @_;
  97         my $val = $self->{$field};
  98         return $val if defined $val;
  99
 100         my $mime = $self->{mime} or return;
 101         $val = $mime->header($field);
 102         $val = '' unless defined $val;
 103         $val =~ tr/\n/ /;
 104         $val =~ tr/\r//d;
 105         $self->{$field} = $val;
 106 }
 107
 108 sub subject ($) { __hdr($_[0], 'subject') }
 109 sub to ($) { __hdr($_[0], 'to') }
 110 sub cc ($) { __hdr($_[0], 'cc') }
 111
 112 # no strftime, that is locale-dependent and not for RFC822
 113 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 114 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 115
 116 sub date ($) {
 117         my ($self) = @_;
 118         my $ds = $self->{ds};
 119         return unless defined $ds;
 120         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 121         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 122                                 $mday, $year+1900, $hour, $min, $sec);
 123
 124 }
 125
 126 sub from ($) {
 127         my ($self) = @_;
 128         my $from = __hdr($self, 'from');
 129         if (defined $from && !defined $self->{from_name}) {
 130                 my @n = PublicInbox::Address::names($from);
 131                 $self->{from_name} = join(', ', @n);
 132         }
 133         $from;
 134 }
 135
 136 sub from_name {
 137         my ($self) = @_;
 138         my $from_name = $self->{from_name};
 139         return $from_name if defined $from_name;
 140         $self->from;
 141         $self->{from_name};
 142 }
 143
 144 sub ts {
 145         my ($self) = @_;
 146         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 147 }
 148
 149 sub ds {
 150         my ($self) = @_;
 151         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 152 }
 153
 154 sub references {
 155         my ($self) = @_;
 156         my $x = $self->{references};
 157         defined $x ? $x : '';
 158 }
 159
 160 sub _get_term_val ($$$) {
 161         my ($self, $pfx, $re) = @_;
 162         my $doc = $self->{doc};
 163         my $end = $doc->termlist_end;
 164         my $i = $doc->termlist_begin;
 165         $i->skip_to($pfx);
 166         if ($i != $end) {
 167                 my $val = $i->get_termname;
 168                 $val =~ s/$re// and return $val;
 169         }
 170         undef;
 171 }
 172
 173 sub mid ($;$) {
 174         my ($self, $mid) = @_;
 175
 176         if (defined $mid) {
 177                 $self->{mid} = $mid;
 178         } elsif (my $rv = $self->{mid}) {
 179                 $rv;
 180         } elsif ($self->{doc}) {
 181                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 182         } else {
 183                 $self->_extract_mid; # v1 w/o Xapian
 184         }
 185 }
 186
 187 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 188
 189 1;