lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use PublicInbox::MID qw/mid_clean mid_mime/;
  11 use PublicInbox::Address;
  12 use PublicInbox::MsgTime qw(msg_timestamp);
  13
  14 sub new {
  15         my ($class, $mime) = @_;
  16         my $doc = Search::Xapian::Document->new;
  17         $doc->add_boolean_term('T' . 'mail');
  18
  19         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  20 }
  21
  22 sub wrap {
  23         my ($class, $doc, $mid) = @_;
  24         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  25 }
  26
  27 sub get_val ($$) {
  28         my ($doc, $col) = @_;
  29         Search::Xapian::sortable_unserialise($doc->get_value($col));
  30 }
  31
  32 sub load_from_data ($$) {
  33         my ($self) = $_[0]; # data = $_[1]
  34         my ($subj, $from, $refs, $to, $cc, $blob, $mid0) = split(/\n/, $_[1]);
  35         $self->{subject} = $subj;
  36         $self->{from} = $from;
  37         $self->{references} = $refs;
  38         $self->{to} = $to;
  39         $self->{cc} = $cc;
  40         $self->{blob} = $blob;
  41         $self->{mid} = $mid0;
  42 }
  43
  44 sub load_expand {
  45         my ($self) = @_;
  46         my $doc = $self->{doc};
  47         my $data = $doc->get_data or return;
  48         $self->{ts} = get_val($doc, &PublicInbox::Search::TS);
  49         utf8::decode($data);
  50         load_from_data($self, $data);
  51         $self;
  52 }
  53
  54 sub load_doc {
  55         my ($class, $doc) = @_;
  56         my $data = $doc->get_data or return;
  57         my $ts = get_val($doc, &PublicInbox::Search::TS);
  58         utf8::decode($data);
  59         my $self = bless { doc => $doc, ts => $ts }, $class;
  60         load_from_data($self, $data);
  61         $self
  62 }
  63
  64 # :bytes and :lines metadata in RFC 3977
  65 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  66 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  67 sub num ($) {
  68         $_[0]->{num} ||= get_val($_[0]->{doc}, PublicInbox::Search::NUM)
  69 }
  70
  71 sub __hdr ($$) {
  72         my ($self, $field) = @_;
  73         my $val = $self->{$field};
  74         return $val if defined $val;
  75
  76         my $mime = $self->{mime} or return;
  77         $val = $mime->header($field);
  78         $val = '' unless defined $val;
  79         $val =~ tr/\n/ /;
  80         $val =~ tr/\r//d;
  81         $self->{$field} = $val;
  82 }
  83
  84 sub subject ($) { __hdr($_[0], 'subject') }
  85 sub to ($) { __hdr($_[0], 'to') }
  86 sub cc ($) { __hdr($_[0], 'cc') }
  87
  88 # no strftime, that is locale-dependent and not for RFC822
  89 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
  90 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  91
  92 sub date ($) {
  93         my ($self) = @_;
  94         my $ts = $self->{ts};
  95         return unless defined $ts;
  96         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ts);
  97         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
  98                                 $mday, $year+1900, $hour, $min, $sec);
  99
 100 }
 101
 102 sub from ($) {
 103         my ($self) = @_;
 104         my $from = __hdr($self, 'from');
 105         if (defined $from && !defined $self->{from_name}) {
 106                 my @n = PublicInbox::Address::names($from);
 107                 $self->{from_name} = join(', ', @n);
 108         }
 109         $from;
 110 }
 111
 112 sub from_name {
 113         my ($self) = @_;
 114         my $from_name = $self->{from_name};
 115         return $from_name if defined $from_name;
 116         $self->from;
 117         $self->{from_name};
 118 }
 119
 120 sub ts {
 121         my ($self) = @_;
 122         $self->{ts} ||= eval {
 123                 msg_timestamp($self->{mime}->header_obj);
 124         } || 0;
 125 }
 126
 127 sub to_doc_data {
 128         my ($self, $oid, $mid0) = @_;
 129         my @rows = ($self->subject, $self->from, $self->references,
 130                         $self->to, $self->cc);
 131         $oid = '' unless defined $oid;
 132         join("\n", @rows, $oid, $mid0);
 133 }
 134
 135 sub references {
 136         my ($self) = @_;
 137         my $x = $self->{references};
 138         defined $x ? $x : '';
 139 }
 140
 141 sub _get_term_val ($$$) {
 142         my ($self, $pfx, $re) = @_;
 143         my $doc = $self->{doc};
 144         my $end = $doc->termlist_end;
 145         my $i = $doc->termlist_begin;
 146         $i->skip_to($pfx);
 147         if ($i != $end) {
 148                 my $val = $i->get_termname;
 149                 $val =~ s/$re// and return $val;
 150         }
 151         undef;
 152 }
 153
 154 sub mid ($;$) {
 155         my ($self, $mid) = @_;
 156
 157         if (defined $mid) {
 158                 $self->{mid} = $mid;
 159         } elsif (my $rv = $self->{mid}) {
 160                 $rv;
 161         } else {
 162                 $self->{mid} = _get_term_val($self, 'Q', qr/\AQ/) ||
 163                                 $self->_extract_mid;
 164         }
 165 }
 166
 167 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 168
 169 sub thread_id {
 170         my ($self) = @_;
 171         my $tid = $self->{thread};
 172         return $tid if defined $tid;
 173         $self->{thread} = _get_term_val($self, 'G', qr/\AG/); # *G*roup
 174 }
 175
 176 # XXX: consider removing this, we can phrase match subject
 177 sub path {
 178         my ($self) = @_;
 179         my $path = $self->{path};
 180         return $path if defined $path;
 181         $self->{path} = _get_term_val($self, 'XPATH', qr/\AXPATH/); # path
 182 }
 183
 184 sub type {
 185         my ($self) = @_;
 186         my $type = $self->{type};
 187         return $type if defined $type;
 188         $self->{type} = _get_term_val($self, 'T', qr/\AT/);
 189 }
 190
 191 1;