lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: GPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchMsg;
   5 use strict;
   6 use warnings;
   7 use Search::Xapian;
   8 use Email::Address qw//;
   9 use Email::Simple qw//;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean mid_compress/;
  13 use Encode qw/find_encoding/;
  14 my $enc_utf8 = find_encoding('UTF-8');
  15 our $PFX2TERM_RE = undef;
  16
  17 sub new {
  18         my ($class, $mime) = @_;
  19         my $doc = Search::Xapian::Document->new;
  20         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  21
  22         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $doc, $mid) = @_;
  27         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  28 }
  29
  30 sub load_doc {
  31         my ($class, $doc) = @_;
  32         my $data = $doc->get_data;
  33         $data = $enc_utf8->decode($data);
  34         my ($mid, $subj, $from, $date, $refs) = split(/\n/, $data);
  35         bless {
  36                 doc => $doc,
  37                 mid => $mid,
  38                 subject => $subj,
  39                 date => $date,
  40                 from_name => $from,
  41                 references_sorted => $refs,
  42         }, $class;
  43 }
  44
  45 sub subject {
  46         my ($self) = @_;
  47         my $subj = $self->{subject};
  48         return $subj if defined $subj;
  49         $subj = $self->{mime}->header('Subject');
  50         $subj = '' unless defined $subj;
  51         $subj =~ tr/\n/ /;
  52         $self->{subject} = $subj;
  53 }
  54
  55 sub from {
  56         my ($self) = @_;
  57         my $from = $self->mime->header('From') || '';
  58         my @from;
  59
  60         if ($from) {
  61                 $from =~ tr/\n/ /;
  62                 @from = Email::Address->parse($from);
  63                 $self->{from} = $from[0];
  64                 $from = $from[0]->name;
  65         }
  66         $self->{from_name} = $from;
  67         $self->{from};
  68 }
  69
  70 sub from_name {
  71         my ($self) = @_;
  72         my $from_name = $self->{from_name};
  73         return $from_name if defined $from_name;
  74         $self->from;
  75         $self->{from_name};
  76 }
  77
  78 sub ts {
  79         my ($self) = @_;
  80         my $ts = $self->{ts};
  81         return $ts if $ts;
  82         $self->{ts} = eval {
  83                 str2time($self->date || $self->mime->header('Date'))
  84         } || 0;
  85 }
  86
  87 sub date {
  88         my ($self) = @_;
  89         my $date = $self->{date};
  90         return $date if $date;
  91         my $ts = eval { str2time($self->mime->header('Date')) };
  92         $self->{date} = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
  93 }
  94
  95 sub to_doc_data {
  96         my ($self) = @_;
  97         $self->mid . "\n" .
  98         PublicInbox::Search::subject_summary($self->subject) . "\n" .
  99         $self->from_name . "\n".
 100         $self->date . "\n" .
 101         $self->references_sorted;
 102 }
 103
 104 sub references_sorted {
 105         my ($self) = @_;
 106         my $x = $self->{references_sorted};
 107         defined $x ? $x : '';
 108 }
 109
 110 sub ensure_metadata {
 111         my ($self) = @_;
 112         my $doc = $self->{doc};
 113         my $end = $doc->termlist_end;
 114
 115         unless (defined $PFX2TERM_RE) {
 116                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 117                 $PFX2TERM_RE = qr/\A($or)/;
 118         }
 119
 120         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 121                 # ideally we'd move this out of the loop:
 122                 my $i = $doc->termlist_begin;
 123
 124                 $i->skip_to($pfx);
 125                 if ($i != $end) {
 126                         my $val = $i->get_termname;
 127
 128                         if ($val =~ s/$PFX2TERM_RE//o) {
 129                                 $self->{$field} = $val;
 130                         }
 131                 }
 132         }
 133 }
 134
 135 # for threading only
 136 sub mini_mime {
 137         my ($self) = @_;
 138         $self->ensure_metadata;
 139         my @h = (
 140                 Subject => $self->subject,
 141                 'X-PI-From' => $self->from_name,
 142                 'X-PI-Date' => $self->date,
 143                 'X-PI-TS' => $self->ts,
 144                 'Message-ID' => "<$self->{mid}>",
 145         );
 146
 147         my $refs = $self->{references_sorted};
 148         my $mime = Email::MIME->create(header_str => \@h);
 149         $mime->header_set('References', $refs) if (defined $refs);
 150         $mime;
 151 }
 152
 153 sub mid {
 154         my ($self, $mid) = @_;
 155
 156         if (defined $mid) {
 157                 $self->{mid} = $mid;
 158         } else {
 159                 $self->ensure_metadata; # needed for ghosts
 160                 $self->{mid} ||= $self->_extract_mid;
 161         }
 162 }
 163
 164 sub _extract_mid {
 165         my ($self) = @_;
 166
 167         my $mid = $self->mime->header('Message-ID');
 168         $mid ? mid_compress(mid_clean($mid)) : $mid;
 169 }
 170
 171 sub mime {
 172         my ($self, $mime) = @_;
 173         if (defined $mime) {
 174                 $self->{mime} = $mime;
 175         } else {
 176                 # TODO load from git
 177                 $self->{mime};
 178         }
 179 }
 180
 181 sub doc_id {
 182         my ($self, $doc_id) = @_;
 183         if (defined $doc_id) {
 184                 $self->{doc_id} = $doc_id;
 185         } else {
 186                 # TODO load from xapian
 187                 $self->{doc_id};
 188         }
 189 }
 190
 191 sub thread_id {
 192         my ($self) = @_;
 193         my $tid = $self->{thread};
 194         return $tid if defined $tid;
 195         $self->ensure_metadata;
 196         $self->{thread};
 197 }
 198
 199 sub path {
 200         my ($self) = @_;
 201         my $path = $self->{path};
 202         return $path if defined $path;
 203         $self->ensure_metadata;
 204         $self->{path};
 205 }
 206
 207 1;