lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::MID qw/mid_clean/;
  12 use PublicInbox::Address;
  13 our $PFX2TERM_RE = undef;
  14
  15 sub new {
  16         my ($class, $mime) = @_;
  17         my $doc = Search::Xapian::Document->new;
  18         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  19
  20         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  21 }
  22
  23 sub wrap {
  24         my ($class, $doc, $mid) = @_;
  25         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  26 }
  27
  28 sub get_val ($$) {
  29         my ($doc, $col) = @_;
  30         Search::Xapian::sortable_unserialise($doc->get_value($col));
  31 }
  32
  33 sub load_doc {
  34         my ($class, $doc) = @_;
  35         my $data = $doc->get_data or return;
  36         my $ts = get_val($doc, &PublicInbox::Search::TS);
  37         utf8::decode($data);
  38         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  39         bless {
  40                 doc => $doc,
  41                 subject => $subj,
  42                 ts => $ts,
  43                 from => $from,
  44                 references => $refs,
  45                 to => $to,
  46                 cc => $cc,
  47                 blob => $blob,
  48         }, $class;
  49 }
  50
  51 # :bytes and :lines metadata in RFC 3977
  52 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  53 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  54 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  55
  56 sub __hdr ($$) {
  57         my ($self, $field) = @_;
  58         my $val = $self->{$field};
  59         return $val if defined $val;
  60
  61         my $mime = $self->{mime} or return;
  62         $val = $mime->header($field);
  63         $val = '' unless defined $val;
  64         $val =~ tr/\n/ /;
  65         $val =~ tr/\r//d;
  66         $self->{$field} = $val;
  67 }
  68
  69 sub subject ($) { __hdr($_[0], 'subject') }
  70 sub to ($) { __hdr($_[0], 'to') }
  71 sub cc ($) { __hdr($_[0], 'cc') }
  72
  73 # no strftime, that is locale-dependent
  74 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  75 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  76
  77 sub date ($) {
  78         my ($self) = @_;
  79         my $ts = $self->{ts};
  80         return unless defined $ts;
  81         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  82         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  83                                 $mday, $year+1900, $hour, $min, $sec);
  84
  85 }
  86
  87 sub from ($) {
  88         my ($self) = @_;
  89         my $from = __hdr($self, 'from');
  90         if (defined $from && !defined $self->{from_name}) {
  91                 my @n = PublicInbox::Address::names($from);
  92                 $self->{from_name} = join(', ', @n);
  93         }
  94         $from;
  95 }
  96
  97 sub from_name {
  98         my ($self) = @_;
  99         my $from_name = $self->{from_name};
 100         return $from_name if defined $from_name;
 101         $self->from;
 102         $self->{from_name};
 103 }
 104
 105 sub ts {
 106         my ($self) = @_;
 107         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 108 }
 109
 110 sub to_doc_data {
 111         my ($self, $blob) = @_;
 112         my @rows = ($self->subject, $self->from, $self->references,
 113                         $self->to, $self->cc);
 114         push @rows, $blob if defined $blob;
 115         join("\n", @rows);
 116 }
 117
 118 sub references {
 119         my ($self) = @_;
 120         my $x = $self->{references};
 121         defined $x ? $x : '';
 122 }
 123
 124 sub ensure_metadata {
 125         my ($self) = @_;
 126         my $doc = $self->{doc};
 127         my $end = $doc->termlist_end;
 128
 129         unless (defined $PFX2TERM_RE) {
 130                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 131                 $PFX2TERM_RE = qr/\A($or)/;
 132         }
 133
 134         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 135                 # ideally we'd move this out of the loop:
 136                 my $i = $doc->termlist_begin;
 137
 138                 $i->skip_to($pfx);
 139                 if ($i != $end) {
 140                         my $val = $i->get_termname;
 141
 142                         if ($val =~ s/$PFX2TERM_RE//o) {
 143                                 $self->{$field} = $val;
 144                         }
 145                 }
 146         }
 147 }
 148
 149 sub mid ($;$) {
 150         my ($self, $mid) = @_;
 151
 152         if (defined $mid) {
 153                 $self->{mid} = $mid;
 154         } elsif (my $rv = $self->{mid}) {
 155                 $rv;
 156         } else {
 157                 $self->ensure_metadata; # needed for ghosts
 158                 $self->{mid} ||= $self->_extract_mid;
 159         }
 160 }
 161
 162 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 163
 164 sub blob {
 165         my ($self, $x40) = @_;
 166         if (defined $x40) {
 167                 $self->{blob} = $x40;
 168         } else {
 169                 $self->{blob};
 170         }
 171 }
 172
 173 sub mime {
 174         my ($self, $mime) = @_;
 175         if (defined $mime) {
 176                 $self->{mime} = $mime;
 177         } else {
 178                 # TODO load from git
 179                 $self->{mime};
 180         }
 181 }
 182
 183 sub doc_id {
 184         my ($self, $doc_id) = @_;
 185         if (defined $doc_id) {
 186                 $self->{doc_id} = $doc_id;
 187         } else {
 188                 # TODO load from xapian
 189                 $self->{doc_id};
 190         }
 191 }
 192
 193 sub thread_id {
 194         my ($self) = @_;
 195         my $tid = $self->{thread};
 196         return $tid if defined $tid;
 197         $self->ensure_metadata;
 198         $self->{thread};
 199 }
 200
 201 sub path {
 202         my ($self) = @_;
 203         my $path = $self->{path};
 204         return $path if defined $path;
 205         $self->ensure_metadata;
 206         $self->{path};
 207 }
 208
 209 1;