lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub mbox_results {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         require PublicInbox::Mbox;
  26         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  27         sres_top_html($ctx);
  28 }
  29
  30 sub sres_top_html {
  31         my ($ctx) = @_;
  32         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  33         my $x = $q->{x};
  34         my $query = $q->{'q'};
  35
  36         my $code = 200;
  37         # double the limit for expanded views:
  38         my $opts = {
  39                 limit => $q->{l},
  40                 offset => $q->{o},
  41                 mset => 1,
  42                 relevance => $q->{r},
  43         };
  44         my ($mset, $total, $err, $cb);
  45 retry:
  46         eval {
  47                 $mset = $ctx->{srch}->query($query, $opts);
  48                 $total = $mset->get_matches_estimated;
  49         };
  50         $err = $@;
  51         ctx_prepare($q, $ctx);
  52         if ($err) {
  53                 $code = 400;
  54                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  55                 $cb = *noop;
  56         } elsif ($total == 0) {
  57                 if (defined($ctx->{-uxs_retried})) {
  58                         # undo retry damage:
  59                         $q->{'q'} = $ctx->{-uxs_retried};
  60                 } elsif (index($q->{'q'}, '%') >= 0) {
  61                         $ctx->{-uxs_retried} = $q->{'q'};
  62                         $q->{'q'} = uri_unescape($q->{'q'});
  63                         goto retry;
  64                 }
  65                 $code = 404;
  66                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  67                 $cb = *noop;
  68         } else {
  69                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  70
  71                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  72                 if ($x eq 't') {
  73                         $cb = mset_thread($ctx, $mset, $q);
  74                 } else {
  75                         $cb = mset_summary($ctx, $mset, $q);
  76                 }
  77         }
  78         PublicInbox::WwwStream->response($ctx, $code, $cb);
  79 }
  80
  81 # allow undef for individual doc loads...
  82 sub load_doc_retry {
  83         my ($srch, $mitem) = @_;
  84
  85         eval {
  86                 $srch->retry_reopen(sub {
  87                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  88                 });
  89         }
  90 }
  91
  92 # display non-nested search results similar to what users expect from
  93 # regular WWW search engines:
  94 sub mset_summary {
  95         my ($ctx, $mset, $q) = @_;
  96
  97         my $total = $mset->get_matches_estimated;
  98         my $pad = length("$total");
  99         my $pfx = ' ' x $pad;
 100         my $res = \($ctx->{-html_tip});
 101         my $srch = $ctx->{srch};
 102         my $ibx = $ctx->{-inbox};
 103         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 104         foreach my $m ($mset->items) {
 105                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 106                 my $pct = $m->get_percent;
 107                 my $smsg = load_doc_retry($srch, $m);
 108                 unless ($smsg) {
 109                         eval {
 110                                 $m = "$m ".$m->get_docid . " expired\n";
 111                                 $ctx->{env}->{'psgi.errors'}->print($m);
 112                         };
 113                         next;
 114                 }
 115                 my $s = ascii_html($smsg->subject);
 116                 my $f = ascii_html($smsg->from_name);
 117                 if ($obfs_ibx) {
 118                         obfuscate_addrs($obfs_ibx, $s);
 119                         obfuscate_addrs($obfs_ibx, $f);
 120                 }
 121                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 122                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 123                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 124                         $s . "</a></b>\n";
 125                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 126         }
 127         $$res .= search_nav_bot($mset, $q);
 128         *noop;
 129 }
 130
 131 sub err_txt {
 132         my ($ctx, $err) = @_;
 133         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 134         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 135         $err = ascii_html($err);
 136         "\nBad query: <b>$err</b>\n" .
 137                 qq{See <a\nhref="$u">$u</a> for help on using search};
 138 }
 139
 140 sub search_nav_top {
 141         my ($mset, $q, $ctx) = @_;
 142         my $m = $q->qs_html(x => 'm', r => undef);
 143         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 144         my $initial_q = $ctx->{-uxs_retried};
 145         if (defined $initial_q) {
 146                 my $rewritten = $q->{'q'};
 147                 utf8::decode($initial_q);
 148                 utf8::decode($rewritten);
 149                 $initial_q = ascii_html($initial_q);
 150                 $rewritten = ascii_html($rewritten);
 151                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 152                 $rv .= " returned no results, used:\n";
 153                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 154         }
 155
 156         $rv .= 'Search results ordered by [';
 157         if ($q->{r}) {
 158                 my $d = $q->qs_html(r => 0);
 159                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 160         } else {
 161                 my $d = $q->qs_html(r => 1);
 162                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 163         }
 164
 165         $rv .= ']  view[';
 166
 167         my $x = $q->{x};
 168         if ($x eq '') {
 169                 my $t = $q->qs_html(x => 't');
 170                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 171         } elsif ($q->{x} eq 't') {
 172                 my $s = $q->qs_html(x => '');
 173                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 174         }
 175         my $A = $q->qs_html(x => 'A', r => undef);
 176         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 177         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 178         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 179 }
 180
 181 sub search_nav_bot {
 182         my ($mset, $q) = @_;
 183         my $total = $mset->get_matches_estimated;
 184         my $o = $q->{o};
 185         my $l = $q->{l};
 186         my $end = $o + $mset->size;
 187         my $beg = $o + 1;
 188         my $rv = '</pre><hr><pre id=t>';
 189         if ($beg <= $end) {
 190                 $rv .= "Results $beg-$end of $total";
 191                 $rv .= ' (estimated)' if $end != $total;
 192         } else {
 193                 $rv .= "No more results, only $total";
 194         }
 195         my $n = $o + $l;
 196
 197         if ($n < $total) {
 198                 my $qs = $q->qs_html(o => $n, l => $l);
 199                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 200         }
 201         if ($o > 0) {
 202                 $rv .= $n < $total ? '/' : '       ';
 203                 my $p = $o - $l;
 204                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 205                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 206         }
 207         $rv .= '</pre>';
 208 }
 209
 210 sub sort_relevance {
 211         my ($pct) = @_;
 212         sub {
 213                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 214                                 <=>
 215                         (eval { $pct->{$a->topmost->{id}} } || 0)
 216         } @{$_[0]} ] };
 217 }
 218
 219 sub mset_thread {
 220         my ($ctx, $mset, $q) = @_;
 221         my %pct;
 222         my $srch = $ctx->{srch};
 223         my $msgs = $srch->retry_reopen(sub { [ map {
 224                 my $i = $_;
 225                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 226                 $pct{$smsg->mid} = $i->get_percent;
 227                 $smsg;
 228         } ($mset->items) ]});
 229         my $r = $q->{r};
 230         my $rootset = PublicInbox::SearchThread::thread($msgs,
 231                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ds,
 232                 $ctx);
 233         my $skel = search_nav_bot($mset, $q). "<pre>";
 234         my $ibx = $ctx->{-inbox};
 235         $ctx->{-upfx} = '';
 236         $ctx->{anchor_idx} = 1;
 237         $ctx->{cur_level} = 0;
 238         $ctx->{dst} = \$skel;
 239         $ctx->{mapping} = {};
 240         $ctx->{pct} = \%pct;
 241         $ctx->{prev_attr} = '';
 242         $ctx->{prev_level} = 0;
 243         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 244
 245         # reduce hash lookups in skel_dump
 246         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 247         PublicInbox::View::walk_thread($rootset, $ctx,
 248                 *PublicInbox::View::pre_thread);
 249
 250         @$msgs = reverse @$msgs if $r;
 251         sub {
 252                 return unless $msgs;
 253                 my $smsg;
 254                 while (my $m = pop @$msgs) {
 255                         $smsg = $ibx->smsg_mime($m) and last;
 256                 }
 257                 if ($smsg) {
 258                         return PublicInbox::View::index_entry($smsg, $ctx,
 259                                 scalar @$msgs);
 260                 }
 261                 $msgs = undef;
 262                 $skel .= "\n</pre>";
 263         };
 264 }
 265
 266 sub ctx_prepare {
 267         my ($q, $ctx) = @_;
 268         my $qh = $q->{'q'};
 269         utf8::decode($qh);
 270         $qh = ascii_html($qh);
 271         $ctx->{-q_value_html} = $qh;
 272         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 273         $ctx->{-title_html} = "$qh - search results";
 274         my $extra = '';
 275         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 276         if (my $x = $q->{x}) {
 277                 $x = ascii_html($x);
 278                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 279         }
 280         $ctx->{-extra_form_html} = $extra;
 281 }
 282
 283 sub adump {
 284         my ($cb, $mset, $q, $ctx) = @_;
 285         my $ibx = $ctx->{-inbox};
 286         my @items = $mset->items;
 287         $ctx->{search_query} = $q;
 288         my $srch = $ctx->{srch};
 289         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 290                 while (my $x = shift @items) {
 291                         $x = load_doc_retry($srch, $x);
 292                         $x = $ibx->smsg_mime($x) and return $x;
 293                 }
 294                 return undef;
 295         });
 296 }
 297
 298 package PublicInbox::SearchQuery;
 299 use strict;
 300 use warnings;
 301 use URI::Escape qw(uri_escape);
 302 use PublicInbox::Hval;
 303 use PublicInbox::MID qw(MID_ESC);
 304
 305 sub new {
 306         my ($class, $qp) = @_;
 307
 308         my $r = $qp->{r};
 309         my ($l) = (($qp->{l} || '') =~ /(\d+)/);
 310         $l = $LIM if !$l || $l > $LIM;
 311         bless {
 312                 q => $qp->{'q'},
 313                 x => $qp->{x} || '',
 314                 o => (($qp->{o} || '0') =~ /(\d+)/),
 315                 l => $l,
 316                 r => (defined $r && $r ne '0'),
 317         }, $class;
 318 }
 319
 320 sub qs_html {
 321         my ($self, %over) = @_;
 322
 323         if (keys %over) {
 324                 my $tmp = bless { %$self }, ref($self);
 325                 foreach my $k (keys %over) {
 326                         $tmp->{$k} = $over{$k};
 327                 }
 328                 $self = $tmp;
 329         }
 330
 331         my $q = uri_escape($self->{'q'}, MID_ESC);
 332         $q =~ s/%20/+/g; # improve URL readability
 333         my $qs = "q=$q";
 334
 335         if (my $o = $self->{o}) { # ignore o == 0
 336                 $qs .= "&amp;o=$o";
 337         }
 338         if (my $l = $self->{l}) {
 339                 $qs .= "&amp;l=$l" unless $l == $LIM;
 340         }
 341         if (my $r = $self->{r}) {
 342                 $qs .= "&amp;r";
 343         }
 344         if (my $x = $self->{x}) {
 345                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 346         }
 347         $qs;
 348 }
 349
 350 1;