lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub sres_top_html {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $code = 200;
  25
  26         # double the limit for expanded views:
  27         my $opts = {
  28                 limit => $LIM,
  29                 offset => $q->{o},
  30                 mset => 1,
  31                 relevance => $q->{r},
  32         };
  33         my ($mset, $total, $err, $cb);
  34 retry:
  35         eval {
  36                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  37                 $total = $mset->get_matches_estimated;
  38         };
  39         $err = $@;
  40         ctx_prepare($q, $ctx);
  41         if ($err) {
  42                 $code = 400;
  43                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  44                 $cb = *noop;
  45         } elsif ($total == 0) {
  46                 if (defined($ctx->{-uxs_retried})) {
  47                         # undo retry damage:
  48                         $q->{'q'} = $ctx->{-uxs_retried};
  49                 } elsif (index($q->{'q'}, '%') >= 0) {
  50                         $ctx->{-uxs_retried} = $q->{'q'};
  51                         $q->{'q'} = uri_unescape($q->{'q'});
  52                         goto retry;
  53                 }
  54                 $code = 404;
  55                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  56                 $cb = *noop;
  57         } else {
  58                 my $x = $q->{x};
  59                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  60
  61                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx) . "\n\n";
  62                 if ($x eq 't') {
  63                         $cb = mset_thread($ctx, $mset, $q);
  64                 } else {
  65                         $cb = mset_summary($ctx, $mset, $q);
  66                 }
  67         }
  68         PublicInbox::WwwStream->response($ctx, $code, $cb);
  69 }
  70
  71 # allow undef for individual doc loads...
  72 sub load_doc_retry {
  73         my ($srch, $mitem) = @_;
  74
  75         eval {
  76                 $srch->retry_reopen(sub {
  77                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  78                 });
  79         }
  80 }
  81
  82 # display non-threaded search results similar to what users expect from
  83 # regular WWW search engines:
  84 sub mset_summary {
  85         my ($ctx, $mset, $q) = @_;
  86
  87         my $total = $mset->get_matches_estimated;
  88         my $pad = length("$total");
  89         my $pfx = ' ' x $pad;
  90         my $res = \($ctx->{-html_tip});
  91         my $srch = $ctx->{srch};
  92         my $obfs = $ctx->{-inbox}->{obfuscate};
  93         foreach my $m ($mset->items) {
  94                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  95                 my $pct = $m->get_percent;
  96                 my $smsg = load_doc_retry($srch, $m);
  97                 unless ($smsg) {
  98                         eval {
  99                                 $m = "$m ".$m->get_docid . " expired\n";
 100                                 $ctx->{env}->{'psgi.errors'}->print($m);
 101                         };
 102                         next;
 103                 }
 104                 my $s = ascii_html($smsg->subject);
 105                 my $f = ascii_html($smsg->from_name);
 106                 if ($obfs) {
 107                         obfuscate_addrs($s);
 108                         obfuscate_addrs($f);
 109                 }
 110                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
 111                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 112                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 113                         $s . "</a></b>\n";
 114                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
 115         }
 116         $$res .= search_nav_bot($mset, $q);
 117         *noop;
 118 }
 119
 120 sub err_txt {
 121         my ($ctx, $err) = @_;
 122         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 123         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 124         $err = ascii_html($err);
 125         "\nBad query: <b>$err</b>\n" .
 126                 qq{See <a\nhref="$u">$u</a> for help on using search};
 127 }
 128
 129 sub search_nav_top {
 130         my ($mset, $q, $ctx) = @_;
 131
 132         my $rv = '<pre>';
 133         my $initial_q = $ctx->{-uxs_retried};
 134         if (defined $initial_q) {
 135                 my $rewritten = $q->{'q'};
 136                 utf8::decode($initial_q);
 137                 utf8::decode($rewritten);
 138                 $initial_q = ascii_html($initial_q);
 139                 $rewritten = ascii_html($rewritten);
 140                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 141                 $rv .= " returned no results, used:\n";
 142                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 143         }
 144
 145         $rv .= 'Search results ordered by [';
 146         if ($q->{r}) {
 147                 my $d = $q->qs_html(r => 0);
 148                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 149         } else {
 150                 my $d = $q->qs_html(r => 1);
 151                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 152         }
 153
 154         $rv .= ']  view[';
 155
 156         my $x = $q->{x};
 157         if ($x eq '') {
 158                 my $t = $q->qs_html(x => 't');
 159                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 160         } elsif ($q->{x} eq 't') {
 161                 my $s = $q->qs_html(x => '');
 162                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 163         }
 164         my $A = $q->qs_html(x => 'A', r => undef);
 165         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 166 }
 167
 168 sub search_nav_bot {
 169         my ($mset, $q) = @_;
 170         my $total = $mset->get_matches_estimated;
 171         my $nr = scalar $mset->items;
 172         my $o = $q->{o};
 173         my $end = $o + $nr;
 174         my $beg = $o + 1;
 175         my $rv = '</pre><hr><pre id=t>';
 176         if ($beg <= $end) {
 177                 $rv .= "Results $beg-$end of $total";
 178                 $rv .= ' (estimated)' if $end != $total;
 179         } else {
 180                 $rv .= "No more results, only $total";
 181         }
 182         my $n = $o + $LIM;
 183
 184         if ($n < $total) {
 185                 my $qs = $q->qs_html(o => $n);
 186                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 187         }
 188         if ($o > 0) {
 189                 $rv .= $n < $total ? '/' : '       ';
 190                 my $p = $o - $LIM;
 191                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 192                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 193         }
 194         $rv .= '</pre>';
 195 }
 196
 197 sub sort_relevance {
 198         my ($pct) = @_;
 199         sub {
 200                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 201                                 <=>
 202                         (eval { $pct->{$a->topmost->{id}} } || 0)
 203         } @{$_[0]} ] };
 204 }
 205
 206 sub mset_thread {
 207         my ($ctx, $mset, $q) = @_;
 208         my %pct;
 209         my $msgs = $ctx->{srch}->retry_reopen(sub { [ map {
 210                 my $i = $_;
 211                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 212                 $pct{$smsg->mid} = $i->get_percent;
 213                 $smsg;
 214         } ($mset->items) ]});
 215         my $r = $q->{r};
 216         my $rootset = PublicInbox::SearchThread::thread($msgs,
 217                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ts);
 218         my $skel = search_nav_bot($mset, $q). "<pre>";
 219         my $inbox = $ctx->{-inbox};
 220         $ctx->{-upfx} = '';
 221         $ctx->{anchor_idx} = 1;
 222         $ctx->{cur_level} = 0;
 223         $ctx->{dst} = \$skel;
 224         $ctx->{mapping} = {};
 225         $ctx->{pct} = \%pct;
 226         $ctx->{prev_attr} = '';
 227         $ctx->{prev_level} = 0;
 228         $ctx->{seen} = {};
 229         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 230
 231         # reduce hash lookups in skel_dump
 232         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 233         PublicInbox::View::walk_thread($rootset, $ctx,
 234                 *PublicInbox::View::pre_thread);
 235
 236         @$msgs = reverse @$msgs if $r;
 237         my $mime;
 238         sub {
 239                 return unless $msgs;
 240                 while ($mime = pop @$msgs) {
 241                         $mime = $inbox->msg_by_smsg($mime) and last;
 242                 }
 243                 if ($mime) {
 244                         $mime = PublicInbox::MIME->new($mime);
 245                         return PublicInbox::View::index_entry($mime, $ctx,
 246                                 scalar @$msgs);
 247                 }
 248                 $msgs = undef;
 249                 $skel .= "\n</pre>";
 250         };
 251 }
 252
 253 sub ctx_prepare {
 254         my ($q, $ctx) = @_;
 255         my $qh = $q->{'q'};
 256         utf8::decode($qh);
 257         $qh = ascii_html($qh);
 258         $ctx->{-q_value_html} = $qh;
 259         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 260         $ctx->{-title_html} = "$qh - search results";
 261         my $extra = '';
 262         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 263         if (my $x = $q->{x}) {
 264                 $x = ascii_html($x);
 265                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 266         }
 267         $ctx->{-extra_form_html} = $extra;
 268 }
 269
 270 sub adump {
 271         my ($cb, $mset, $q, $ctx) = @_;
 272         my $ibx = $ctx->{-inbox};
 273         my @items = $mset->items;
 274         $ctx->{search_query} = $q;
 275         my $srch = $ctx->{srch};
 276         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 277                 while (my $x = shift @items) {
 278                         $x = load_doc_retry($srch, $x);
 279                         $x = $ibx->msg_by_smsg($x) and
 280                                         return PublicInbox::MIME->new($x);
 281                 }
 282                 return undef;
 283         });
 284 }
 285
 286 package PublicInbox::SearchQuery;
 287 use strict;
 288 use warnings;
 289 use URI::Escape qw(uri_escape);
 290 use PublicInbox::Hval;
 291 use PublicInbox::MID qw(MID_ESC);
 292
 293 sub new {
 294         my ($class, $qp) = @_;
 295
 296         my $r = $qp->{r};
 297         bless {
 298                 q => $qp->{'q'},
 299                 x => $qp->{x} || '',
 300                 o => (($qp->{o} || '0') =~ /(\d+)/),
 301                 r => (defined $r && $r ne '0'),
 302         }, $class;
 303 }
 304
 305 sub qs_html {
 306         my ($self, %over) = @_;
 307
 308         if (keys %over) {
 309                 my $tmp = bless { %$self }, ref($self);
 310                 foreach my $k (keys %over) {
 311                         $tmp->{$k} = $over{$k};
 312                 }
 313                 $self = $tmp;
 314         }
 315
 316         my $q = uri_escape($self->{'q'}, MID_ESC);
 317         $q =~ s/%20/+/g; # improve URL readability
 318         my $qs = "q=$q";
 319
 320         if (my $o = $self->{o}) { # ignore o == 0
 321                 $qs .= "&amp;o=$o";
 322         }
 323         if (my $r = $self->{r}) {
 324                 $qs .= "&amp;r";
 325         }
 326         if (my $x = $self->{x}) {
 327                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 328         }
 329         $qs;
 330 }
 331
 332 1;