lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12
  13 sub new {
  14         my ($class, $mime) = @_;
  15         my $doc = Search::Xapian::Document->new;
  16         $doc->add_boolean_term('T' . 'mail');
  17
  18         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  19 }
  20
  21 sub wrap {
  22         my ($class, $doc, $mid) = @_;
  23         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  24 }
  25
  26 sub get {
  27         my ($class, $head, $db, $mid) = @_;
  28         my $doc_id = $head->get_docid;
  29         my $doc = $db->get_document($doc_id);
  30         load_expand(wrap($class, $doc, $mid))
  31 }
  32
  33 sub get_val ($$) {
  34         my ($doc, $col) = @_;
  35         Search::Xapian::sortable_unserialise($doc->get_value($col));
  36 }
  37
  38 sub load_from_data ($$) {
  39         my ($self) = $_[0]; # data = $_[1]
  40         my ($subj, $from, $refs, $to, $cc, $blob, $mid0) = split(/\n/, $_[1]);
  41         $self->{subject} = $subj;
  42         $self->{from} = $from;
  43         $self->{references} = $refs;
  44
  45         # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  46         # some NNTP clients will use that for message displays.
  47         $self->{to} = $to;
  48         $self->{cc} = $cc;
  49
  50         $self->{blob} = $blob;
  51         $self->{mid} = $mid0;
  52 }
  53
  54 sub load_expand {
  55         my ($self) = @_;
  56         my $doc = $self->{doc};
  57         my $data = $doc->get_data or return;
  58         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  59         $self->{ds} = get_val($doc, &PublicInbox::Search::DS);
  60         utf8::decode($data);
  61         load_from_data($self, $data);
  62         $self;
  63 }
  64
  65 sub load_doc {
  66         my ($class, $doc) = @_;
  67         my $self = bless { doc => $doc }, $class;
  68         $self->load_expand;
  69 }
  70
  71 # :bytes and :lines metadata in RFC 3977
  72 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  73 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  74 sub num ($) {
  75         $_[0]->{num} ||= get_val($_[0]->{doc}, PublicInbox::Search::NUM())
  76 }
  77
  78 sub __hdr ($$) {
  79         my ($self, $field) = @_;
  80         my $val = $self->{$field};
  81         return $val if defined $val;
  82
  83         my $mime = $self->{mime} or return;
  84         $val = $mime->header($field);
  85         $val = '' unless defined $val;
  86         $val =~ tr/\n/ /;
  87         $val =~ tr/\r//d;
  88         $self->{$field} = $val;
  89 }
  90
  91 sub subject ($) { __hdr($_[0], 'subject') }
  92 sub to ($) { __hdr($_[0], 'to') }
  93 sub cc ($) { __hdr($_[0], 'cc') }
  94
  95 # no strftime, that is locale-dependent and not for RFC822
  96 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  97 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  98
  99 sub date ($) {
 100         my ($self) = @_;
 101         my $ds = $self->{ds};
 102         return unless defined $ds;
 103         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 104         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 105                                 $mday, $year+1900, $hour, $min, $sec);
 106
 107 }
 108
 109 sub from ($) {
 110         my ($self) = @_;
 111         my $from = __hdr($self, 'from');
 112         if (defined $from && !defined $self->{from_name}) {
 113                 my @n = PublicInbox::Address::names($from);
 114                 $self->{from_name} = join(', ', @n);
 115         }
 116         $from;
 117 }
 118
 119 sub from_name {
 120         my ($self) = @_;
 121         my $from_name = $self->{from_name};
 122         return $from_name if defined $from_name;
 123         $self->from;
 124         $self->{from_name};
 125 }
 126
 127 sub ts {
 128         my ($self) = @_;
 129         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 130 }
 131
 132 sub ds {
 133         my ($self) = @_;
 134         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 135 }
 136
 137 sub to_doc_data {
 138         my ($self, $oid, $mid0) = @_;
 139         my @rows = ($self->subject, $self->from, $self->references,
 140                         $self->to, $self->cc);
 141         $oid = '' unless defined $oid;
 142         join("\n", @rows, $oid, $mid0);
 143 }
 144
 145 sub references {
 146         my ($self) = @_;
 147         my $x = $self->{references};
 148         defined $x ? $x : '';
 149 }
 150
 151 sub _get_term_val ($$$) {
 152         my ($self, $pfx, $re) = @_;
 153         my $doc = $self->{doc};
 154         my $end = $doc->termlist_end;
 155         my $i = $doc->termlist_begin;
 156         $i->skip_to($pfx);
 157         if ($i != $end) {
 158                 my $val = $i->get_termname;
 159                 $val =~ s/$re// and return $val;
 160         }
 161         undef;
 162 }
 163
 164 sub mid ($;$) {
 165         my ($self, $mid) = @_;
 166
 167         if (defined $mid) {
 168                 $self->{mid} = $mid;
 169         } elsif (my $rv = $self->{mid}) {
 170                 $rv;
 171         } elsif ($self->{doc}) {
 172                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 173         } else {
 174                 $self->_extract_mid; # v1 w/o Xapian
 175         }
 176 }
 177
 178 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 179
 180 sub thread_id {
 181         my ($self) = @_;
 182         my $tid = $self->{thread};
 183         return $tid if defined $tid;
 184         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 185 }
 186
 187 # XXX: consider removing this, we can phrase match subject
 188 sub path {
 189         my ($self) = @_;
 190         my $path = $self->{path};
 191         return $path if defined $path;
 192         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 193 }
 194
 195 sub type {
 196         my ($self) = @_;
 197         my $type = $self->{type};
 198         return $type if defined $type;
 199         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 200 }
 201
 202 1;