lib/PublicInbox/SearchThread.pm

   1 # This library is free software; you can redistribute it and/or modify
   2 # it under the same terms as Perl itself.
   3 #
   4 # This license differs from the rest of public-inbox
   5 #
   6 # Our own jwz-style threading class based on Mail::Thread from CPAN.
   7 # Mail::Thread is unmaintained and unavailable on some distros.
   8 # We also do not want pruning or subject grouping, since we want
   9 # to encourage strict threading and hopefully encourage people
  10 # to use proper In-Reply-To.
  11 #
  12 # This includes fixes from several open bugs for Mail::Thread
  13 #
  14 # Avoid circular references
  15 # - https://rt.cpan.org/Public/Bug/Display.html?id=22817
  16 #
  17 # And avoid recursion in recurse_down:
  18 # - https://rt.cpan.org/Ticket/Display.html?id=116727
  19 # - http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=833479
  20 package PublicInbox::SearchThread;
  21 use strict;
  22 use warnings;
  23
  24 sub new {
  25         return bless {
  26                 messages => $_[1],
  27                 id_table => {},
  28                 rootset  => []
  29         }, $_[0];
  30 }
  31
  32 sub thread {
  33         my $self = shift;
  34         _add_message($self, $_) foreach @{$self->{messages}};
  35         my $id_table = delete $self->{id_table};
  36         $self->{rootset} = [ grep {
  37                 !delete($_->{parent}) && $_->visible } values %$id_table ];
  38 }
  39
  40 sub _get_cont_for_id ($$) {
  41         my ($self, $mid) = @_;
  42         $self->{id_table}{$mid} ||= PublicInbox::SearchThread::Msg->new($mid);
  43 }
  44
  45 sub _add_message ($$) {
  46         my ($self, $smsg) = @_;
  47
  48         # A. if id_table...
  49         my $this = _get_cont_for_id($self, $smsg->{mid});
  50         $this->{smsg} = $smsg;
  51
  52         # B. For each element in the message's References field:
  53         defined(my $refs = $smsg->{references}) or return;
  54
  55         my $prev;
  56         foreach my $ref ($refs =~ m/<([^>]+)>/g) {
  57                 # Find a Container object for the given Message-ID
  58                 my $cont = _get_cont_for_id($self, $ref);
  59
  60                 # Link the References field's Containers together in
  61                 # the order implied by the References header
  62                 #
  63                 # * If they are already linked don't change the
  64                 #   existing links
  65                 # * Do not add a link if adding that link would
  66                 #   introduce a loop...
  67                 if ($prev &&
  68                         !$cont->{parent} &&  # already linked
  69                         !$cont->has_descendent($prev) # would loop
  70                    ) {
  71                         $prev->add_child($cont);
  72                 }
  73                 $prev = $cont;
  74         }
  75
  76         # C. Set the parent of this message to be the last element in
  77         # References...
  78         if ($prev && !$this->has_descendent($prev)) { # would loop
  79                 $prev->add_child($this)
  80         }
  81 }
  82
  83 sub order {
  84         my ($self, $ordersub) = @_;
  85         my $rootset = $ordersub->($self->{rootset});
  86         $self->{rootset} = $rootset;
  87         $_->order_children($ordersub) for @$rootset;
  88 }
  89
  90 package PublicInbox::SearchThread::Msg;
  91 use strict;
  92 use warnings;
  93 use Carp qw(croak);
  94
  95 sub new {
  96         bless {
  97                 id => $_[1],
  98                 children => {}, # becomes an array when sorted by ->order(...)
  99         }, $_[0];
 100 }
 101
 102 sub topmost {
 103         my ($self) = @_;
 104         my @q = ($self);
 105         while (my $cont = shift @q) {
 106                 return $cont if $cont->{smsg};
 107                 push @q, values %{$cont->{children}};
 108         }
 109         undef;
 110 }
 111
 112 sub add_child {
 113         my ($self, $child) = @_;
 114         croak "Cowardly refusing to become my own parent: $self"
 115           if $self == $child;
 116
 117         my $cid = $child->{id};
 118
 119         # reparenting:
 120         if (defined(my $parent = $child->{parent})) {
 121                 delete $parent->{children}->{$cid};
 122         }
 123
 124         $self->{children}->{$cid} = $child;
 125         $child->{parent} = $self;
 126 }
 127
 128 sub has_descendent {
 129         my ($self, $child) = @_;
 130         while ($child) {
 131                 return 1 if $self == $child;
 132                 $child = $child->{parent};
 133         }
 134         0;
 135 }
 136
 137 # Do not show/keep ghosts iff they have no children.  Sometimes
 138 # a ghost Message-ID is the result of a long header line
 139 # being folded/mangled by a MUA, and not a missing message.
 140 sub visible ($) {
 141         my ($self) = @_;
 142         $self->{smsg} || scalar values %{$self->{children}};
 143 }
 144
 145 sub order_children {
 146         my ($cur, $ordersub) = @_;
 147
 148         my %seen = ($cur => 1); # self-referential loop prevention
 149         my @q = ($cur);
 150         while (defined($cur = shift @q)) {
 151                 my $c = $cur->{children}; # The hashref here...
 152
 153                 $c = [ grep { !$seen{$_}++ && visible($_) } values %$c ];
 154                 $c = $ordersub->($c) if scalar @$c > 1;
 155                 $cur->{children} = $c; # ...becomes an arrayref
 156                 push @q, @$c;
 157         }
 158 }
 159
 160 1;