lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12
  13 sub new {
  14         my ($class, $mime) = @_;
  15         my $doc = Search::Xapian::Document->new;
  16         $doc->add_boolean_term('T' . 'mail');
  17
  18         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  19 }
  20
  21 sub wrap {
  22         my ($class, $doc, $mid) = @_;
  23         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  24 }
  25
  26 sub get {
  27         my ($class, $head, $db, $mid) = @_;
  28         my $doc_id = $head->get_docid;
  29         my $doc = $db->get_document($doc_id);
  30         load_expand(wrap($class, $doc, $mid))
  31 }
  32
  33 sub get_val ($$) {
  34         my ($doc, $col) = @_;
  35         Search::Xapian::sortable_unserialise($doc->get_value($col));
  36 }
  37
  38 sub to_doc_data {
  39         my ($self, $oid, $mid0) = @_;
  40         $oid = '' unless defined $oid;
  41         join("\n",
  42                 $self->subject,
  43                 $self->from,
  44                 $self->references,
  45                 $self->to,
  46                 $self->cc,
  47                 $oid,
  48                 $mid0,
  49                 $self->ds,
  50                 $self->{bytes},
  51                 $self->{lines}
  52         );
  53 }
  54
  55 sub load_from_data ($$) {
  56         my ($self) = $_[0]; # data = $_[1]
  57         (
  58                 $self->{subject},
  59                 $self->{from},
  60                 $self->{references},
  61
  62                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  63                 # some NNTP clients will use that for message displays.
  64                 $self->{to},
  65                 $self->{cc},
  66
  67                 $self->{blob},
  68                 $self->{mid},
  69                 $self->{ds},
  70                 $self->{bytes},
  71                 $self->{lines}
  72         ) = split(/\n/, $_[1]);
  73 }
  74
  75 sub load_expand {
  76         my ($self) = @_;
  77         my $doc = $self->{doc};
  78         my $data = $doc->get_data or return;
  79         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  80         utf8::decode($data);
  81         load_from_data($self, $data);
  82         $self;
  83 }
  84
  85 sub load_doc {
  86         my ($class, $doc) = @_;
  87         my $self = bless { doc => $doc }, $class;
  88         $self->load_expand;
  89 }
  90
  91 # :bytes and :lines metadata in RFC 3977
  92 sub bytes ($) { $_[0]->{bytes} }
  93 sub lines ($) { $_[0]->{lines} }
  94 sub num ($) { $_[0]->{num} ||= _get_term_val($_[0], 'XNUM', qr/\AXNUM/) }
  95
  96 sub __hdr ($$) {
  97         my ($self, $field) = @_;
  98         my $val = $self->{$field};
  99         return $val if defined $val;
 100
 101         my $mime = $self->{mime} or return;
 102         $val = $mime->header($field);
 103         $val = '' unless defined $val;
 104         $val =~ tr/\n/ /;
 105         $val =~ tr/\r//d;
 106         $self->{$field} = $val;
 107 }
 108
 109 sub subject ($) { __hdr($_[0], 'subject') }
 110 sub to ($) { __hdr($_[0], 'to') }
 111 sub cc ($) { __hdr($_[0], 'cc') }
 112
 113 # no strftime, that is locale-dependent and not for RFC822
 114 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 115 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 116
 117 sub date ($) {
 118         my ($self) = @_;
 119         my $ds = $self->{ds};
 120         return unless defined $ds;
 121         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 122         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 123                                 $mday, $year+1900, $hour, $min, $sec);
 124
 125 }
 126
 127 sub from ($) {
 128         my ($self) = @_;
 129         my $from = __hdr($self, 'from');
 130         if (defined $from && !defined $self->{from_name}) {
 131                 my @n = PublicInbox::Address::names($from);
 132                 $self->{from_name} = join(', ', @n);
 133         }
 134         $from;
 135 }
 136
 137 sub from_name {
 138         my ($self) = @_;
 139         my $from_name = $self->{from_name};
 140         return $from_name if defined $from_name;
 141         $self->from;
 142         $self->{from_name};
 143 }
 144
 145 sub ts {
 146         my ($self) = @_;
 147         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 148 }
 149
 150 sub ds {
 151         my ($self) = @_;
 152         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 153 }
 154
 155 sub references {
 156         my ($self) = @_;
 157         my $x = $self->{references};
 158         defined $x ? $x : '';
 159 }
 160
 161 sub _get_term_val ($$$) {
 162         my ($self, $pfx, $re) = @_;
 163         my $doc = $self->{doc};
 164         my $end = $doc->termlist_end;
 165         my $i = $doc->termlist_begin;
 166         $i->skip_to($pfx);
 167         if ($i != $end) {
 168                 my $val = $i->get_termname;
 169                 $val =~ s/$re// and return $val;
 170         }
 171         undef;
 172 }
 173
 174 sub mid ($;$) {
 175         my ($self, $mid) = @_;
 176
 177         if (defined $mid) {
 178                 $self->{mid} = $mid;
 179         } elsif (my $rv = $self->{mid}) {
 180                 $rv;
 181         } elsif ($self->{doc}) {
 182                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/);
 183         } else {
 184                 $self->_extract_mid; # v1 w/o Xapian
 185         }
 186 }
 187
 188 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 189
 190 sub thread_id {
 191         my ($self) = @_;
 192         my $tid = $self->{thread};
 193         return $tid if defined $tid;
 194         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 195 }
 196
 197 # XXX: consider removing this, we can phrase match subject
 198 sub path {
 199         my ($self) = @_;
 200         my $path = $self->{path};
 201         return $path if defined $path;
 202         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 203 }
 204
 205 sub type {
 206         my ($self) = @_;
 207         my $type = $self->{type};
 208         return $type if defined $type;
 209         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 210 }
 211
 212 1;