lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: GPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::SearchMsg;
   5 use strict;
   6 use warnings;
   7 use Search::Xapian;
   8 our $PFX2TERM_RE = undef;
   9
  10 sub new {
  11         my ($class, $mime) = @_;
  12         my $doc = Search::Xapian::Document->new;
  13         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  14
  15         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  16 }
  17
  18 sub wrap {
  19         my ($class, $doc, $mid) = @_;
  20         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  21 }
  22
  23 sub ensure_metadata {
  24         my ($self) = @_;
  25         my $doc = $self->{doc};
  26         my $i = $doc->termlist_begin;
  27         my $end = $doc->termlist_end;
  28
  29         unless (defined $PFX2TERM_RE) {
  30                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
  31                 $PFX2TERM_RE = qr/\A($or)/;
  32         }
  33
  34         for (; $i != $end; $i->inc) {
  35                 my $val = $i->get_termname;
  36
  37                 if ($val =~ s/$PFX2TERM_RE//o) {
  38                         my $field = $PublicInbox::Search::PFX2TERM_RMAP{$1};
  39                         if ($field eq 'references') {
  40                                 my $refs = $self->{references} ||= [];
  41                                 push @$refs, $val;
  42                         } else {
  43                                 $self->{$field} = $val;
  44                         }
  45                 }
  46         }
  47 }
  48
  49 sub mid {
  50         my ($self, $mid) = @_;
  51
  52         if (defined $mid) {
  53             $self->{mid} = $mid;
  54         } else {
  55             $self->{mid} ||= $self->_extract_mid;
  56         }
  57 }
  58
  59 sub _extract_mid {
  60         my ($self) = @_;
  61
  62         my $mid = $self->mime->header('Message-ID');
  63         if ($mid && $mid =~ /<([^>]+)>/) {
  64                 return $1;
  65         }
  66         return $mid;
  67 }
  68
  69 sub mime {
  70         my ($self, $mime) = @_;
  71         if (defined $mime) {
  72                 $self->{mime} = $mime;
  73         } else {
  74                 # TODO load from git
  75                 $self->{mime};
  76         }
  77 }
  78
  79 sub doc_id {
  80         my ($self, $doc_id) = @_;
  81         if (defined $doc_id) {
  82                 $self->{doc_id} = $doc_id;
  83         } else {
  84                 # TODO load from xapian
  85                 $self->{doc_id};
  86         }
  87 }
  88
  89 sub thread_id {
  90         my ($self) = @_;
  91         my $tid = $self->{thread};
  92         return $tid if defined $tid;
  93         $self->ensure_metadata;
  94         $self->{thread};
  95 }
  96
  97 sub path {
  98         my ($self) = @_;
  99         my $path = $self->{path};
 100         return $path if defined $path;
 101         $self->ensure_metadata;
 102         $self->{path};
 103 }
 104
 105 1;