lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::SearchThread;
  14 our $LIM = 200;
  15 my %rmap_inc;
  16
  17 sub noop {}
  18
  19 sub mbox_results {
  20         my ($ctx) = @_;
  21         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  22         my $x = $q->{x};
  23         require PublicInbox::Mbox;
  24         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  25         sres_top_html($ctx);
  26 }
  27
  28 sub sres_top_html {
  29         my ($ctx) = @_;
  30         my $srch = $ctx->{-inbox}->search or
  31                 return PublicInbox::WWW::need($ctx, 'Search');
  32         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  33         my $x = $q->{x};
  34         my $query = $q->{'q'};
  35         my $o = $q->{o};
  36         my $asc;
  37         if ($o < 0) {
  38                 $asc = 1;
  39                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  40         }
  41
  42         my $code = 200;
  43         # double the limit for expanded views:
  44         my $opts = {
  45                 limit => $q->{l},
  46                 offset => $o,
  47                 mset => 1,
  48                 relevance => $q->{r},
  49                 asc => $asc,
  50         };
  51         my ($mset, $total, $err, $cb);
  52 retry:
  53         eval {
  54                 $mset = $srch->query($query, $opts);
  55                 $total = $mset->get_matches_estimated;
  56         };
  57         $err = $@;
  58         ctx_prepare($q, $ctx);
  59         if ($err) {
  60                 $code = 400;
  61                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  62                 $cb = *noop;
  63         } elsif ($total == 0) {
  64                 if (defined($ctx->{-uxs_retried})) {
  65                         # undo retry damage:
  66                         $q->{'q'} = $ctx->{-uxs_retried};
  67                 } elsif (index($q->{'q'}, '%') >= 0) {
  68                         $ctx->{-uxs_retried} = $q->{'q'};
  69                         $q->{'q'} = uri_unescape($q->{'q'});
  70                         goto retry;
  71                 }
  72                 $code = 404;
  73                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  74                 $cb = *noop;
  75         } else {
  76                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  77
  78                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  79                 if ($x eq 't') {
  80                         $cb = mset_thread($ctx, $mset, $q);
  81                 } else {
  82                         $cb = mset_summary($ctx, $mset, $q);
  83                 }
  84         }
  85         PublicInbox::WwwStream->response($ctx, $code, $cb);
  86 }
  87
  88 # display non-nested search results similar to what users expect from
  89 # regular WWW search engines:
  90 sub mset_summary {
  91         my ($ctx, $mset, $q) = @_;
  92
  93         my $total = $mset->get_matches_estimated;
  94         my $pad = length("$total");
  95         my $pfx = ' ' x $pad;
  96         my $res = \($ctx->{-html_tip});
  97         my $ibx = $ctx->{-inbox};
  98         my $srch = $ibx->search;
  99         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 100         foreach my $m ($mset->items) {
 101                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 102                 my $pct = get_pct($m);
 103                 my $smsg = PublicInbox::SearchMsg::from_mitem($m, $srch);
 104                 unless ($smsg) {
 105                         eval {
 106                                 $m = "$m ".$m->get_docid . " expired\n";
 107                                 $ctx->{env}->{'psgi.errors'}->print($m);
 108                         };
 109                         next;
 110                 }
 111                 my $s = ascii_html($smsg->subject);
 112                 my $f = ascii_html($smsg->from_name);
 113                 if ($obfs_ibx) {
 114                         obfuscate_addrs($obfs_ibx, $s);
 115                         obfuscate_addrs($obfs_ibx, $f);
 116                 }
 117                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 118                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 119                 $s = '(no subject)' if $s eq '';
 120                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 121                         $s . "</a></b>\n";
 122                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 123         }
 124         $$res .= search_nav_bot($mset, $q);
 125         *noop;
 126 }
 127
 128 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 129 # messages don't reveal FS layout info in case people use non-standard
 130 # installation paths
 131 sub path2inc ($) {
 132         my $full = $_[0];
 133         if (my $short = $rmap_inc{$full}) {
 134                 return $short;
 135         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 136                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 137                 # fall back to basename as last resort
 138                 $rmap_inc{$full} // (split('/', $full))[-1];
 139         } else {
 140                 $full;
 141         }
 142 }
 143
 144 sub err_txt {
 145         my ($ctx, $err) = @_;
 146         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 147         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 148         $err =~ s!(\S+)!path2inc($1)!sge;
 149         $err = ascii_html($err);
 150         "\nBad query: <b>$err</b>\n" .
 151                 qq{See <a\nhref="$u">$u</a> for help on using search};
 152 }
 153
 154 sub search_nav_top {
 155         my ($mset, $q, $ctx) = @_;
 156         my $m = $q->qs_html(x => 'm', r => undef);
 157         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 158         my $initial_q = $ctx->{-uxs_retried};
 159         if (defined $initial_q) {
 160                 my $rewritten = $q->{'q'};
 161                 utf8::decode($initial_q);
 162                 utf8::decode($rewritten);
 163                 $initial_q = ascii_html($initial_q);
 164                 $rewritten = ascii_html($rewritten);
 165                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 166                 $rv .= " returned no results, used:\n";
 167                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 168         }
 169
 170         $rv .= 'Search results ordered by [';
 171         if ($q->{r}) {
 172                 my $d = $q->qs_html(r => 0);
 173                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 174         } else {
 175                 my $d = $q->qs_html(r => 1);
 176                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 177         }
 178
 179         $rv .= ']  view[';
 180
 181         my $x = $q->{x};
 182         if ($x eq '') {
 183                 my $t = $q->qs_html(x => 't');
 184                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 185         } elsif ($q->{x} eq 't') {
 186                 my $s = $q->qs_html(x => '');
 187                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 188         }
 189         my $A = $q->qs_html(x => 'A', r => undef);
 190         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 191         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 192         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 193 }
 194
 195 sub search_nav_bot {
 196         my ($mset, $q) = @_;
 197         my $total = $mset->get_matches_estimated;
 198         my $l = $q->{l};
 199         my $rv = '</pre><hr><pre id=t>';
 200         my $o = $q->{o};
 201         my $off = $o < 0 ? -($o + 1) : $o;
 202         my $end = $off + $mset->size;
 203         my $beg = $off + 1;
 204
 205         if ($beg <= $end) {
 206                 $rv .= "Results $beg-$end of $total";
 207                 $rv .= ' (estimated)' if $end != $total;
 208         } else {
 209                 $rv .= "No more results, only $total";
 210         }
 211         my ($next, $join, $prev);
 212
 213         if ($o >= 0) { # sort descending
 214                 my $n = $o + $l;
 215                 if ($n < $total) {
 216                         $next = $q->qs_html(o => $n, l => $l);
 217                 }
 218                 if ($o > 0) {
 219                         $join = $n < $total ? '/' : '       ';
 220                         my $p = $o - $l;
 221                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 222                 }
 223         } else { # o < 0, sort ascending
 224                 my $n = $o - $l;
 225
 226                 if (-$n < $total) {
 227                         $next = $q->qs_html(o => $n, l => $l);
 228                 }
 229                 if ($o < -1) {
 230                         $join = -$n < $total ? '/' : '       ';
 231                         my $p = $o + $l;
 232                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 233                 }
 234         }
 235
 236         $rv .= qq{  <a\nhref="?$next"\nrel=next>next</a>} if $next;
 237         $rv .= $join if $join;
 238         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev</a>} if $prev;
 239
 240         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 241         $rv .= qq{ | <a\nhref="?$rev">reverse results</a></pre>};
 242 }
 243
 244 sub sort_relevance {
 245         [ sort {
 246                 (eval { $b->topmost->{smsg}->{pct} } // 0) <=>
 247                 (eval { $a->topmost->{smsg}->{pct} } // 0)
 248         } @{$_[0]} ]
 249 }
 250
 251 sub get_pct ($) {
 252         # Capped at "99%" since "100%" takes an extra column in the
 253         # thread skeleton view.  <xapian/mset.h> says the value isn't
 254         # very meaningful, anyways.
 255         my $n = $_[0]->get_percent;
 256         $n > 99 ? 99 : $n;
 257 }
 258
 259 sub load_msgs {
 260         my ($mset) = @_;
 261         [ map {
 262                 my $mi = $_;
 263                 my $smsg = PublicInbox::SearchMsg::from_mitem($mi);
 264                 $smsg->{pct} = get_pct($mi);
 265                 $smsg;
 266         } ($mset->items) ]
 267 }
 268
 269 sub mset_thread {
 270         my ($ctx, $mset, $q) = @_;
 271         my $msgs = $ctx->{-inbox}->search->retry_reopen(\&load_msgs, $mset);
 272         my $r = $q->{r};
 273         my $rootset = PublicInbox::SearchThread::thread($msgs,
 274                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 275                 $ctx);
 276         my $skel = search_nav_bot($mset, $q). "<pre>";
 277         $ctx->{-upfx} = '';
 278         $ctx->{anchor_idx} = 1;
 279         $ctx->{cur_level} = 0;
 280         $ctx->{skel} = \$skel;
 281         $ctx->{mapping} = {};
 282         $ctx->{searchview} = 1;
 283         $ctx->{prev_attr} = '';
 284         $ctx->{prev_level} = 0;
 285         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 286
 287         # reduce hash lookups in skel_dump
 288         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 289         PublicInbox::View::walk_thread($rootset, $ctx,
 290                 *PublicInbox::View::pre_thread);
 291
 292         @$msgs = reverse @$msgs if $r;
 293         $ctx->{msgs} = $msgs;
 294         \&mset_thread_i;
 295 }
 296
 297 # callback for PublicInbox::WwwStream::getline
 298 sub mset_thread_i {
 299         my ($nr, $ctx) = @_;
 300         my $msgs = $ctx->{msgs} or return;
 301         while (my $smsg = pop @$msgs) {
 302                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 303                 return PublicInbox::View::index_entry($smsg, $ctx,
 304                                                         scalar @$msgs);
 305         }
 306         my ($skel) = delete @$ctx{qw(skel msgs)};
 307         $$skel .= "\n</pre>";
 308 }
 309
 310 sub ctx_prepare {
 311         my ($q, $ctx) = @_;
 312         my $qh = $q->{'q'};
 313         utf8::decode($qh);
 314         $qh = ascii_html($qh);
 315         $ctx->{-q_value_html} = $qh;
 316         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 317         $ctx->{-title_html} = "$qh - search results";
 318         my $extra = '';
 319         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 320         if (my $x = $q->{x}) {
 321                 $x = ascii_html($x);
 322                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 323         }
 324         $ctx->{-extra_form_html} = $extra;
 325 }
 326
 327 sub adump {
 328         my ($cb, $mset, $q, $ctx) = @_;
 329         $ctx->{items} = [ $mset->items ];
 330         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 331         $ctx->{srch} = $ctx->{-inbox}->search;
 332         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 333 }
 334
 335 # callback for PublicInbox::WwwAtomStream::getline
 336 sub adump_i {
 337         my ($ctx) = @_;
 338         while (my $mi = shift @{$ctx->{items}}) {
 339                 my $smsg = eval {
 340                         PublicInbox::SearchMsg::from_mitem($mi, $ctx->{srch});
 341                 } or next;
 342                 $ctx->{-inbox}->smsg_mime($smsg) and return $smsg;
 343         }
 344 }
 345
 346 package PublicInbox::SearchQuery;
 347 use strict;
 348 use warnings;
 349 use URI::Escape qw(uri_escape);
 350 use PublicInbox::MID qw(MID_ESC);
 351
 352 sub new {
 353         my ($class, $qp) = @_;
 354
 355         my $r = $qp->{r};
 356         my ($l) = (($qp->{l} || '') =~ /([0-9]+)/);
 357         $l = $LIM if !$l || $l > $LIM;
 358         bless {
 359                 q => $qp->{'q'},
 360                 x => $qp->{x} || '',
 361                 o => (($qp->{o} || '0') =~ /(-?[0-9]+)/),
 362                 l => $l,
 363                 r => (defined $r && $r ne '0'),
 364         }, $class;
 365 }
 366
 367 sub qs_html {
 368         my ($self, %over) = @_;
 369
 370         if (keys %over) {
 371                 my $tmp = bless { %$self }, ref($self);
 372                 foreach my $k (keys %over) {
 373                         $tmp->{$k} = $over{$k};
 374                 }
 375                 $self = $tmp;
 376         }
 377
 378         my $q = uri_escape($self->{'q'}, MID_ESC);
 379         $q =~ s/%20/+/g; # improve URL readability
 380         my $qs = "q=$q";
 381
 382         if (my $o = $self->{o}) { # ignore o == 0
 383                 $qs .= "&amp;o=$o";
 384         }
 385         if (my $l = $self->{l}) {
 386                 $qs .= "&amp;l=$l" unless $l == $LIM;
 387         }
 388         if (my $r = $self->{r}) {
 389                 $qs .= "&amp;r";
 390         }
 391         if (my $x = $self->{x}) {
 392                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 393         }
 394         $qs;
 395 }
 396
 397 1;