lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use PublicInbox::MID qw/mid_clean mid_mime/;
  11 use PublicInbox::Address;
  12 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_boolean_term('T' . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get {
  28         my ($class, $head, $db, $mid) = @_;
  29         my $doc_id = $head->get_docid;
  30         my $doc = $db->get_document($doc_id);
  31         load_expand(wrap($class, $doc, $mid))
  32 }
  33
  34 sub get_val ($$) {
  35         my ($doc, $col) = @_;
  36         Search::Xapian::sortable_unserialise($doc->get_value($col));
  37 }
  38
  39 sub load_from_data ($$) {
  40         my ($self) = $_[0]; # data = $_[1]
  41         my ($subj, $from, $refs, $to, $cc, $blob, $mid0) = split(/\n/, $_[1]);
  42         $self->{subject} = $subj;
  43         $self->{from} = $from;
  44         $self->{references} = $refs;
  45         $self->{to} = $to;
  46         $self->{cc} = $cc;
  47         $self->{blob} = $blob;
  48         $self->{mid} = $mid0;
  49 }
  50
  51 sub load_expand {
  52         my ($self) = @_;
  53         my $doc = $self->{doc};
  54         my $data = $doc->get_data or return;
  55         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  56         $self->{ds} = get_val($doc, &PublicInbox::Search::DS);
  57         utf8::decode($data);
  58         load_from_data($self, $data);
  59         $self;
  60 }
  61
  62 sub load_doc {
  63         my ($class, $doc) = @_;
  64         my $self = bless { doc => $doc }, $class;
  65         $self->load_expand;
  66 }
  67
  68 # :bytes and :lines metadata in RFC 3977
  69 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  70 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  71 sub num ($) {
  72         $_[0]->{num} ||= get_val($_[0]->{doc}, PublicInbox::Search::NUM())
  73 }
  74
  75 sub __hdr ($$) {
  76         my ($self, $field) = @_;
  77         my $val = $self->{$field};
  78         return $val if defined $val;
  79
  80         my $mime = $self->{mime} or return;
  81         $val = $mime->header($field);
  82         $val = '' unless defined $val;
  83         $val =~ tr/\n/ /;
  84         $val =~ tr/\r//d;
  85         $self->{$field} = $val;
  86 }
  87
  88 sub subject ($) { __hdr($_[0], 'subject') }
  89 sub to ($) { __hdr($_[0], 'to') }
  90 sub cc ($) { __hdr($_[0], 'cc') }
  91
  92 # no strftime, that is locale-dependent and not for RFC822
  93 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  94 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  95
  96 sub date ($) {
  97         my ($self) = @_;
  98         my $ds = $self->{ds};
  99         return unless defined $ds;
 100         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 101         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 102                                 $mday, $year+1900, $hour, $min, $sec);
 103
 104 }
 105
 106 sub from ($) {
 107         my ($self) = @_;
 108         my $from = __hdr($self, 'from');
 109         if (defined $from && !defined $self->{from_name}) {
 110                 my @n = PublicInbox::Address::names($from);
 111                 $self->{from_name} = join(', ', @n);
 112         }
 113         $from;
 114 }
 115
 116 sub from_name {
 117         my ($self) = @_;
 118         my $from_name = $self->{from_name};
 119         return $from_name if defined $from_name;
 120         $self->from;
 121         $self->{from_name};
 122 }
 123
 124 sub ts {
 125         my ($self) = @_;
 126         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 127 }
 128
 129 sub ds {
 130         my ($self) = @_;
 131         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 132 }
 133
 134 sub to_doc_data {
 135         my ($self, $oid, $mid0) = @_;
 136         my @rows = ($self->subject, $self->from, $self->references,
 137                         $self->to, $self->cc);
 138         $oid = '' unless defined $oid;
 139         join("\n", @rows, $oid, $mid0);
 140 }
 141
 142 sub references {
 143         my ($self) = @_;
 144         my $x = $self->{references};
 145         defined $x ? $x : '';
 146 }
 147
 148 sub _get_term_val ($$$) {
 149         my ($self, $pfx, $re) = @_;
 150         my $doc = $self->{doc};
 151         my $end = $doc->termlist_end;
 152         my $i = $doc->termlist_begin;
 153         $i->skip_to($pfx);
 154         if ($i != $end) {
 155                 my $val = $i->get_termname;
 156                 $val =~ s/$re// and return $val;
 157         }
 158         undef;
 159 }
 160
 161 sub mid ($;$) {
 162         my ($self, $mid) = @_;
 163
 164         if (defined $mid) {
 165                 $self->{mid} = $mid;
 166         } elsif (my $rv = $self->{mid}) {
 167                 $rv;
 168         } else {
 169                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 170                                 $self->_extract_mid;
 171         }
 172 }
 173
 174 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 175
 176 sub thread_id {
 177         my ($self) = @_;
 178         my $tid = $self->{thread};
 179         return $tid if defined $tid;
 180         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 181 }
 182
 183 # XXX: consider removing this, we can phrase match subject
 184 sub path {
 185         my ($self) = @_;
 186         my $path = $self->{path};
 187         return $path if defined $path;
 188         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 189 }
 190
 191 sub type {
 192         my ($self) = @_;
 193         my $type = $self->{type};
 194         return $type if defined $type;
 195         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 196 }
 197
 198 1;