lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval qw/ascii_html/;
  10 use PublicInbox::View;
  11 use PublicInbox::MID qw(mid2path mid_mime mid_clean);
  12 use Email::MIME;
  13 require PublicInbox::Git;
  14 require PublicInbox::Thread;
  15 our $LIM = 50;
  16
  17 sub noop {}
  18
  19 sub sres_top_html {
  20         my ($ctx) = @_;
  21         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  22         my $code = 200;
  23
  24         # double the limit for expanded views:
  25         my $opts = {
  26                 limit => $LIM,
  27                 offset => $q->{o},
  28                 mset => 1,
  29                 relevance => $q->{r},
  30         };
  31         my ($mset, $total);
  32         eval {
  33                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  34                 $total = $mset->get_matches_estimated;
  35         };
  36         my $err = $@;
  37         ctx_prepare($q, $ctx);
  38         my $cb;
  39         if ($err) {
  40                 $code = 400;
  41                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr />';
  42                 $cb = *noop;
  43         } elsif ($total == 0) {
  44                 $code = 404;
  45                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr />";
  46                 $cb = *noop;
  47         } else {
  48                 my $x = $q->{x};
  49                 return sub { adump($_[0], $mset, $q, $ctx) } if ($x eq 'A');
  50
  51                 $ctx->{-html_tip} = search_nav_top($mset, $q) . "\n\n";
  52                 if ($x eq 't') {
  53                         $cb = mset_thread($ctx, $mset, $q);
  54                 } else {
  55                         $cb = mset_summary($ctx, $mset, $q);
  56                 }
  57         }
  58         PublicInbox::WwwStream->response($ctx, $code, $cb);
  59 }
  60
  61 # display non-threaded search results similar to what users expect from
  62 # regular WWW search engines:
  63 sub mset_summary {
  64         my ($ctx, $mset, $q) = @_;
  65
  66         my $total = $mset->get_matches_estimated;
  67         my $pad = length("$total");
  68         my $pfx = ' ' x $pad;
  69         my $res = \($ctx->{-html_tip});
  70         foreach my $m ($mset->items) {
  71                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  72                 my $pct = $m->get_percent;
  73                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  74                 my $s = ascii_html($smsg->subject);
  75                 my $f = ascii_html($smsg->from_name);
  76                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  77                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->as_href;
  78                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  79                         $s . "</a></b>\n";
  80                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
  81         }
  82         $$res .= search_nav_bot($mset, $q);
  83         *noop;
  84 }
  85
  86 sub err_txt {
  87         my ($ctx, $err) = @_;
  88         my $u = '//xapian.org/docs/queryparser.html';
  89         $u = PublicInbox::Hval::prurl($ctx->{cgi}->{env}, $u);
  90         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  91         $err = ascii_html($err);
  92         "\nBad query: <b>$err</b>\n" .
  93                 qq{See <a\nhref="$u">$u</a> for Xapian query syntax};
  94 }
  95
  96 sub search_nav_top {
  97         my ($mset, $q) = @_;
  98
  99         my $rv = "<pre>Search results ordered by [";
 100         if ($q->{r}) {
 101                 my $d = $q->qs_html(r => 0);
 102                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 103         } else {
 104                 my $d = $q->qs_html(r => 1);
 105                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 106         }
 107
 108         $rv .= ']  view[';
 109
 110         my $x = $q->{x};
 111         if ($x eq '') {
 112                 my $t = $q->qs_html(x => 't');
 113                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 114         } elsif ($q->{x} eq 't') {
 115                 my $s = $q->qs_html(x => '');
 116                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 117         }
 118         my $A = $q->qs_html(x => 'A', r => undef);
 119         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 120 }
 121
 122 sub search_nav_bot {
 123         my ($mset, $q) = @_;
 124         my $total = $mset->get_matches_estimated;
 125         my $nr = scalar $mset->items;
 126         my $o = $q->{o};
 127         my $end = $o + $nr;
 128         my $beg = $o + 1;
 129         my $rv = "</pre><hr /><pre>Results $beg-$end of $total";
 130         my $n = $o + $LIM;
 131
 132         if ($n < $total) {
 133                 my $qs = $q->qs_html(o => $n);
 134                 $rv .= qq{, <a\nhref="?$qs"\nrel=next>next</a>}
 135         }
 136         if ($o > 0) {
 137                 $rv .= $n < $total ? '/' : ',      ';
 138                 my $p = $o - $LIM;
 139                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 140                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 141         }
 142         $rv .= '</pre>';
 143 }
 144
 145 sub mset_thread {
 146         my ($ctx, $mset, $q) = @_;
 147         my %pct;
 148         my @m = map {
 149                 my $i = $_;
 150                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 151                 $pct{$m->mid} = $i->get_percent;
 152                 $m = $m->mini_mime;
 153                 $m;
 154         } ($mset->items);
 155
 156         my $th = PublicInbox::Thread->new(@m);
 157         $th->thread;
 158         if ($q->{r}) { # order by relevance
 159                 $th->order(sub {
 160                         sort { (eval { $pct{$b->topmost->messageid} } || 0)
 161                                         <=>
 162                                 (eval { $pct{$a->topmost->messageid} } || 0)
 163                         } @_;
 164                 });
 165         } else { # order by time (default for threaded view)
 166                 $th->order(*PublicInbox::View::sort_ts);
 167         }
 168         my $skel = search_nav_bot($mset, $q). "<pre>";
 169         my $inbox = $ctx->{-inbox};
 170         $ctx->{-upfx} = '';
 171         $ctx->{anchor_idx} = 1;
 172         $ctx->{cur_level} = 0;
 173         $ctx->{dst} = \$skel;
 174         $ctx->{mapping} = {};
 175         $ctx->{pct} = \%pct;
 176         $ctx->{prev_attr} = '';
 177         $ctx->{prev_level} = 0;
 178         $ctx->{seen} = {};
 179
 180         PublicInbox::View::walk_thread($th, $ctx,
 181                 *PublicInbox::View::pre_thread);
 182
 183         my $msgs = \@m;
 184         my $mime;
 185         sub {
 186                 return unless $msgs;
 187                 while ($mime = shift @$msgs) {
 188                         my $mid = mid_clean(mid_mime($mime));
 189                         $mime = $inbox->msg_by_mid($mid) and last;
 190                 }
 191                 if ($mime) {
 192                         $mime = Email::MIME->new($mime);
 193                         return PublicInbox::View::index_entry($mime, $ctx);
 194                 }
 195                 $msgs = undef;
 196                 $skel .= "\n</pre>";
 197         };
 198 }
 199
 200 sub ctx_prepare {
 201         my ($q, $ctx) = @_;
 202         my $qh = ascii_html($q->{'q'});
 203         $ctx->{-q_value_html} = $qh;
 204         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 205         $ctx->{-title_html} = "$qh - search results";
 206         my $extra = '';
 207         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 208         if (my $x = $q->{x}) {
 209                 $x = ascii_html($x);
 210                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 211         }
 212         $ctx->{-extra_form_html} = $extra;
 213 }
 214
 215 sub adump {
 216         my ($cb, $mset, $q, $ctx) = @_;
 217         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
 218         my $ibx = $ctx->{-inbox};
 219         my $feed_opts = PublicInbox::Feed::get_feedopts($ctx);
 220         my $x = ascii_html($q->{'q'});
 221         $x = qq{$x - search results};
 222         $feed_opts->{atomurl} = $feed_opts->{url} . '?'. $q->qs_html;
 223         $feed_opts->{url} .= '?'. $q->qs_html(x => undef);
 224         $x = PublicInbox::Feed::atom_header($feed_opts, $x);
 225         $fh->write($x. PublicInbox::Feed::feed_updated());
 226
 227         for ($mset->items) {
 228                 $x = PublicInbox::SearchMsg->load_doc($_->get_document)->mid;
 229                 $x = mid2path($x);
 230                 my $s = PublicInbox::Feed::feed_entry($feed_opts, $x, $ibx);
 231                 $fh->write($s) if defined $s;
 232         }
 233         PublicInbox::Feed::end_feed($fh);
 234 }
 235
 236 package PublicInbox::SearchQuery;
 237 use strict;
 238 use warnings;
 239 use PublicInbox::Hval;
 240
 241 sub new {
 242         my ($class, $qp) = @_;
 243
 244         my $r = $qp->{r};
 245         bless {
 246                 q => $qp->{'q'},
 247                 x => $qp->{x} || '',
 248                 o => (($qp->{o} || '0') =~ /(\d+)/),
 249                 r => (defined $r && $r ne '0'),
 250         }, $class;
 251 }
 252
 253 sub qs_html {
 254         my ($self, %over) = @_;
 255
 256         if (keys %over) {
 257                 my $tmp = bless { %$self }, ref($self);
 258                 foreach my $k (keys %over) {
 259                         $tmp->{$k} = $over{$k};
 260                 }
 261                 $self = $tmp;
 262         }
 263
 264         my $q = PublicInbox::Hval->new($self->{'q'})->as_href;
 265         $q =~ s/%20/+/g; # improve URL readability
 266         my $qs = "q=$q";
 267
 268         if (my $o = $self->{o}) { # ignore o == 0
 269                 $qs .= "&amp;o=$o";
 270         }
 271         if (my $r = $self->{r}) {
 272                 $qs .= "&amp;r";
 273         }
 274         if (my $x = $self->{x}) {
 275                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 276         }
 277         $qs;
 278 }
 279
 280 1;