lib/PublicInbox/SearchMsg.pm

   1 # Copyright (C) 2015-2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Wraps a document inside our Xapian search index.
   6 package PublicInbox::SearchMsg;
   7 use strict;
   8 use warnings;
   9 use Search::Xapian;
  10 use POSIX qw//;
  11 use Date::Parse qw/str2time/;
  12 use PublicInbox::MID qw/mid_clean/;
  13 use PublicInbox::Address;
  14 our $PFX2TERM_RE = undef;
  15 use POSIX qw(strftime);
  16
  17 sub new {
  18         my ($class, $mime) = @_;
  19         my $doc = Search::Xapian::Document->new;
  20         $doc->add_term(PublicInbox::Search::xpfx('type') . 'mail');
  21
  22         bless { type => 'mail', doc => $doc, mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $doc, $mid) = @_;
  27         bless { doc => $doc, mime => undef, mid => $mid }, $class;
  28 }
  29
  30 sub get_val ($$) {
  31         my ($doc, $col) = @_;
  32         Search::Xapian::sortable_unserialise($doc->get_value($col));
  33 }
  34
  35 sub load_doc {
  36         my ($class, $doc) = @_;
  37         my $data = $doc->get_data or return;
  38         my $ts = get_val($doc, &PublicInbox::Search::TS);
  39         utf8::decode($data);
  40         my ($subj, $from, $refs, $to, $cc, $blob) = split(/\n/, $data);
  41         bless {
  42                 doc => $doc,
  43                 subject => $subj,
  44                 ts => $ts,
  45                 from => $from,
  46                 references => $refs,
  47                 to => $to,
  48                 cc => $cc,
  49                 blob => $blob,
  50         }, $class;
  51 }
  52
  53 # :bytes and :lines metadata in RFC 3977
  54 sub bytes ($) { get_val($_[0]->{doc}, &PublicInbox::Search::BYTES) }
  55 sub lines ($) { get_val($_[0]->{doc}, &PublicInbox::Search::LINES) }
  56 sub num ($) { get_val($_[0]->{doc}, &PublicInbox::Search::NUM) }
  57
  58 sub __hdr ($$) {
  59         my ($self, $field) = @_;
  60         my $val = $self->{$field};
  61         return $val if defined $val;
  62
  63         my $mime = $self->{mime} or return;
  64         $val = $mime->header($field);
  65         $val = '' unless defined $val;
  66         $val =~ tr/\n/ /;
  67         $val =~ tr/\r//d;
  68         $self->{$field} = $val;
  69 }
  70
  71 sub subject ($) { __hdr($_[0], 'subject') }
  72 sub to ($) { __hdr($_[0], 'to') }
  73 sub cc ($) { __hdr($_[0], 'cc') }
  74
  75 sub date ($) {
  76         my ($self) = @_;
  77         my $date = __hdr($self, 'date');
  78         return $date if defined $date;
  79         my $ts = $self->{ts};
  80         return unless defined $ts;
  81         $self->{date} = strftime('%a, %d %b %Y %T +0000', gmtime($ts));
  82 }
  83
  84 sub from ($) {
  85         my ($self) = @_;
  86         my $from = __hdr($self, 'from');
  87         if (defined $from && !defined $self->{from_name}) {
  88                 my @n = PublicInbox::Address::names($from);
  89                 $self->{from_name} = join(', ', @n);
  90         }
  91         $from;
  92 }
  93
  94 sub from_name {
  95         my ($self) = @_;
  96         my $from_name = $self->{from_name};
  97         return $from_name if defined $from_name;
  98         $self->from;
  99         $self->{from_name};
 100 }
 101
 102 sub ts {
 103         my ($self) = @_;
 104         $self->{ts} ||= eval { str2time($self->mime->header('Date')) } || 0;
 105 }
 106
 107 sub to_doc_data {
 108         my ($self, $blob) = @_;
 109         my @rows = ($self->subject, $self->from, $self->references,
 110                         $self->to, $self->cc);
 111         push @rows, $blob if defined $blob;
 112         join("\n", @rows);
 113 }
 114
 115 sub references {
 116         my ($self) = @_;
 117         my $x = $self->{references};
 118         defined $x ? $x : '';
 119 }
 120
 121 sub ensure_metadata {
 122         my ($self) = @_;
 123         my $doc = $self->{doc};
 124         my $end = $doc->termlist_end;
 125
 126         unless (defined $PFX2TERM_RE) {
 127                 my $or = join('|', keys %PublicInbox::Search::PFX2TERM_RMAP);
 128                 $PFX2TERM_RE = qr/\A($or)/;
 129         }
 130
 131         while (my ($pfx, $field) = each %PublicInbox::Search::PFX2TERM_RMAP) {
 132                 # ideally we'd move this out of the loop:
 133                 my $i = $doc->termlist_begin;
 134
 135                 $i->skip_to($pfx);
 136                 if ($i != $end) {
 137                         my $val = $i->get_termname;
 138
 139                         if ($val =~ s/$PFX2TERM_RE//o) {
 140                                 $self->{$field} = $val;
 141                         }
 142                 }
 143         }
 144 }
 145
 146 sub mid ($;$) {
 147         my ($self, $mid) = @_;
 148
 149         if (defined $mid) {
 150                 $self->{mid} = $mid;
 151         } elsif (my $rv = $self->{mid}) {
 152                 $rv;
 153         } else {
 154                 $self->ensure_metadata; # needed for ghosts
 155                 $self->{mid} ||= $self->_extract_mid;
 156         }
 157 }
 158
 159 sub _extract_mid { mid_clean(mid_mime($_[0]->mime)) }
 160
 161 sub blob {
 162         my ($self, $x40) = @_;
 163         if (defined $x40) {
 164                 $self->{blob} = $x40;
 165         } else {
 166                 $self->{blob};
 167         }
 168 }
 169
 170 sub mime {
 171         my ($self, $mime) = @_;
 172         if (defined $mime) {
 173                 $self->{mime} = $mime;
 174         } else {
 175                 # TODO load from git
 176                 $self->{mime};
 177         }
 178 }
 179
 180 sub doc_id {
 181         my ($self, $doc_id) = @_;
 182         if (defined $doc_id) {
 183                 $self->{doc_id} = $doc_id;
 184         } else {
 185                 # TODO load from xapian
 186                 $self->{doc_id};
 187         }
 188 }
 189
 190 sub thread_id {
 191         my ($self) = @_;
 192         my $tid = $self->{thread};
 193         return $tid if defined $tid;
 194         $self->ensure_metadata;
 195         $self->{thread};
 196 }
 197
 198 sub path {
 199         my ($self) = @_;
 200         my $path = $self->{path};
 201         return $path if defined $path;
 202         $self->ensure_metadata;
 203         $self->{path};
 204 }
 205
 206 1;