lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: GPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchMsg;
   5 use strict;
   6 use warnings;
   7 use Search::Xapian;
   8 use Email::Address qw//;
   9 use Email::Simple qw//;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use Encode qw/find_encoding/;
  14 my $enc_utf8 = find_encoding('UTF-8');
  15 our $PFX2TERM_RE = undef;
  16 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  17 use POSIX qw(strftime);
  18
  19 sub new {
  20         my ($class, $mime) = @_;
  21         my $doc = Search::Xapian::Document->new;
  22         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  23
  24         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  25 }
  26
  27 sub wrap {
  28         my ($class, $doc, $mid) = @_;
  29         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  30 }
  31
  32 sub get_val ($$) {
  33         my ($doc, $col) = @_;
  34         Search::Xapian::sortable_unserialise($doc->get_value($col));
  35 }
  36
  37 sub load_doc {
  38         my ($class, $doc) = @_;
  39         my $data = $doc->get_data;
  40         my $ts = get_val($doc, &PublicInbox::Search::TS);
  41         $data = $enc_utf8->decode($data);
  42         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  43         bless {
  44                 doc => $doc,
  45                 subject => $subj,
  46                 ts => $ts,
  47                 from => $from,
  48                 references => $refs,
  49                 to => $to,
  50                 cc => $cc,
  51         }, $class;
  52 }
  53
  54 # :bytes and :lines metadata in RFC 3977
  55 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  56 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  57 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  58
  59 sub __hdr ($$) {
  60         my ($self, $field) = @_;
  61         my $val = $self->{$field};
  62         return $val if defined $val;
  63
  64         my $mime = $self->{mime} or return;
  65         $val = $mime->header($field);
  66         $val = '' unless defined $val;
  67         $val =~ tr/\t\r\n/ /;
  68         $self->{$field} = $val;
  69 }
  70
  71 sub subject ($) { __hdr($_[0], 'subject') }
  72 sub to ($) { __hdr($_[0], 'to') }
  73 sub cc ($) { __hdr($_[0], 'cc') }
  74
  75 sub date ($) {
  76         my ($self) = @_;
  77         my $date = __hdr($self, 'date');
  78         return $date if defined $date;
  79         my $ts = $self->{ts};
  80         return unless defined $ts;
  81         $self->{date} = strftime('%a, %d %b %Y %T %z', gmtime($ts));
  82 }
  83
  84 sub from ($) {
  85         my ($self) = @_;
  86         my $from = __hdr($self, 'from');
  87         if (defined $from && !defined $self->{from_name}) {
  88                 $from =~ tr/\t\r\n/ /;
  89                 my @from = Email::Address->parse($from);
  90                 $self->{from_name} = $from[0]->name;
  91         }
  92         $from;
  93 }
  94
  95 sub from_name {
  96         my ($self) = @_;
  97         my $from_name = $self->{from_name};
  98         return $from_name if defined $from_name;
  99         $self->from;
 100         $self->{from_name};
 101 }
 102
 103 sub ts {
 104         my ($self) = @_;
 105         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 106 }
 107
 108 sub to_doc_data {
 109         my ($self) = @_;
 110         join("\n", $self->subject, $self->from, $self->references,
 111                 $self->to, $self->cc);
 112 }
 113
 114 sub references {
 115         my ($self) = @_;
 116         my $x = $self->{references};
 117         defined $x ? $x : '';
 118 }
 119
 120 sub ensure_metadata {
 121         my ($self) = @_;
 122         my $doc = $self->{doc};
 123         my $end = $doc->termlist_end;
 124
 125         unless (defined $PFX2TERM_RE) {
 126                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 127                 $PFX2TERM_RE = qr/\A($or)/;
 128         }
 129
 130         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 131                 # ideally we'd move this out of the loop:
 132                 my $i = $doc->termlist_begin;
 133
 134                 $i->skip_to($pfx);
 135                 if ($i != $end) {
 136                         my $val = $i->get_termname;
 137
 138                         if ($val =~ s/$PFX2TERM_RE//o) {
 139                                 $self->{$field} = $val;
 140                         }
 141                 }
 142         }
 143 }
 144
 145 # for threading only
 146 sub mini_mime {
 147         my ($self) = @_;
 148         $self->ensure_metadata;
 149         my @hs = (
 150                 'Subject' => $self->subject,
 151                 'X-PI-From' => $self->from_name,
 152         );
 153
 154         my @h = (
 155                 # prevent Email::Simple::Creator from running,
 156                 # this header is useless for threading as we use X-PI-TS
 157                 # for sorting and display:
 158                 'Date' => EPOCH_822,
 159                 'Message-ID' => "<$self->{mid}>",
 160                 'X-PI-TS' => $self->ts,
 161         );
 162         if (my $refs = $self->{references}) {
 163                 push @h, References => $refs;
 164         }
 165         my $mime = Email::MIME->create(header_str => \@hs, header => \@h);
 166         my $h = $mime->header_obj;
 167
 168         # set these headers manually since Encode::encode('MIME-Q', ...)
 169         # will add spaces to long values when using header_str above.
 170
 171         # drop useless headers Email::MIME set for us
 172         $h->header_set('Date');
 173         $h->header_set('MIME-Version');
 174         $mime;
 175 }
 176
 177 sub mid ($;$) {
 178         my ($self, $mid) = @_;
 179
 180         if (defined $mid) {
 181                 $self->{mid} = $mid;
 182         } elsif (my $rv = $self->{mid}) {
 183                 $rv;
 184         } else {
 185                 $self->ensure_metadata; # needed for ghosts
 186                 $self->{mid} ||= $self->_extract_mid;
 187         }
 188 }
 189
 190 sub _extract_mid {
 191         my ($self) = @_;
 192
 193         my $mid = $self->mime->header('Message-ID');
 194         defined $mid ? mid_clean($mid) : $mid;
 195 }
 196
 197 sub mime {
 198         my ($self, $mime) = @_;
 199         if (defined $mime) {
 200                 $self->{mime} = $mime;
 201         } else {
 202                 # TODO load from git
 203                 $self->{mime};
 204         }
 205 }
 206
 207 sub doc_id {
 208         my ($self, $doc_id) = @_;
 209         if (defined $doc_id) {
 210                 $self->{doc_id} = $doc_id;
 211         } else {
 212                 # TODO load from xapian
 213                 $self->{doc_id};
 214         }
 215 }
 216
 217 sub thread_id {
 218         my ($self) = @_;
 219         my $tid = $self->{thread};
 220         return $tid if defined $tid;
 221         $self->ensure_metadata;
 222         $self->{thread};
 223 }
 224
 225 sub path {
 226         my ($self) = @_;
 227         my $path = $self->{path};
 228         return $path if defined $path;
 229         $self->ensure_metadata;
 230         $self->{path};
 231 }
 232
 233 1;