lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use PublicInbox::MID qw/mid_clean mid_mime/;
  11 use PublicInbox::Address;
  12 use PublicInbox::MsgTime qw(msg_timestamp);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_boolean_term('T' . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get_val ($$) {
  28         my ($doc, $col) = @_;
  29         Search::Xapian::sortable_unserialise($doc->get_value($col));
  30 }
  31
  32 sub load_from_data ($$) {
  33         my ($self) = $_[0]; # data = $_[1]
  34         my ($subj, $from, $refs, $to, $cc, $blob, $mid0) = split(/\n/, $_[1]);
  35         $self->{subject} = $subj;
  36         $self->{from} = $from;
  37         $self->{references} = $refs;
  38         $self->{to} = $to;
  39         $self->{cc} = $cc;
  40         $self->{blob} = $blob;
  41         $self->{mid} = $mid0;
  42 }
  43
  44 sub load_expand {
  45         my ($self) = @_;
  46         my $doc = $self->{doc};
  47         my $data = $doc->get_data or return;
  48         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  49         utf8::decode($data);
  50         load_from_data($self, $data);
  51         $self;
  52 }
  53
  54 sub load_doc {
  55         my ($class, $doc) = @_;
  56         my $data = $doc->get_data or return;
  57         my $ts = get_val($doc, &PublicInbox::Search::TS);
  58         utf8::decode($data);
  59         my $self = bless { doc => $doc, ts => $ts }, $class;
  60         load_from_data($self, $data);
  61         $self
  62 }
  63
  64 # :bytes and :lines metadata in RFC 3977
  65 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  66 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  67 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  68
  69 sub __hdr ($$) {
  70         my ($self, $field) = @_;
  71         my $val = $self->{$field};
  72         return $val if defined $val;
  73
  74         my $mime = $self->{mime} or return;
  75         $val = $mime->header($field);
  76         $val = '' unless defined $val;
  77         $val =~ tr/\n/ /;
  78         $val =~ tr/\r//d;
  79         $self->{$field} = $val;
  80 }
  81
  82 sub subject ($) { __hdr($_[0], 'subject') }
  83 sub to ($) { __hdr($_[0], 'to') }
  84 sub cc ($) { __hdr($_[0], 'cc') }
  85
  86 # no strftime, that is locale-dependent and not for RFC822
  87 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  88 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  89
  90 sub date ($) {
  91         my ($self) = @_;
  92         my $ts = $self->{ts};
  93         return unless defined $ts;
  94         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  95         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  96                                 $mday, $year+1900, $hour, $min, $sec);
  97
  98 }
  99
 100 sub from ($) {
 101         my ($self) = @_;
 102         my $from = __hdr($self, 'from');
 103         if (defined $from && !defined $self->{from_name}) {
 104                 my @n = PublicInbox::Address::names($from);
 105                 $self->{from_name} = join(', ', @n);
 106         }
 107         $from;
 108 }
 109
 110 sub from_name {
 111         my ($self) = @_;
 112         my $from_name = $self->{from_name};
 113         return $from_name if defined $from_name;
 114         $self->from;
 115         $self->{from_name};
 116 }
 117
 118 sub ts {
 119         my ($self) = @_;
 120         $self->{ts} ||= eval {
 121                 msg_timestamp($self->{mime}->header_obj);
 122         } || 0;
 123 }
 124
 125 sub to_doc_data {
 126         my ($self, $oid, $mid0) = @_;
 127         my @rows = ($self->subject, $self->from, $self->references,
 128                         $self->to, $self->cc);
 129         $oid = '' unless defined $oid;
 130         join("\n", @rows, $oid, $mid0);
 131 }
 132
 133 sub references {
 134         my ($self) = @_;
 135         my $x = $self->{references};
 136         defined $x ? $x : '';
 137 }
 138
 139 sub _get_term_val ($$$) {
 140         my ($self, $pfx, $re) = @_;
 141         my $doc = $self->{doc};
 142         my $end = $doc->termlist_end;
 143         my $i = $doc->termlist_begin;
 144         $i->skip_to($pfx);
 145         if ($i != $end) {
 146                 my $val = $i->get_termname;
 147                 $val =~ s/$re// and return $val;
 148         }
 149         undef;
 150 }
 151
 152 sub mid ($;$) {
 153         my ($self, $mid) = @_;
 154
 155         if (defined $mid) {
 156                 $self->{mid} = $mid;
 157         } elsif (my $rv = $self->{mid}) {
 158                 $rv;
 159         } else {
 160                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 161                                 $self->_extract_mid;
 162         }
 163 }
 164
 165 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 166
 167 sub thread_id {
 168         my ($self) = @_;
 169         my $tid = $self->{thread};
 170         return $tid if defined $tid;
 171         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 172 }
 173
 174 # XXX: consider removing this, we can phrase match subject
 175 sub path {
 176         my ($self) = @_;
 177         my $path = $self->{path};
 178         return $path if defined $path;
 179         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 180 }
 181
 182 sub type {
 183         my ($self) = @_;
 184         my $type = $self->{type};
 185         return $type if defined $type;
 186         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 187 }
 188
 189 1;