lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: GPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchMsg;
   5 use strict;
   6 use warnings;
   7 use Search::Xapian;
   8 use Email::Address qw//;
   9 use Email::Simple qw//;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean mid_compressed/;
  13 use Encode qw/find_encoding/;
  14 my $enc_utf8 = find_encoding('UTF-8');
  15 our $PFX2TERM_RE = undef;
  16
  17 sub new {
  18         my ($class, $mime) = @_;
  19         my $doc = Search::Xapian::Document->new;
  20         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  21
  22         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $doc, $mid) = @_;
  27         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  28 }
  29
  30 sub load_doc {
  31         my ($class, $doc) = @_;
  32         my $data = $doc->get_data;
  33         $data = $enc_utf8->decode($data);
  34         my ($mid, $subj, $from, $date) = split(/\n/, $data);
  35         bless {
  36                 doc => $doc,
  37                 mid => $mid,
  38                 subject => $subj,
  39                 date => $date,
  40                 from_name => $from,
  41         }, $class;
  42 }
  43
  44 sub subject {
  45         my ($self) = @_;
  46         my $subj = $self->{subject};
  47         return $subj if defined $subj;
  48         $subj = $self->{mime}->header('Subject');
  49         $subj = '' unless defined $subj;
  50         $subj =~ tr/\n/ /;
  51         $self->{subject} = $subj;
  52 }
  53
  54 sub from {
  55         my ($self) = @_;
  56         my $from = $self->mime->header('From') || '';
  57         my @from;
  58
  59         if ($from) {
  60                 $from =~ tr/\n/ /;
  61                 @from = Email::Address->parse($from);
  62                 $self->{from} = $from[0];
  63                 $from = $from[0]->name;
  64         }
  65         $self->{from_name} = $from;
  66         $self->{from};
  67 }
  68
  69 sub from_name {
  70         my ($self) = @_;
  71         my $from_name = $self->{from_name};
  72         return $from_name if defined $from_name;
  73         $self->from;
  74         $self->{from_name};
  75 }
  76
  77 sub ts {
  78         my ($self) = @_;
  79         my $ts = $self->{ts};
  80         return $ts if $ts;
  81         $self->{date} = undef;
  82         $self->date;
  83         $self->{ts};
  84 }
  85
  86 sub date {
  87         my ($self) = @_;
  88         my $date = $self->{date};
  89         return $date if $date;
  90         my $ts = eval { str2time($self->mime->header('Date')) } || 0;
  91         $self->{ts} = $ts;
  92         $self->{date} = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
  93 }
  94
  95 sub to_doc_data {
  96         my ($self) = @_;
  97
  98         $self->mid . "\n" .
  99         $self->subject . "\n" .
 100         $self->from_name . "\n".
 101         $self->date;
 102 }
 103
 104 sub ensure_metadata {
 105         my ($self) = @_;
 106         my $doc = $self->{doc};
 107         my $i = $doc->termlist_begin;
 108         my $end = $doc->termlist_end;
 109
 110         unless (defined $PFX2TERM_RE) {
 111                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 112                 $PFX2TERM_RE = qr/\A($or)/;
 113         }
 114
 115         for (; $i != $end; $i->inc) {
 116                 my $val = $i->get_termname;
 117
 118                 if ($val =~ s/$PFX2TERM_RE//o) {
 119                         my $field = $PublicInbox::Search::PFX2TERM_RMAP{$1};
 120                         if ($field eq 'references') {
 121                                 my $refs = $self->{references} ||= [];
 122                                 push @$refs, $val;
 123                         } else {
 124                                 $self->{$field} = $val;
 125                         }
 126                 }
 127         }
 128 }
 129
 130 # for threading only
 131 sub mini_mime {
 132         my ($self) = @_;
 133         $self->ensure_metadata;
 134         my @h = (
 135                 Subject => $self->subject,
 136                 'X-PI-From' => $self->from_name,
 137                 'X-PI-Date' => $self->date,
 138                 'X-PI-TS' => $self->ts,
 139                 'Message-ID' => "<$self->{mid}>",
 140         );
 141         if (my $refs = $self->{references}) {
 142                 push @h, References => '<' . join('> <', @$refs) . '>';
 143         }
 144         if (my $irt = $self->{inreplyto}) {
 145                 push @h, 'In-Reply-To' => "<$irt>";
 146         }
 147
 148         Email::MIME->create(header_str => \@h);
 149 }
 150
 151 sub mid {
 152         my ($self, $mid) = @_;
 153
 154         if (defined $mid) {
 155                 $self->{mid} = $mid;
 156         } else {
 157                 $self->ensure_metadata; # needed for ghosts
 158                 $self->{mid} ||= $self->_extract_mid;
 159         }
 160 }
 161
 162 sub _extract_mid {
 163         my ($self) = @_;
 164
 165         my $mid = $self->mime->header('Message-ID');
 166         $mid ? mid_compressed(mid_clean($mid)) : $mid;
 167 }
 168
 169 sub mime {
 170         my ($self, $mime) = @_;
 171         if (defined $mime) {
 172                 $self->{mime} = $mime;
 173         } else {
 174                 # TODO load from git
 175                 $self->{mime};
 176         }
 177 }
 178
 179 sub doc_id {
 180         my ($self, $doc_id) = @_;
 181         if (defined $doc_id) {
 182                 $self->{doc_id} = $doc_id;
 183         } else {
 184                 # TODO load from xapian
 185                 $self->{doc_id};
 186         }
 187 }
 188
 189 sub thread_id {
 190         my ($self) = @_;
 191         my $tid = $self->{thread};
 192         return $tid if defined $tid;
 193         $self->ensure_metadata;
 194         $self->{thread};
 195 }
 196
 197 sub path {
 198         my ($self) = @_;
 199         my $path = $self->{path};
 200         return $path if defined $path;
 201         $self->ensure_metadata;
 202         $self->{path};
 203 }
 204
 205 1;