lib/PublicInbox/SearchThread.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # Our own jwz-style threading class based on Mail::Thread from CPAN.
   7 # Mail::Thread is unmaintained and available on some distros.
   8 # We also do not want pruning or subject grouping, since we want
   9 # to encourage strict threading and hopefully encourage people
  10 # to use proper In-Reply-To.
  11 #
  12 # This includes fixes from several open bugs for Mail::Thread
  13 #
  14 # Avoid circular references
  15 # - https://rt.cpan.org/Public/Bug/Display.html?id=22817
  16 #
  17 # And avoid recursion in recurse_down:
  18 # - https://rt.cpan.org/Ticket/Display.html?id=116727
  19 # - http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=833479
  20 package PublicInbox::SearchThread;
  21 use strict;
  22 use warnings;
  23
  24 sub new {
  25         return bless {
  26                 messages => $_[1],
  27                 id_table => {},
  28                 rootset  => []
  29         }, $_[0];
  30 }
  31
  32 sub thread {
  33         my $self = shift;
  34         _add_message($self, $_) foreach @{$self->{messages}};
  35         my $id_table = delete $self->{id_table};
  36         $self->{rootset} = [ grep { !$_->{parent} } values %$id_table ];
  37 }
  38
  39 sub _get_cont_for_id ($$) {
  40         my ($self, $mid) = @_;
  41         $self->{id_table}{$mid} ||= PublicInbox::SearchThread::Msg->new($mid);
  42 }
  43
  44 sub _add_message ($$) {
  45         my ($self, $smsg) = @_;
  46
  47         # A. if id_table...
  48         my $this = _get_cont_for_id($self, $smsg->{mid});
  49         $this->{smsg} = $smsg;
  50
  51         # B. For each element in the message's References field:
  52         my $prev;
  53         if (defined(my $refs = $smsg->{references})) {
  54                 foreach my $ref ($refs =~ m/<([^>]+)>/g) {
  55                         # Find a Container object for the given Message-ID
  56                         my $cont = _get_cont_for_id($self, $ref);
  57
  58                         # Link the References field's Containers together in
  59                         # the order implied by the References header
  60                         #
  61                         # * If they are already linked don't change the
  62                         #   existing links
  63                         # * Do not add a link if adding that link would
  64                         #   introduce a loop...
  65                         if ($prev &&
  66                                 !$cont->{parent} &&  # already linked
  67                                 !$cont->has_descendent($prev) # would loop
  68                            ) {
  69                                 $prev->add_child($cont);
  70                         }
  71                         $prev = $cont;
  72                 }
  73         }
  74
  75         # C. Set the parent of this message to be the last element in
  76         # References...
  77         if ($prev && !$this->has_descendent($prev)) { # would loop
  78                 $prev->add_child($this)
  79         }
  80 }
  81
  82 sub order {
  83         my ($self, $ordersub) = @_;
  84         my $rootset = $ordersub->($self->{rootset});
  85         $self->{rootset} = $rootset;
  86         $_->order_children($ordersub) for @$rootset;
  87 }
  88
  89 package PublicInbox::SearchThread::Msg;
  90 use strict;
  91 use warnings;
  92 use Carp qw(croak);
  93 use Scalar::Util qw(weaken);
  94
  95 sub new {
  96         bless {
  97                 id => $_[1],
  98                 children => {}, # becomes an array when sorted by ->order(...)
  99         }, $_[0];
 100 }
 101
 102 sub add_child {
 103         my ($self, $child) = @_;
 104         croak "Cowardly refusing to become my own parent: $self"
 105           if $self == $child;
 106
 107         my $cid = $child->{id};
 108         $self->{children}->{$cid} = $child;
 109
 110         # reparenting:
 111         if (defined(my $parent = $child->{parent})) {
 112                 delete $parent->{children}->{$cid};
 113         }
 114
 115         weaken($child->{parent} = $self);
 116 }
 117
 118 sub has_descendent {
 119         my ($cur, $child) = @_;
 120         my %seen;
 121         my @q = ($cur->{parent} || $cur);
 122
 123         while (defined($cur = shift @q)) {
 124                 return 1 if $cur == $child;
 125
 126                 if (!$seen{$cur}++) {
 127                         push @q, values %{$cur->{children}};
 128                 }
 129         }
 130         0;
 131 }
 132
 133 sub order_children {
 134         my ($cur, $ordersub) = @_;
 135
 136         my %seen = ($cur => 1);
 137         my @q = ($cur);
 138         while (defined($cur = shift @q)) {
 139                 my $c = $cur->{children}; # The hashref here...
 140
 141                 $c = [ grep { !$seen{$_}++ } values %$c ]; # spot/break loops
 142                 $c = $ordersub->($c) if scalar @$c > 1;
 143                 $cur->{children} = $c; # ...becomes an arrayref
 144                 push @q, @$c;
 145         }
 146 }
 147
 148 1;