lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use PublicInbox::Address;
  14 our $PFX2TERM_RE = undef;
  15 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  16 use POSIX qw(strftime);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         my $doc = Search::Xapian::Document->new;
  21         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  22
  23         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  24 }
  25
  26 sub wrap {
  27         my ($class, $doc, $mid) = @_;
  28         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  29 }
  30
  31 sub get_val ($$) {
  32         my ($doc, $col) = @_;
  33         Search::Xapian::sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub load_doc {
  37         my ($class, $doc) = @_;
  38         my $data = $doc->get_data or return;
  39         my $ts = get_val($doc, &PublicInbox::Search::TS);
  40         utf8::decode($data);
  41         my ($subj, $from, $refs, $to, $cc) = split(/\n/, $data);
  42         bless {
  43                 doc => $doc,
  44                 subject => $subj,
  45                 ts => $ts,
  46                 from => $from,
  47                 references => $refs,
  48                 to => $to,
  49                 cc => $cc,
  50         }, $class;
  51 }
  52
  53 # :bytes and :lines metadata in RFC 3977
  54 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  55 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  56 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  57
  58 sub __hdr ($$) {
  59         my ($self, $field) = @_;
  60         my $val = $self->{$field};
  61         return $val if defined $val;
  62
  63         my $mime = $self->{mime} or return;
  64         $val = $mime->header($field);
  65         $val = '' unless defined $val;
  66         $val =~ tr/\n/ /;
  67         $val =~ tr/\r//d;
  68         $self->{$field} = $val;
  69 }
  70
  71 sub subject ($) { __hdr($_[0], 'subject') }
  72 sub to ($) { __hdr($_[0], 'to') }
  73 sub cc ($) { __hdr($_[0], 'cc') }
  74
  75 sub date ($) {
  76         my ($self) = @_;
  77         my $date = __hdr($self, 'date');
  78         return $date if defined $date;
  79         my $ts = $self->{ts};
  80         return unless defined $ts;
  81         $self->{date} = strftime('%a, %d %b %Y %T +0000', gmtime($ts));
  82 }
  83
  84 sub from ($) {
  85         my ($self) = @_;
  86         my $from = __hdr($self, 'from');
  87         if (defined $from && !defined $self->{from_name}) {
  88                 $self->{from_name} = PublicInbox::Address::from_name($from);
  89         }
  90         $from;
  91 }
  92
  93 sub from_name {
  94         my ($self) = @_;
  95         my $from_name = $self->{from_name};
  96         return $from_name if defined $from_name;
  97         $self->from;
  98         $self->{from_name};
  99 }
 100
 101 sub ts {
 102         my ($self) = @_;
 103         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 104 }
 105
 106 sub to_doc_data {
 107         my ($self) = @_;
 108         join("\n", $self->subject, $self->from, $self->references,
 109                 $self->to, $self->cc);
 110 }
 111
 112 sub references {
 113         my ($self) = @_;
 114         my $x = $self->{references};
 115         defined $x ? $x : '';
 116 }
 117
 118 sub ensure_metadata {
 119         my ($self) = @_;
 120         my $doc = $self->{doc};
 121         my $end = $doc->termlist_end;
 122
 123         unless (defined $PFX2TERM_RE) {
 124                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 125                 $PFX2TERM_RE = qr/\A($or)/;
 126         }
 127
 128         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 129                 # ideally we'd move this out of the loop:
 130                 my $i = $doc->termlist_begin;
 131
 132                 $i->skip_to($pfx);
 133                 if ($i != $end) {
 134                         my $val = $i->get_termname;
 135
 136                         if ($val =~ s/$PFX2TERM_RE//o) {
 137                                 $self->{$field} = $val;
 138                         }
 139                 }
 140         }
 141 }
 142
 143 # for threading only
 144 sub mini_mime {
 145         my ($self) = @_;
 146         $self->ensure_metadata;
 147         my @h = (
 148                 'Subject' => $self->subject,
 149                 'X-PI-From' => $self->from_name,
 150                 # prevent Email::Simple::Creator from running,
 151                 # this header is useless for threading as we use X-PI-TS
 152                 # for sorting and display:
 153                 'Date' => EPOCH_822,
 154                 'Message-ID' => "<$self->{mid}>",
 155                 'X-PI-TS' => $self->ts,
 156         );
 157         if (my $refs = $self->{references}) {
 158                 push @h, References => $refs;
 159         }
 160         my $mime = Email::MIME->create(header => \@h);
 161         my $h = $mime->header_obj;
 162
 163         # set these headers manually since Encode::encode('MIME-Q', ...)
 164         # will add spaces to long values when using header_str above.
 165
 166         # drop useless headers Email::MIME set for us
 167         $h->header_set('Date');
 168         $h->header_set('MIME-Version');
 169         $mime;
 170 }
 171
 172 sub mid ($;$) {
 173         my ($self, $mid) = @_;
 174
 175         if (defined $mid) {
 176                 $self->{mid} = $mid;
 177         } elsif (my $rv = $self->{mid}) {
 178                 $rv;
 179         } else {
 180                 $self->ensure_metadata; # needed for ghosts
 181                 $self->{mid} ||= $self->_extract_mid;
 182         }
 183 }
 184
 185 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 186
 187 sub mime {
 188         my ($self, $mime) = @_;
 189         if (defined $mime) {
 190                 $self->{mime} = $mime;
 191         } else {
 192                 # TODO load from git
 193                 $self->{mime};
 194         }
 195 }
 196
 197 sub doc_id {
 198         my ($self, $doc_id) = @_;
 199         if (defined $doc_id) {
 200                 $self->{doc_id} = $doc_id;
 201         } else {
 202                 # TODO load from xapian
 203                 $self->{doc_id};
 204         }
 205 }
 206
 207 sub thread_id {
 208         my ($self) = @_;
 209         my $tid = $self->{thread};
 210         return $tid if defined $tid;
 211         $self->ensure_metadata;
 212         $self->{thread};
 213 }
 214
 215 sub path {
 216         my ($self) = @_;
 217         my $path = $self->{path};
 218         return $path if defined $path;
 219         $self->ensure_metadata;
 220         $self->{path};
 221 }
 222
 223 1;