lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use URI::Escape qw(uri_unescape);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href);
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::WwwStream qw(html_oneshot);
  14 use PublicInbox::SearchThread;
  15 use PublicInbox::SearchQuery;
  16 use PublicInbox::Search qw(mdocid);
  17 my %rmap_inc;
  18
  19 sub mbox_results {
  20         my ($ctx) = @_;
  21         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  22         my $x = $q->{x};
  23         require PublicInbox::Mbox;
  24         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  25         sres_top_html($ctx);
  26 }
  27
  28 sub sres_top_html {
  29         my ($ctx) = @_;
  30         my $srch = $ctx->{-inbox}->search or
  31                 return PublicInbox::WWW::need($ctx, 'Search');
  32         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  33         my $x = $q->{x};
  34         my $query = $q->{'q'};
  35         my $o = $q->{o};
  36         my $asc;
  37         if ($o < 0) {
  38                 $asc = 1;
  39                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  40         }
  41
  42         my $code = 200;
  43         # double the limit for expanded views:
  44         my $opts = {
  45                 limit => $q->{l},
  46                 offset => $o,
  47                 mset => 1,
  48                 relevance => $q->{r},
  49                 asc => $asc,
  50         };
  51         my ($mset, $total, $err, $html);
  52 retry:
  53         eval {
  54                 $mset = $srch->query($query, $opts);
  55                 $total = $mset->get_matches_estimated;
  56         };
  57         $err = $@;
  58         ctx_prepare($q, $ctx);
  59         if ($err) {
  60                 $code = 400;
  61                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  62         } elsif ($total == 0) {
  63                 if (defined($ctx->{-uxs_retried})) {
  64                         # undo retry damage:
  65                         $q->{'q'} = $ctx->{-uxs_retried};
  66                 } elsif (index($q->{'q'}, '%') >= 0) {
  67                         $ctx->{-uxs_retried} = $q->{'q'};
  68                         $q->{'q'} = uri_unescape($q->{'q'});
  69                         goto retry;
  70                 }
  71                 $code = 404;
  72                 $html = "<pre>\n[No results found]</pre><hr>";
  73         } else {
  74                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  75
  76                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  77                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  78                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  79                 $html = '';
  80         }
  81         html_oneshot($ctx, $code);
  82 }
  83
  84 # display non-nested search results similar to what users expect from
  85 # regular WWW search engines:
  86 sub mset_summary {
  87         my ($ctx, $mset, $q) = @_;
  88
  89         my $total = $mset->get_matches_estimated;
  90         my $pad = length("$total");
  91         my $pfx = ' ' x $pad;
  92         my $res = \($ctx->{-html_tip});
  93         my $ibx = $ctx->{-inbox};
  94         my $over = $ibx->over;
  95         my $nshard = $ibx->search->{nshard} // 1;
  96         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  97         foreach my $m ($mset->items) {
  98                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  99                 my $pct = get_pct($m);
 100                 my $num = mdocid($nshard, $m);
 101                 my $smsg = $over->get_art($num, 1);
 102                 unless ($smsg) {
 103                         eval {
 104                                 $m = "$m $num expired\n";
 105                                 $ctx->{env}->{'psgi.errors'}->print($m);
 106                         };
 107                         next;
 108                 }
 109                 PublicInbox::Smsg::psgi_cull($smsg);
 110                 my $s = ascii_html($smsg->{subject});
 111                 my $f = ascii_html($smsg->{from_name});
 112                 if ($obfs_ibx) {
 113                         obfuscate_addrs($obfs_ibx, $s);
 114                         obfuscate_addrs($obfs_ibx, $f);
 115                 }
 116                 my $date = PublicInbox::View::fmt_ts($smsg->{ds});
 117                 my $mid = mid_href($smsg->{mid});
 118                 $s = '(no subject)' if $s eq '';
 119                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 120                         $s . "</a></b>\n";
 121                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 122         }
 123         $$res .= search_nav_bot($mset, $q);
 124         undef;
 125 }
 126
 127 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 128 # messages don't reveal FS layout info in case people use non-standard
 129 # installation paths
 130 sub path2inc ($) {
 131         my $full = $_[0];
 132         if (my $short = $rmap_inc{$full}) {
 133                 return $short;
 134         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 135                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 136                 # fall back to basename as last resort
 137                 $rmap_inc{$full} // (split('/', $full))[-1];
 138         } else {
 139                 $full;
 140         }
 141 }
 142
 143 sub err_txt {
 144         my ($ctx, $err) = @_;
 145         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 146         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 147         $err =~ s!(\S+)!path2inc($1)!sge;
 148         $err = ascii_html($err);
 149         "\nBad query: <b>$err</b>\n" .
 150                 qq{See <a\nhref="$u">$u</a> for help on using search};
 151 }
 152
 153 sub search_nav_top {
 154         my ($mset, $q, $ctx) = @_;
 155         my $m = $q->qs_html(x => 'm', r => undef);
 156         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 157         my $initial_q = $ctx->{-uxs_retried};
 158         if (defined $initial_q) {
 159                 my $rewritten = $q->{'q'};
 160                 utf8::decode($initial_q);
 161                 utf8::decode($rewritten);
 162                 $initial_q = ascii_html($initial_q);
 163                 $rewritten = ascii_html($rewritten);
 164                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 165                 $rv .= " returned no results, used:\n";
 166                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 167         }
 168
 169         $rv .= 'Search results ordered by [';
 170         if ($q->{r}) {
 171                 my $d = $q->qs_html(r => 0);
 172                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 173         } else {
 174                 my $d = $q->qs_html(r => 1);
 175                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 176         }
 177
 178         $rv .= ']  view[';
 179
 180         my $x = $q->{x};
 181         if ($x eq '') {
 182                 my $t = $q->qs_html(x => 't');
 183                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 184         } elsif ($q->{x} eq 't') {
 185                 my $s = $q->qs_html(x => '');
 186                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 187         }
 188         my $A = $q->qs_html(x => 'A', r => undef);
 189         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 190         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 191         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 192 }
 193
 194 sub search_nav_bot {
 195         my ($mset, $q) = @_;
 196         my $total = $mset->get_matches_estimated;
 197         my $l = $q->{l};
 198         my $rv = '</pre><hr><pre id=t>';
 199         my $o = $q->{o};
 200         my $off = $o < 0 ? -($o + 1) : $o;
 201         my $end = $off + $mset->size;
 202         my $beg = $off + 1;
 203
 204         if ($beg <= $end) {
 205                 $rv .= "Results $beg-$end of $total";
 206                 $rv .= ' (estimated)' if $end != $total;
 207         } else {
 208                 $rv .= "No more results, only $total";
 209         }
 210         my ($next, $join, $prev);
 211
 212         if ($o >= 0) { # sort descending
 213                 my $n = $o + $l;
 214                 if ($n < $total) {
 215                         $next = $q->qs_html(o => $n, l => $l);
 216                 }
 217                 if ($o > 0) {
 218                         $join = $n < $total ? '/' : '       ';
 219                         my $p = $o - $l;
 220                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 221                 }
 222         } else { # o < 0, sort ascending
 223                 my $n = $o - $l;
 224
 225                 if (-$n < $total) {
 226                         $next = $q->qs_html(o => $n, l => $l);
 227                 }
 228                 if ($o < -1) {
 229                         $join = -$n < $total ? '/' : '       ';
 230                         my $p = $o + $l;
 231                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 232                 }
 233         }
 234
 235         $rv .= qq{  <a\nhref="?$next"\nrel=next>next</a>} if $next;
 236         $rv .= $join if $join;
 237         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev</a>} if $prev;
 238
 239         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 240         $rv .= qq{ | <a\nhref="?$rev">reverse results</a></pre>};
 241 }
 242
 243 sub sort_relevance {
 244         [ sort {
 245                 (eval { $b->topmost->{pct} } // 0) <=>
 246                 (eval { $a->topmost->{pct} } // 0)
 247         } @{$_[0]} ]
 248 }
 249
 250 sub get_pct ($) {
 251         # Capped at "99%" since "100%" takes an extra column in the
 252         # thread skeleton view.  <xapian/mset.h> says the value isn't
 253         # very meaningful, anyways.
 254         my $n = $_[0]->get_percent;
 255         $n > 99 ? 99 : $n;
 256 }
 257
 258 sub load_msgs {
 259         my ($mset) = @_;
 260         [ map {
 261                 my $mi = $_;
 262                 my $smsg = PublicInbox::Smsg::from_mitem($mi);
 263                 $smsg->{pct} = get_pct($mi);
 264                 $smsg;
 265         } ($mset->items) ]
 266 }
 267
 268 sub mset_thread {
 269         my ($ctx, $mset, $q) = @_;
 270         my $ibx = $ctx->{-inbox};
 271         my $msgs = $ibx->search->retry_reopen(\&load_msgs, $mset);
 272         my $r = $q->{r};
 273         my $rootset = PublicInbox::SearchThread::thread($msgs,
 274                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 275                 $ctx);
 276         my $skel = search_nav_bot($mset, $q). "<pre>";
 277         $ctx->{-upfx} = '';
 278         $ctx->{anchor_idx} = 1;
 279         $ctx->{cur_level} = 0;
 280         $ctx->{skel} = \$skel;
 281         $ctx->{mapping} = {};
 282         $ctx->{searchview} = 1;
 283         $ctx->{prev_attr} = '';
 284         $ctx->{prev_level} = 0;
 285         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 286
 287         # reduce hash lookups in skel_dump
 288         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 289         PublicInbox::View::walk_thread($rootset, $ctx,
 290                 \&PublicInbox::View::pre_thread);
 291
 292         @$msgs = reverse @$msgs if $r;
 293         $ctx->{msgs} = $msgs;
 294         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 295 }
 296
 297 # callback for PublicInbox::WwwStream::getline
 298 sub mset_thread_i {
 299         my ($ctx, $eml) = @_;
 300         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 301         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 302         my $smsg = shift @{$ctx->{msgs}} or
 303                 $ctx->zmore(${delete($ctx->{skel})});
 304         $smsg;
 305 }
 306
 307 sub ctx_prepare {
 308         my ($q, $ctx) = @_;
 309         my $qh = $q->{'q'};
 310         utf8::decode($qh);
 311         $qh = ascii_html($qh);
 312         $ctx->{-q_value_html} = $qh;
 313         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 314         $ctx->{-title_html} = "$qh - search results";
 315         my $extra = '';
 316         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 317         if (my $x = $q->{x}) {
 318                 $x = ascii_html($x);
 319                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 320         }
 321         $ctx->{-extra_form_html} = $extra;
 322 }
 323
 324 sub adump {
 325         my ($cb, $mset, $q, $ctx) = @_;
 326         $ctx->{items} = [ $mset->items ];
 327         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 328         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 329 }
 330
 331 # callback for PublicInbox::WwwAtomStream::getline
 332 sub adump_i {
 333         my ($ctx) = @_;
 334         while (my $mi = shift @{$ctx->{items}}) {
 335                 my $srch = $ctx->{-inbox}->search(undef, $ctx) or return;
 336                 my $smsg = eval {
 337                         PublicInbox::Smsg::from_mitem($mi, $srch);
 338                 } or next;
 339                 return $smsg;
 340         }
 341 }
 342
 343 1;