lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use List::Util qw(min max);
   9 use URI::Escape qw(uri_unescape);
  10 use PublicInbox::Smsg;
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href fmt_ts);
  12 use PublicInbox::View;
  13 use PublicInbox::WwwAtomStream;
  14 use PublicInbox::WwwStream qw(html_oneshot);
  15 use PublicInbox::SearchThread;
  16 use PublicInbox::SearchQuery;
  17 use PublicInbox::Search qw(get_pct);
  18 my %rmap_inc;
  19
  20 sub mbox_results {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         if ($ctx->{env}->{'psgi.input'}->read(my $buf, 3)) {
  24                 $q->{t} = 1 if $buf =~ /\Ax=[^0]/;
  25         }
  26         require PublicInbox::Mbox;
  27         $q->{x} eq 'm' ? PublicInbox::Mbox::mbox_all($ctx, $q) :
  28                         sres_top_html($ctx);
  29 }
  30
  31 sub sres_top_html {
  32         my ($ctx) = @_;
  33         my $srch = $ctx->{ibx}->isrch or
  34                 return PublicInbox::WWW::need($ctx, 'Search');
  35         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  36         my $x = $q->{x};
  37         my $o = $q->{o};
  38         my $asc;
  39         if ($o < 0) {
  40                 $asc = 1;
  41                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  42         }
  43
  44         my $code = 200;
  45         # double the limit for expanded views:
  46         my $opts = {
  47                 limit => $q->{l},
  48                 offset => $o,
  49                 relevance => $q->{r},
  50                 threads => $q->{t},
  51                 asc => $asc,
  52         };
  53         my ($mset, $total, $err, $html);
  54 retry:
  55         eval {
  56                 my $query = $q->{'q'};
  57                 $srch->query_approxidate($ctx->{ibx}->git, $query);
  58                 $mset = $srch->mset($query, $opts);
  59                 $total = $mset->get_matches_estimated;
  60         };
  61         $err = $@;
  62         ctx_prepare($q, $ctx);
  63         if ($err) {
  64                 $code = 400;
  65                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  66         } elsif ($total == 0) {
  67                 if (defined($ctx->{-uxs_retried})) {
  68                         # undo retry damage:
  69                         $q->{'q'} = $ctx->{-uxs_retried};
  70                 } elsif (index($q->{'q'}, '%') >= 0) {
  71                         $ctx->{-uxs_retried} = $q->{'q'};
  72                         $q->{'q'} = uri_unescape($q->{'q'});
  73                         goto retry;
  74                 }
  75                 $code = 404;
  76                 $html = "<pre>\n[No results found]</pre><hr>";
  77         } else {
  78                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  79
  80                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  81                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  82                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  83                 $html = '';
  84         }
  85         html_oneshot($ctx, $code);
  86 }
  87
  88 # display non-nested search results similar to what users expect from
  89 # regular WWW search engines:
  90 sub mset_summary {
  91         my ($ctx, $mset, $q) = @_;
  92
  93         my $total = $mset->get_matches_estimated;
  94         my $pad = length("$total");
  95         my $pfx = ' ' x $pad;
  96         my $res = \($ctx->{-html_tip});
  97         my $ibx = $ctx->{ibx};
  98         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  99         my @nums = @{$ibx->isrch->mset_to_artnums($mset)};
 100         my %num2msg = map { $_->{num} => $_ } @{$ibx->over->get_all(@nums)};
 101         my ($min, $max);
 102
 103         foreach my $m ($mset->items) {
 104                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 105                 my $pct = get_pct($m);
 106                 my $num = shift @nums;
 107                 my $smsg = delete($num2msg{$num}) or do {
 108                         eval {
 109                                 $m = "$m $num expired\n";
 110                                 $ctx->{env}->{'psgi.errors'}->print($m);
 111                         };
 112                         next;
 113                 };
 114                 $ctx->{-t_max} //= $smsg->{ts};
 115
 116                 # only when sorting by relevance, ->items is always
 117                 # ordered descending:
 118                 $max //= $pct;
 119                 $min = $pct;
 120
 121                 my $s = ascii_html($smsg->{subject});
 122                 my $f = ascii_html($smsg->{from_name});
 123                 if ($obfs_ibx) {
 124                         obfuscate_addrs($obfs_ibx, $s);
 125                         obfuscate_addrs($obfs_ibx, $f);
 126                 }
 127                 my $date = fmt_ts($smsg->{ds});
 128                 my $mid = mid_href($smsg->{mid});
 129                 $s = '(no subject)' if $s eq '';
 130                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 131                         $s . "</a></b>\n";
 132                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 133         }
 134         if ($q->{r}) { # for descriptions in search_nav_bot
 135                 $q->{-min_pct} = $min;
 136                 $q->{-max_pct} = $max;
 137         }
 138         $$res .= search_nav_bot($mset, $q);
 139         undef;
 140 }
 141
 142 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 143 # messages don't reveal FS layout info in case people use non-standard
 144 # installation paths
 145 sub path2inc ($) {
 146         my $full = $_[0];
 147         if (my $short = $rmap_inc{$full}) {
 148                 return $short;
 149         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 150                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 151                 # fall back to basename as last resort
 152                 $rmap_inc{$full} // (split('/', $full))[-1];
 153         } else {
 154                 $full;
 155         }
 156 }
 157
 158 sub err_txt {
 159         my ($ctx, $err) = @_;
 160         my $u = $ctx->{ibx}->base_url($ctx->{env}) . '_/text/help/';
 161         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 162         $err =~ s!(\S+)!path2inc($1)!sge;
 163         $err = ascii_html($err);
 164         "\nBad query: <b>$err</b>\n" .
 165                 qq{See <a\nhref="$u">$u</a> for help on using search};
 166 }
 167
 168 sub search_nav_top {
 169         my ($mset, $q, $ctx) = @_;
 170         my $m = $q->qs_html(x => 'm', r => undef, t => undef);
 171         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 172         my $initial_q = $ctx->{-uxs_retried};
 173         if (defined $initial_q) {
 174                 my $rewritten = $q->{'q'};
 175                 utf8::decode($initial_q);
 176                 utf8::decode($rewritten);
 177                 $initial_q = ascii_html($initial_q);
 178                 $rewritten = ascii_html($rewritten);
 179                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 180                 $rv .= " returned no results, used:\n";
 181                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 182         }
 183
 184         $rv .= 'Search results ordered by [';
 185         if ($q->{r}) {
 186                 my $d = $q->qs_html(r => 0);
 187                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 188         } else {
 189                 my $d = $q->qs_html(r => 1);
 190                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 191         }
 192
 193         $rv .= ']  view[';
 194
 195         my $x = $q->{x};
 196         if ($x eq '') {
 197                 my $t = $q->qs_html(x => 't');
 198                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 199         } elsif ($q->{x} eq 't') {
 200                 my $s = $q->qs_html(x => '');
 201                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 202         }
 203         my $A = $q->qs_html(x => 'A', r => undef);
 204         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 205         if ($ctx->{ibx}->isrch->has_threadid) {
 206                 $rv .= qq{\n\t\t\tdownload mbox.gz: } .
 207                         # we set name=z w/o using it since it seems required for
 208                         # lynx (but works fine for w3m).
 209                         qq{<input\ntype=submit\nname=z\n} .
 210                                 q{value="results only"/>} .
 211                         qq{|<input\ntype=submit\nname=x\n} .
 212                                 q{value="full threads"/>};
 213         } else { # BOFH needs to --reindex
 214                 $rv .= qq{\n\t\t\t\t\t\tdownload: } .
 215                         qq{<input\ntype=submit\nname=z\nvalue="mbox.gz"/>}
 216         }
 217         $rv .= qq{</pre></form><pre>};
 218 }
 219
 220 sub search_nav_bot {
 221         my ($mset, $q) = @_;
 222         my $total = $mset->get_matches_estimated;
 223         my $l = $q->{l};
 224         my $rv = '</pre><hr><pre id=t>';
 225         my $o = $q->{o};
 226         my $off = $o < 0 ? -($o + 1) : $o;
 227         my $end = $off + $mset->size;
 228         my $beg = $off + 1;
 229
 230         if ($beg <= $end) {
 231                 my $approx = $end == $total ? '' : '~';
 232                 $rv .= "Results $beg-$end of $approx$total";
 233         } else {
 234                 $rv .= "No more results, only $total";
 235         }
 236         my ($next, $join, $prev, $nd, $pd);
 237
 238         if ($o >= 0) { # sort descending
 239                 my $n = $o + $l;
 240                 if ($n < $total) {
 241                         $next = $q->qs_html(o => $n, l => $l);
 242                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(older)';
 243                 }
 244                 if ($o > 0) {
 245                         $join = $n < $total ? ' | ' : "\t";
 246                         my $p = $o - $l;
 247                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 248                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(newer)';
 249                 }
 250         } else { # o < 0, sort ascending
 251                 my $n = $o - $l;
 252
 253                 if (-$n < $total) {
 254                         $next = $q->qs_html(o => $n, l => $l);
 255                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(newer)';
 256                 }
 257                 if ($o < -1) {
 258                         $join = -$n < $total ? ' | ' : "\t";
 259                         my $p = $o + $l;
 260                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 261                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(older)';
 262                 }
 263         }
 264
 265         $rv .= qq{  <a\nhref="?$next"\nrel=next>next $nd</a>} if $next;
 266         $rv .= $join if $join;
 267         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev $pd</a>} if $prev;
 268
 269         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 270         $rv .= qq{ | <a\nhref="?$rev">reverse</a></pre>};
 271 }
 272
 273 sub sort_relevance {
 274         [ sort {
 275                 (eval { $b->topmost->{pct} } // 0) <=>
 276                 (eval { $a->topmost->{pct} } // 0)
 277         } @{$_[0]} ]
 278 }
 279
 280 sub mset_thread {
 281         my ($ctx, $mset, $q) = @_;
 282         my $ibx = $ctx->{ibx};
 283         my @pct = map { get_pct($_) } $mset->items;
 284         my $msgs = $ibx->isrch->mset_to_smsg($ibx, $mset);
 285         my $i = 0;
 286         $_->{pct} = $pct[$i++] for @$msgs;
 287         my $r = $q->{r};
 288         if ($r) { # for descriptions in search_nav_bot
 289                 $q->{-min_pct} = min(@pct);
 290                 $q->{-max_pct} = max(@pct);
 291         }
 292         my $rootset = PublicInbox::SearchThread::thread($msgs,
 293                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 294                 $ctx);
 295         my $skel = search_nav_bot($mset, $q). "<pre>";
 296         $ctx->{-upfx} = '';
 297         $ctx->{anchor_idx} = 1;
 298         $ctx->{cur_level} = 0;
 299         $ctx->{skel} = \$skel;
 300         $ctx->{mapping} = {};
 301         $ctx->{searchview} = 1;
 302         $ctx->{prev_attr} = '';
 303         $ctx->{prev_level} = 0;
 304         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 305
 306         # reduce hash lookups in skel_dump
 307         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 308         PublicInbox::View::walk_thread($rootset, $ctx,
 309                 \&PublicInbox::View::pre_thread);
 310
 311         # link $INBOX_DIR/description text to "recent" view around
 312         # the newest message in this result set:
 313         $ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs);
 314
 315         @$msgs = reverse @$msgs if $r;
 316         $ctx->{msgs} = $msgs;
 317         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 318 }
 319
 320 # callback for PublicInbox::WwwStream::getline
 321 sub mset_thread_i {
 322         my ($ctx, $eml) = @_;
 323         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 324         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 325         my $smsg = shift @{$ctx->{msgs}} or
 326                 $ctx->zmore(${delete($ctx->{skel})});
 327         $smsg;
 328 }
 329
 330 sub ctx_prepare {
 331         my ($q, $ctx) = @_;
 332         my $qh = $q->{'q'};
 333         utf8::decode($qh);
 334         $qh = ascii_html($qh);
 335         $ctx->{-q_value_html} = $qh;
 336         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 337         $ctx->{-title_html} = "$qh - search results";
 338         my $extra = '';
 339         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 340         if (my $x = $q->{x}) {
 341                 $x = ascii_html($x);
 342                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 343         }
 344         $ctx->{-extra_form_html} = $extra;
 345 }
 346
 347 sub adump {
 348         my ($cb, $mset, $q, $ctx) = @_;
 349         $ctx->{ids} = $ctx->{ibx}->isrch->mset_to_artnums($mset);
 350         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 351         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 352 }
 353
 354 # callback for PublicInbox::WwwAtomStream::getline
 355 sub adump_i {
 356         my ($ctx) = @_;
 357         while (my $num = shift @{$ctx->{ids}}) {
 358                 my $smsg = eval { $ctx->{ibx}->over->get_art($num) } or next;
 359                 return $smsg;
 360         }
 361 }
 362
 363 1;