lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use PublicInbox::Address;
  14 our $PFX2TERM_RE = undef;
  15 use constant EPOCH_822 => 'Thu, 01 Jan 1970 00:00:00 +0000';
  16 use POSIX qw(strftime);
  17
  18 sub new {
  19         my ($class, $mime) = @_;
  20         my $doc = Search::Xapian::Document->new;
  21         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  22
  23         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  24 }
  25
  26 sub wrap {
  27         my ($class, $doc, $mid) = @_;
  28         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  29 }
  30
  31 sub get_val ($$) {
  32         my ($doc, $col) = @_;
  33         Search::Xapian::sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub load_doc {
  37         my ($class, $doc) = @_;
  38         my $data = $doc->get_data or return;
  39         my $ts = get_val($doc, &PublicInbox::Search::TS);
  40         utf8::decode($data);
  41         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  42         bless {
  43                 doc => $doc,
  44                 subject => $subj,
  45                 ts => $ts,
  46                 from => $from,
  47                 references => $refs,
  48                 to => $to,
  49                 cc => $cc,
  50                 blob => $blob,
  51         }, $class;
  52 }
  53
  54 # :bytes and :lines metadata in RFC 3977
  55 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  56 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  57 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  58
  59 sub __hdr ($$) {
  60         my ($self, $field) = @_;
  61         my $val = $self->{$field};
  62         return $val if defined $val;
  63
  64         my $mime = $self->{mime} or return;
  65         $val = $mime->header($field);
  66         $val = '' unless defined $val;
  67         $val =~ tr/\n/ /;
  68         $val =~ tr/\r//d;
  69         $self->{$field} = $val;
  70 }
  71
  72 sub subject ($) { __hdr($_[0], 'subject') }
  73 sub to ($) { __hdr($_[0], 'to') }
  74 sub cc ($) { __hdr($_[0], 'cc') }
  75
  76 sub date ($) {
  77         my ($self) = @_;
  78         my $date = __hdr($self, 'date');
  79         return $date if defined $date;
  80         my $ts = $self->{ts};
  81         return unless defined $ts;
  82         $self->{date} = strftime('%a, %d %b %Y %T +0000', gmtime($ts));
  83 }
  84
  85 sub from ($) {
  86         my ($self) = @_;
  87         my $from = __hdr($self, 'from');
  88         if (defined $from && !defined $self->{from_name}) {
  89                 my @n = PublicInbox::Address::names($from);
  90                 $self->{from_name} = join(', ', @n);
  91         }
  92         $from;
  93 }
  94
  95 sub from_name {
  96         my ($self) = @_;
  97         my $from_name = $self->{from_name};
  98         return $from_name if defined $from_name;
  99         $self->from;
 100         $self->{from_name};
 101 }
 102
 103 sub ts {
 104         my ($self) = @_;
 105         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 106 }
 107
 108 sub to_doc_data {
 109         my ($self, $blob) = @_;
 110         my @rows = ($self->subject, $self->from, $self->references,
 111                         $self->to, $self->cc);
 112         push @rows, $blob if defined $blob;
 113         join("\n", @rows);
 114 }
 115
 116 sub references {
 117         my ($self) = @_;
 118         my $x = $self->{references};
 119         defined $x ? $x : '';
 120 }
 121
 122 sub ensure_metadata {
 123         my ($self) = @_;
 124         my $doc = $self->{doc};
 125         my $end = $doc->termlist_end;
 126
 127         unless (defined $PFX2TERM_RE) {
 128                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 129                 $PFX2TERM_RE = qr/\A($or)/;
 130         }
 131
 132         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 133                 # ideally we'd move this out of the loop:
 134                 my $i = $doc->termlist_begin;
 135
 136                 $i->skip_to($pfx);
 137                 if ($i != $end) {
 138                         my $val = $i->get_termname;
 139
 140                         if ($val =~ s/$PFX2TERM_RE//o) {
 141                                 $self->{$field} = $val;
 142                         }
 143                 }
 144         }
 145 }
 146
 147 # for threading only
 148 sub mini_mime {
 149         my ($self) = @_;
 150         $self->ensure_metadata;
 151         my @h = (
 152                 'Subject' => $self->subject,
 153                 'X-PI-From' => $self->from_name,
 154                 # prevent Email::Simple::Creator from running,
 155                 # this header is useless for threading as we use X-PI-TS
 156                 # for sorting and display:
 157                 'Date' => EPOCH_822,
 158                 'Message-ID' => "<$self->{mid}>",
 159                 'X-PI-TS' => $self->ts,
 160         );
 161         if (my $refs = $self->{references}) {
 162                 push @h, References => $refs;
 163         }
 164         my $mime = Email::MIME->create(header => \@h);
 165         my $h = $mime->header_obj;
 166
 167         # set these headers manually since Encode::encode('MIME-Q', ...)
 168         # will add spaces to long values when using header_str above.
 169
 170         # drop useless headers Email::MIME set for us
 171         $h->header_set('Date');
 172         $h->header_set('MIME-Version');
 173         $mime;
 174 }
 175
 176 sub mid ($;$) {
 177         my ($self, $mid) = @_;
 178
 179         if (defined $mid) {
 180                 $self->{mid} = $mid;
 181         } elsif (my $rv = $self->{mid}) {
 182                 $rv;
 183         } else {
 184                 $self->ensure_metadata; # needed for ghosts
 185                 $self->{mid} ||= $self->_extract_mid;
 186         }
 187 }
 188
 189 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 190
 191 sub blob {
 192         my ($self, $x40) = @_;
 193         if (defined $x40) {
 194                 $self->{blob} = $x40;
 195         } else {
 196                 $self->{blob};
 197         }
 198 }
 199
 200 sub mime {
 201         my ($self, $mime) = @_;
 202         if (defined $mime) {
 203                 $self->{mime} = $mime;
 204         } else {
 205                 # TODO load from git
 206                 $self->{mime};
 207         }
 208 }
 209
 210 sub doc_id {
 211         my ($self, $doc_id) = @_;
 212         if (defined $doc_id) {
 213                 $self->{doc_id} = $doc_id;
 214         } else {
 215                 # TODO load from xapian
 216                 $self->{doc_id};
 217         }
 218 }
 219
 220 sub thread_id {
 221         my ($self) = @_;
 222         my $tid = $self->{thread};
 223         return $tid if defined $tid;
 224         $self->ensure_metadata;
 225         $self->{thread};
 226 }
 227
 228 sub path {
 229         my ($self) = @_;
 230         my $path = $self->{path};
 231         return $path if defined $path;
 232         $self->ensure_metadata;
 233         $self->{path};
 234 }
 235
 236 1;