lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MID qw/mid_clean mid_mime/;
  10 use PublicInbox::Address;
  11 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  12 use Time::Local qw(timegm);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         bless { mime => $mime }, $class;
  17 }
  18
  19 sub wrap {
  20         my ($class, $mid) = @_;
  21         bless { mid => $mid }, $class;
  22 }
  23
  24 sub get {
  25         my ($class, $head, $db, $mid) = @_;
  26         my $doc_id = $head->get_docid;
  27         load_expand(wrap($class, $mid), $db->get_document($doc_id));
  28 }
  29
  30 sub get_val ($$) {
  31         my ($doc, $col) = @_;
  32         Search::Xapian::sortable_unserialise($doc->get_value($col));
  33 }
  34
  35 sub to_doc_data {
  36         my ($self, $oid, $mid0) = @_;
  37         $oid = '' unless defined $oid;
  38         join("\n",
  39                 $self->subject,
  40                 $self->from,
  41                 $self->references,
  42                 $self->to,
  43                 $self->cc,
  44                 $oid,
  45                 $mid0,
  46                 $self->{bytes} || '',
  47                 $self->{lines} || ''
  48         );
  49 }
  50
  51 sub load_from_data ($$) {
  52         my ($self) = $_[0]; # data = $_[1]
  53         (
  54                 $self->{subject},
  55                 $self->{from},
  56                 $self->{references},
  57
  58                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  59                 # some NNTP clients will use that for message displays.
  60                 $self->{to},
  61                 $self->{cc},
  62
  63                 $self->{blob},
  64                 $self->{mid},
  65                 $self->{bytes},
  66                 $self->{lines}
  67         ) = split(/\n/, $_[1]);
  68 }
  69
  70 sub load_expand {
  71         my ($self, $doc) = @_;
  72         my $data = $doc->get_data or return;
  73         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  74         my $dt = get_val($doc, PublicInbox::Search::DT());
  75         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  76         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  77         utf8::decode($data);
  78         load_from_data($self, $data);
  79         $self;
  80 }
  81
  82 sub load_doc {
  83         my ($class, $doc) = @_;
  84         my $self = bless {}, $class;
  85         load_expand($self, $doc);
  86 }
  87
  88 # :bytes and :lines metadata in RFC 3977
  89 sub bytes ($) { $_[0]->{bytes} }
  90 sub lines ($) { $_[0]->{lines} }
  91
  92 sub __hdr ($$) {
  93         my ($self, $field) = @_;
  94         my $val = $self->{$field};
  95         return $val if defined $val;
  96
  97         my $mime = $self->{mime} or return;
  98         $val = $mime->header($field);
  99         $val = '' unless defined $val;
 100         $val =~ tr/\t\n/  /;
 101         $val =~ tr/\r//d;
 102         $self->{$field} = $val;
 103 }
 104
 105 sub subject ($) { __hdr($_[0], 'subject') }
 106 sub to ($) { __hdr($_[0], 'to') }
 107 sub cc ($) { __hdr($_[0], 'cc') }
 108
 109 # no strftime, that is locale-dependent and not for RFC822
 110 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 111 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 112
 113 sub date ($) {
 114         my ($self) = @_;
 115         my $ds = $self->{ds};
 116         return unless defined $ds;
 117         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 118         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 119                                 $mday, $year+1900, $hour, $min, $sec);
 120
 121 }
 122
 123 sub from ($) {
 124         my ($self) = @_;
 125         my $from = __hdr($self, 'from');
 126         if (defined $from && !defined $self->{from_name}) {
 127                 my @n = PublicInbox::Address::names($from);
 128                 $self->{from_name} = join(', ', @n);
 129         }
 130         $from;
 131 }
 132
 133 sub from_name {
 134         my ($self) = @_;
 135         my $from_name = $self->{from_name};
 136         return $from_name if defined $from_name;
 137         $self->from;
 138         $self->{from_name};
 139 }
 140
 141 sub ts {
 142         my ($self) = @_;
 143         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 144 }
 145
 146 sub ds {
 147         my ($self) = @_;
 148         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 149 }
 150
 151 sub references {
 152         my ($self) = @_;
 153         my $x = $self->{references};
 154         defined $x ? $x : '';
 155 }
 156
 157 sub mid ($;$) {
 158         my ($self, $mid) = @_;
 159
 160         if (defined $mid) {
 161                 $self->{mid} = $mid;
 162         } elsif (defined(my $rv = $self->{mid})) {
 163                 $rv;
 164         } else {
 165                 die "NO {mime} for mid\n" unless $self->{mime};
 166                 $self->_extract_mid; # v1 w/o Xapian
 167         }
 168 }
 169
 170 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 171
 172 1;