lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12
  13 sub new {
  14         my ($class, $mime) = @_;
  15         my $doc = Search::Xapian::Document->new;
  16         $doc->add_boolean_term('T' . 'mail');
  17
  18         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  19 }
  20
  21 sub wrap {
  22         my ($class, $doc, $mid) = @_;
  23         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  24 }
  25
  26 sub get {
  27         my ($class, $head, $db, $mid) = @_;
  28         my $doc_id = $head->get_docid;
  29         my $doc = $db->get_document($doc_id);
  30         load_expand(wrap($class, $doc, $mid))
  31 }
  32
  33 sub get_val ($$) {
  34         my ($doc, $col) = @_;
  35         Search::Xapian::sortable_unserialise($doc->get_value($col));
  36 }
  37
  38 sub load_from_data ($$) {
  39         my ($self) = $_[0]; # data = $_[1]
  40         my ($subj, $from, $refs, $to, $cc, $blob, $mid0) = split(/\n/, $_[1]);
  41         $self->{subject} = $subj;
  42         $self->{from} = $from;
  43         $self->{references} = $refs;
  44         $self->{to} = $to;
  45         $self->{cc} = $cc;
  46         $self->{blob} = $blob;
  47         $self->{mid} = $mid0;
  48 }
  49
  50 sub load_expand {
  51         my ($self) = @_;
  52         my $doc = $self->{doc};
  53         my $data = $doc->get_data or return;
  54         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  55         $self->{ds} = get_val($doc, &PublicInbox::Search::DS);
  56         utf8::decode($data);
  57         load_from_data($self, $data);
  58         $self;
  59 }
  60
  61 sub load_doc {
  62         my ($class, $doc) = @_;
  63         my $self = bless { doc => $doc }, $class;
  64         $self->load_expand;
  65 }
  66
  67 # :bytes and :lines metadata in RFC 3977
  68 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  69 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  70 sub num ($) {
  71         $_[0]->{num} ||= get_val($_[0]->{doc}, PublicInbox::Search::NUM())
  72 }
  73
  74 sub __hdr ($$) {
  75         my ($self, $field) = @_;
  76         my $val = $self->{$field};
  77         return $val if defined $val;
  78
  79         my $mime = $self->{mime} or return;
  80         $val = $mime->header($field);
  81         $val = '' unless defined $val;
  82         $val =~ tr/\n/ /;
  83         $val =~ tr/\r//d;
  84         $self->{$field} = $val;
  85 }
  86
  87 sub subject ($) { __hdr($_[0], 'subject') }
  88 sub to ($) { __hdr($_[0], 'to') }
  89 sub cc ($) { __hdr($_[0], 'cc') }
  90
  91 # no strftime, that is locale-dependent and not for RFC822
  92 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  93 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  94
  95 sub date ($) {
  96         my ($self) = @_;
  97         my $ds = $self->{ds};
  98         return unless defined $ds;
  99         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 100         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 101                                 $mday, $year+1900, $hour, $min, $sec);
 102
 103 }
 104
 105 sub from ($) {
 106         my ($self) = @_;
 107         my $from = __hdr($self, 'from');
 108         if (defined $from && !defined $self->{from_name}) {
 109                 my @n = PublicInbox::Address::names($from);
 110                 $self->{from_name} = join(', ', @n);
 111         }
 112         $from;
 113 }
 114
 115 sub from_name {
 116         my ($self) = @_;
 117         my $from_name = $self->{from_name};
 118         return $from_name if defined $from_name;
 119         $self->from;
 120         $self->{from_name};
 121 }
 122
 123 sub ts {
 124         my ($self) = @_;
 125         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 126 }
 127
 128 sub ds {
 129         my ($self) = @_;
 130         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 131 }
 132
 133 sub to_doc_data {
 134         my ($self, $oid, $mid0) = @_;
 135         my @rows = ($self->subject, $self->from, $self->references,
 136                         $self->to, $self->cc);
 137         $oid = '' unless defined $oid;
 138         join("\n", @rows, $oid, $mid0);
 139 }
 140
 141 sub references {
 142         my ($self) = @_;
 143         my $x = $self->{references};
 144         defined $x ? $x : '';
 145 }
 146
 147 sub _get_term_val ($$$) {
 148         my ($self, $pfx, $re) = @_;
 149         my $doc = $self->{doc};
 150         my $end = $doc->termlist_end;
 151         my $i = $doc->termlist_begin;
 152         $i->skip_to($pfx);
 153         if ($i != $end) {
 154                 my $val = $i->get_termname;
 155                 $val =~ s/$re// and return $val;
 156         }
 157         undef;
 158 }
 159
 160 sub mid ($;$) {
 161         my ($self, $mid) = @_;
 162
 163         if (defined $mid) {
 164                 $self->{mid} = $mid;
 165         } elsif (my $rv = $self->{mid}) {
 166                 $rv;
 167         } elsif ($self->{doc}) {
 168                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 169         } else {
 170                 $self->_extract_mid; # v1 w/o Xapian
 171         }
 172 }
 173
 174 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 175
 176 sub thread_id {
 177         my ($self) = @_;
 178         my $tid = $self->{thread};
 179         return $tid if defined $tid;
 180         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 181 }
 182
 183 # XXX: consider removing this, we can phrase match subject
 184 sub path {
 185         my ($self) = @_;
 186         my $path = $self->{path};
 187         return $path if defined $path;
 188         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 189 }
 190
 191 sub type {
 192         my ($self) = @_;
 193         my $type = $self->{type};
 194         return $type if defined $type;
 195         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 196 }
 197
 198 1;