lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use List::Util qw(max);
   9 use URI::Escape qw(uri_unescape);
  10 use PublicInbox::Smsg;
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href fmt_ts);
  12 use PublicInbox::View;
  13 use PublicInbox::WwwAtomStream;
  14 use PublicInbox::WwwStream qw(html_oneshot);
  15 use PublicInbox::SearchThread;
  16 use PublicInbox::SearchQuery;
  17 use PublicInbox::Search qw(mdocid);
  18 my %rmap_inc;
  19
  20 sub mbox_results {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         if ($ctx->{env}->{'psgi.input'}->read(my $buf, 3)) {
  24                 $q->{t} = 1 if $buf =~ /\Ax=[^0]/;
  25         }
  26         require PublicInbox::Mbox;
  27         $q->{x} eq 'm' ? PublicInbox::Mbox::mbox_all($ctx, $q) :
  28                         sres_top_html($ctx);
  29 }
  30
  31 sub sres_top_html {
  32         my ($ctx) = @_;
  33         my $srch = $ctx->{-inbox}->search or
  34                 return PublicInbox::WWW::need($ctx, 'Search');
  35         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  36         my $x = $q->{x};
  37         my $query = $q->{'q'};
  38         my $o = $q->{o};
  39         my $asc;
  40         if ($o < 0) {
  41                 $asc = 1;
  42                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  43         }
  44
  45         my $code = 200;
  46         # double the limit for expanded views:
  47         my $opts = {
  48                 limit => $q->{l},
  49                 offset => $o,
  50                 mset => 1,
  51                 relevance => $q->{r},
  52                 thread => $q->{t},
  53                 asc => $asc,
  54         };
  55         my ($mset, $total, $err, $html);
  56 retry:
  57         eval {
  58                 $mset = $srch->query($query, $opts);
  59                 $total = $mset->get_matches_estimated;
  60         };
  61         $err = $@;
  62         ctx_prepare($q, $ctx);
  63         if ($err) {
  64                 $code = 400;
  65                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  66         } elsif ($total == 0) {
  67                 if (defined($ctx->{-uxs_retried})) {
  68                         # undo retry damage:
  69                         $q->{'q'} = $ctx->{-uxs_retried};
  70                 } elsif (index($q->{'q'}, '%') >= 0) {
  71                         $ctx->{-uxs_retried} = $q->{'q'};
  72                         $q->{'q'} = uri_unescape($q->{'q'});
  73                         goto retry;
  74                 }
  75                 $code = 404;
  76                 $html = "<pre>\n[No results found]</pre><hr>";
  77         } else {
  78                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  79
  80                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  81                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  82                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  83                 $html = '';
  84         }
  85         html_oneshot($ctx, $code);
  86 }
  87
  88 # display non-nested search results similar to what users expect from
  89 # regular WWW search engines:
  90 sub mset_summary {
  91         my ($ctx, $mset, $q) = @_;
  92
  93         my $total = $mset->get_matches_estimated;
  94         my $pad = length("$total");
  95         my $pfx = ' ' x $pad;
  96         my $res = \($ctx->{-html_tip});
  97         my $ibx = $ctx->{-inbox};
  98         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  99         my @nums = @{$ibx->search->mset_to_artnums($mset)};
 100         my %num2msg = map { $_->{num} => $_ } @{$ibx->over->get_all(@nums)};
 101
 102         foreach my $m ($mset->items) {
 103                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 104                 my $pct = get_pct($m);
 105                 my $num = shift @nums;
 106                 my $smsg = delete($num2msg{$num}) or do {
 107                         eval {
 108                                 $m = "$m $num expired\n";
 109                                 $ctx->{env}->{'psgi.errors'}->print($m);
 110                         };
 111                         next;
 112                 };
 113                 $ctx->{-t_max} //= $smsg->{ts};
 114
 115                 my $s = ascii_html($smsg->{subject});
 116                 my $f = ascii_html($smsg->{from_name});
 117                 if ($obfs_ibx) {
 118                         obfuscate_addrs($obfs_ibx, $s);
 119                         obfuscate_addrs($obfs_ibx, $f);
 120                 }
 121                 my $date = fmt_ts($smsg->{ds});
 122                 my $mid = mid_href($smsg->{mid});
 123                 $s = '(no subject)' if $s eq '';
 124                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 125                         $s . "</a></b>\n";
 126                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 127         }
 128         $$res .= search_nav_bot($mset, $q);
 129         undef;
 130 }
 131
 132 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 133 # messages don't reveal FS layout info in case people use non-standard
 134 # installation paths
 135 sub path2inc ($) {
 136         my $full = $_[0];
 137         if (my $short = $rmap_inc{$full}) {
 138                 return $short;
 139         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 140                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 141                 # fall back to basename as last resort
 142                 $rmap_inc{$full} // (split('/', $full))[-1];
 143         } else {
 144                 $full;
 145         }
 146 }
 147
 148 sub err_txt {
 149         my ($ctx, $err) = @_;
 150         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 151         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 152         $err =~ s!(\S+)!path2inc($1)!sge;
 153         $err = ascii_html($err);
 154         "\nBad query: <b>$err</b>\n" .
 155                 qq{See <a\nhref="$u">$u</a> for help on using search};
 156 }
 157
 158 sub search_nav_top {
 159         my ($mset, $q, $ctx) = @_;
 160         my $m = $q->qs_html(x => 'm', r => undef, t => undef);
 161         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 162         my $initial_q = $ctx->{-uxs_retried};
 163         if (defined $initial_q) {
 164                 my $rewritten = $q->{'q'};
 165                 utf8::decode($initial_q);
 166                 utf8::decode($rewritten);
 167                 $initial_q = ascii_html($initial_q);
 168                 $rewritten = ascii_html($rewritten);
 169                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 170                 $rv .= " returned no results, used:\n";
 171                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 172         }
 173
 174         $rv .= 'Search results ordered by [';
 175         if ($q->{r}) {
 176                 my $d = $q->qs_html(r => 0);
 177                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 178         } else {
 179                 my $d = $q->qs_html(r => 1);
 180                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 181         }
 182
 183         $rv .= ']  view[';
 184
 185         my $x = $q->{x};
 186         if ($x eq '') {
 187                 my $t = $q->qs_html(x => 't');
 188                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 189         } elsif ($q->{x} eq 't') {
 190                 my $s = $q->qs_html(x => '');
 191                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 192         }
 193         my $A = $q->qs_html(x => 'A', r => undef);
 194         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 195         if ($ctx->{-inbox}->search->has_threadid) {
 196                 $rv .= qq{\n\t\t\tdownload mbox.gz: } .
 197                         # we set name=z w/o using it since it seems required for
 198                         # lynx (but works fine for w3m).
 199                         qq{<input\ntype=submit\nname=z\n} .
 200                                 q{value="results only"/>} .
 201                         qq{|<input\ntype=submit\nname=x\n} .
 202                                 q{value="full threads"/>};
 203         } else { # BOFH needs to --reindex
 204                 $rv .= qq{\n\t\t\t\t\t\tdownload: } .
 205                         qq{<input\ntype=submit\nname=z\nvalue="mbox.gz"/>}
 206         }
 207         $rv .= qq{</pre></form><pre>};
 208 }
 209
 210 sub search_nav_bot {
 211         my ($mset, $q) = @_;
 212         my $total = $mset->get_matches_estimated;
 213         my $l = $q->{l};
 214         my $rv = '</pre><hr><pre id=t>';
 215         my $o = $q->{o};
 216         my $off = $o < 0 ? -($o + 1) : $o;
 217         my $end = $off + $mset->size;
 218         my $beg = $off + 1;
 219
 220         if ($beg <= $end) {
 221                 $rv .= "Results $beg-$end of $total";
 222                 $rv .= ' (estimated)' if $end != $total;
 223         } else {
 224                 $rv .= "No more results, only $total";
 225         }
 226         my ($next, $join, $prev);
 227
 228         if ($o >= 0) { # sort descending
 229                 my $n = $o + $l;
 230                 if ($n < $total) {
 231                         $next = $q->qs_html(o => $n, l => $l);
 232                 }
 233                 if ($o > 0) {
 234                         $join = $n < $total ? '/' : '       ';
 235                         my $p = $o - $l;
 236                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 237                 }
 238         } else { # o < 0, sort ascending
 239                 my $n = $o - $l;
 240
 241                 if (-$n < $total) {
 242                         $next = $q->qs_html(o => $n, l => $l);
 243                 }
 244                 if ($o < -1) {
 245                         $join = -$n < $total ? '/' : '       ';
 246                         my $p = $o + $l;
 247                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 248                 }
 249         }
 250
 251         $rv .= qq{  <a\nhref="?$next"\nrel=next>next</a>} if $next;
 252         $rv .= $join if $join;
 253         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev</a>} if $prev;
 254
 255         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 256         $rv .= qq{ | <a\nhref="?$rev">reverse results</a></pre>};
 257 }
 258
 259 sub sort_relevance {
 260         [ sort {
 261                 (eval { $b->topmost->{pct} } // 0) <=>
 262                 (eval { $a->topmost->{pct} } // 0)
 263         } @{$_[0]} ]
 264 }
 265
 266 sub get_pct ($) {
 267         # Capped at "99%" since "100%" takes an extra column in the
 268         # thread skeleton view.  <xapian/mset.h> says the value isn't
 269         # very meaningful, anyways.
 270         my $n = $_[0]->get_percent;
 271         $n > 99 ? 99 : $n;
 272 }
 273
 274 sub mset_thread {
 275         my ($ctx, $mset, $q) = @_;
 276         my $ibx = $ctx->{-inbox};
 277         my $nshard = $ibx->search->{nshard} // 1;
 278         my %pct = map { mdocid($nshard, $_) => get_pct($_) } $mset->items;
 279         my $msgs = $ibx->over->get_all(keys %pct);
 280         $_->{pct} = $pct{$_->{num}} for @$msgs;
 281         my $r = $q->{r};
 282         my $rootset = PublicInbox::SearchThread::thread($msgs,
 283                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 284                 $ctx);
 285         my $skel = search_nav_bot($mset, $q). "<pre>";
 286         $ctx->{-upfx} = '';
 287         $ctx->{anchor_idx} = 1;
 288         $ctx->{cur_level} = 0;
 289         $ctx->{skel} = \$skel;
 290         $ctx->{mapping} = {};
 291         $ctx->{searchview} = 1;
 292         $ctx->{prev_attr} = '';
 293         $ctx->{prev_level} = 0;
 294         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 295
 296         # reduce hash lookups in skel_dump
 297         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 298         PublicInbox::View::walk_thread($rootset, $ctx,
 299                 \&PublicInbox::View::pre_thread);
 300
 301         # link $INBOX_DIR/description text to "recent" view around
 302         # the newest message in this result set:
 303         $ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs);
 304
 305         @$msgs = reverse @$msgs if $r;
 306         $ctx->{msgs} = $msgs;
 307         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 308 }
 309
 310 # callback for PublicInbox::WwwStream::getline
 311 sub mset_thread_i {
 312         my ($ctx, $eml) = @_;
 313         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 314         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 315         my $smsg = shift @{$ctx->{msgs}} or
 316                 $ctx->zmore(${delete($ctx->{skel})});
 317         $smsg;
 318 }
 319
 320 sub ctx_prepare {
 321         my ($q, $ctx) = @_;
 322         my $qh = $q->{'q'};
 323         utf8::decode($qh);
 324         $qh = ascii_html($qh);
 325         $ctx->{-q_value_html} = $qh;
 326         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 327         $ctx->{-title_html} = "$qh - search results";
 328         my $extra = '';
 329         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 330         if (my $x = $q->{x}) {
 331                 $x = ascii_html($x);
 332                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 333         }
 334         $ctx->{-extra_form_html} = $extra;
 335 }
 336
 337 sub adump {
 338         my ($cb, $mset, $q, $ctx) = @_;
 339         $ctx->{ids} = $ctx->{-inbox}->search->mset_to_artnums($mset);
 340         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 341         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 342 }
 343
 344 # callback for PublicInbox::WwwAtomStream::getline
 345 sub adump_i {
 346         my ($ctx) = @_;
 347         while (my $num = shift @{$ctx->{ids}}) {
 348                 my $smsg = eval { $ctx->{-inbox}->over->get_art($num) } or next;
 349                 return $smsg;
 350         }
 351 }
 352
 353 1;