lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub sres_top_html {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         my $query = $q->{'q'};
  26         return PublicInbox::Mbox::mbox_all($ctx, $query) if $x eq 'm';
  27
  28         my $code = 200;
  29         # double the limit for expanded views:
  30         my $opts = {
  31                 limit => $LIM,
  32                 offset => $q->{o},
  33                 mset => 1,
  34                 relevance => $q->{r},
  35         };
  36         my ($mset, $total, $err, $cb);
  37 retry:
  38         eval {
  39                 $mset = $ctx->{srch}->query($query, $opts);
  40                 $total = $mset->get_matches_estimated;
  41         };
  42         $err = $@;
  43         ctx_prepare($q, $ctx);
  44         if ($err) {
  45                 $code = 400;
  46                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  47                 $cb = *noop;
  48         } elsif ($total == 0) {
  49                 if (defined($ctx->{-uxs_retried})) {
  50                         # undo retry damage:
  51                         $q->{'q'} = $ctx->{-uxs_retried};
  52                 } elsif (index($q->{'q'}, '%') >= 0) {
  53                         $ctx->{-uxs_retried} = $q->{'q'};
  54                         $q->{'q'} = uri_unescape($q->{'q'});
  55                         goto retry;
  56                 }
  57                 $code = 404;
  58                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  59                 $cb = *noop;
  60         } else {
  61                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  62
  63                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx) . "\n\n";
  64                 if ($x eq 't') {
  65                         $cb = mset_thread($ctx, $mset, $q);
  66                 } else {
  67                         $cb = mset_summary($ctx, $mset, $q);
  68                 }
  69         }
  70         PublicInbox::WwwStream->response($ctx, $code, $cb);
  71 }
  72
  73 # allow undef for individual doc loads...
  74 sub load_doc_retry {
  75         my ($srch, $mitem) = @_;
  76
  77         eval {
  78                 $srch->retry_reopen(sub {
  79                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  80                 });
  81         }
  82 }
  83
  84 # display non-nested search results similar to what users expect from
  85 # regular WWW search engines:
  86 sub mset_summary {
  87         my ($ctx, $mset, $q) = @_;
  88
  89         my $total = $mset->get_matches_estimated;
  90         my $pad = length("$total");
  91         my $pfx = ' ' x $pad;
  92         my $res = \($ctx->{-html_tip});
  93         my $srch = $ctx->{srch};
  94         my $ibx = $ctx->{-inbox};
  95         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  96         foreach my $m ($mset->items) {
  97                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  98                 my $pct = $m->get_percent;
  99                 my $smsg = load_doc_retry($srch, $m);
 100                 unless ($smsg) {
 101                         eval {
 102                                 $m = "$m ".$m->get_docid . " expired\n";
 103                                 $ctx->{env}->{'psgi.errors'}->print($m);
 104                         };
 105                         next;
 106                 }
 107                 my $s = ascii_html($smsg->subject);
 108                 my $f = ascii_html($smsg->from_name);
 109                 if ($obfs_ibx) {
 110                         obfuscate_addrs($obfs_ibx, $s);
 111                         obfuscate_addrs($obfs_ibx, $f);
 112                 }
 113                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
 114                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 115                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 116                         $s . "</a></b>\n";
 117                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
 118         }
 119         $$res .= search_nav_bot($mset, $q);
 120         *noop;
 121 }
 122
 123 sub err_txt {
 124         my ($ctx, $err) = @_;
 125         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 126         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 127         $err = ascii_html($err);
 128         "\nBad query: <b>$err</b>\n" .
 129                 qq{See <a\nhref="$u">$u</a> for help on using search};
 130 }
 131
 132 sub search_nav_top {
 133         my ($mset, $q, $ctx) = @_;
 134
 135         my $rv = '<pre>';
 136         my $initial_q = $ctx->{-uxs_retried};
 137         if (defined $initial_q) {
 138                 my $rewritten = $q->{'q'};
 139                 utf8::decode($initial_q);
 140                 utf8::decode($rewritten);
 141                 $initial_q = ascii_html($initial_q);
 142                 $rewritten = ascii_html($rewritten);
 143                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 144                 $rv .= " returned no results, used:\n";
 145                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 146         }
 147
 148         $rv .= 'Search results ordered by [';
 149         if ($q->{r}) {
 150                 my $d = $q->qs_html(r => 0);
 151                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 152         } else {
 153                 my $d = $q->qs_html(r => 1);
 154                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 155         }
 156
 157         $rv .= ']  view[';
 158
 159         my $x = $q->{x};
 160         if ($x eq '') {
 161                 my $t = $q->qs_html(x => 't');
 162                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 163         } elsif ($q->{x} eq 't') {
 164                 my $s = $q->qs_html(x => '');
 165                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 166         }
 167         my $A = $q->qs_html(x => 'A', r => undef);
 168         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 169         my $m = $q->qs_html(x => 'm', r => undef);
 170         warn "m: $m\n";
 171         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 172         $rv .= qq{<a\nhref="?$m"\nrel="nofollow">mbox.gz</a>};
 173 }
 174
 175 sub search_nav_bot {
 176         my ($mset, $q) = @_;
 177         my $total = $mset->get_matches_estimated;
 178         my $nr = scalar $mset->items;
 179         my $o = $q->{o};
 180         my $end = $o + $nr;
 181         my $beg = $o + 1;
 182         my $rv = '</pre><hr><pre id=t>';
 183         if ($beg <= $end) {
 184                 $rv .= "Results $beg-$end of $total";
 185                 $rv .= ' (estimated)' if $end != $total;
 186         } else {
 187                 $rv .= "No more results, only $total";
 188         }
 189         my $n = $o + $LIM;
 190
 191         if ($n < $total) {
 192                 my $qs = $q->qs_html(o => $n);
 193                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 194         }
 195         if ($o > 0) {
 196                 $rv .= $n < $total ? '/' : '       ';
 197                 my $p = $o - $LIM;
 198                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 199                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 200         }
 201         $rv .= '</pre>';
 202 }
 203
 204 sub sort_relevance {
 205         my ($pct) = @_;
 206         sub {
 207                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 208                                 <=>
 209                         (eval { $pct->{$a->topmost->{id}} } || 0)
 210         } @{$_[0]} ] };
 211 }
 212
 213 sub mset_thread {
 214         my ($ctx, $mset, $q) = @_;
 215         my %pct;
 216         my $srch = $ctx->{srch};
 217         my $msgs = $srch->retry_reopen(sub { [ map {
 218                 my $i = $_;
 219                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 220                 $pct{$smsg->mid} = $i->get_percent;
 221                 $smsg;
 222         } ($mset->items) ]});
 223         my $r = $q->{r};
 224         my $rootset = PublicInbox::SearchThread::thread($msgs,
 225                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ts,
 226                 $srch);
 227         my $skel = search_nav_bot($mset, $q). "<pre>";
 228         my $inbox = $ctx->{-inbox};
 229         $ctx->{-upfx} = '';
 230         $ctx->{anchor_idx} = 1;
 231         $ctx->{cur_level} = 0;
 232         $ctx->{dst} = \$skel;
 233         $ctx->{mapping} = {};
 234         $ctx->{pct} = \%pct;
 235         $ctx->{prev_attr} = '';
 236         $ctx->{prev_level} = 0;
 237         $ctx->{seen} = {};
 238         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 239
 240         # reduce hash lookups in skel_dump
 241         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 242         PublicInbox::View::walk_thread($rootset, $ctx,
 243                 *PublicInbox::View::pre_thread);
 244
 245         @$msgs = reverse @$msgs if $r;
 246         my $mime;
 247         sub {
 248                 return unless $msgs;
 249                 while ($mime = pop @$msgs) {
 250                         $mime = $inbox->msg_by_smsg($mime) and last;
 251                 }
 252                 if ($mime) {
 253                         $mime = PublicInbox::MIME->new($mime);
 254                         return PublicInbox::View::index_entry($mime, $ctx,
 255                                 scalar @$msgs);
 256                 }
 257                 $msgs = undef;
 258                 $skel .= "\n</pre>";
 259         };
 260 }
 261
 262 sub ctx_prepare {
 263         my ($q, $ctx) = @_;
 264         my $qh = $q->{'q'};
 265         utf8::decode($qh);
 266         $qh = ascii_html($qh);
 267         $ctx->{-q_value_html} = $qh;
 268         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 269         $ctx->{-title_html} = "$qh - search results";
 270         my $extra = '';
 271         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 272         if (my $x = $q->{x}) {
 273                 $x = ascii_html($x);
 274                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 275         }
 276         $ctx->{-extra_form_html} = $extra;
 277 }
 278
 279 sub adump {
 280         my ($cb, $mset, $q, $ctx) = @_;
 281         my $ibx = $ctx->{-inbox};
 282         my @items = $mset->items;
 283         $ctx->{search_query} = $q;
 284         my $srch = $ctx->{srch};
 285         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 286                 while (my $x = shift @items) {
 287                         $x = load_doc_retry($srch, $x);
 288                         $x = $ibx->msg_by_smsg($x) and
 289                                         return PublicInbox::MIME->new($x);
 290                 }
 291                 return undef;
 292         });
 293 }
 294
 295 package PublicInbox::SearchQuery;
 296 use strict;
 297 use warnings;
 298 use URI::Escape qw(uri_escape);
 299 use PublicInbox::Hval;
 300 use PublicInbox::MID qw(MID_ESC);
 301
 302 sub new {
 303         my ($class, $qp) = @_;
 304
 305         my $r = $qp->{r};
 306         bless {
 307                 q => $qp->{'q'},
 308                 x => $qp->{x} || '',
 309                 o => (($qp->{o} || '0') =~ /(\d+)/),
 310                 r => (defined $r && $r ne '0'),
 311         }, $class;
 312 }
 313
 314 sub qs_html {
 315         my ($self, %over) = @_;
 316
 317         if (keys %over) {
 318                 my $tmp = bless { %$self }, ref($self);
 319                 foreach my $k (keys %over) {
 320                         $tmp->{$k} = $over{$k};
 321                 }
 322                 $self = $tmp;
 323         }
 324
 325         my $q = uri_escape($self->{'q'}, MID_ESC);
 326         $q =~ s/%20/+/g; # improve URL readability
 327         my $qs = "q=$q";
 328
 329         if (my $o = $self->{o}) { # ignore o == 0
 330                 $qs .= "&amp;o=$o";
 331         }
 332         if (my $r = $self->{r}) {
 333                 $qs .= "&amp;r";
 334         }
 335         if (my $x = $self->{x}) {
 336                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 337         }
 338         $qs;
 339 }
 340
 341 1;