lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use URI::Escape qw(uri_unescape);
   9 use PublicInbox::Smsg;
  10 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href);
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::WwwStream qw(html_oneshot);
  14 use PublicInbox::SearchThread;
  15 use PublicInbox::SearchQuery;
  16 use PublicInbox::Search qw(mdocid);
  17 my %rmap_inc;
  18
  19 sub mbox_results {
  20         my ($ctx) = @_;
  21         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  22         my $x = $q->{x};
  23         require PublicInbox::Mbox;
  24         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  25         sres_top_html($ctx);
  26 }
  27
  28 sub sres_top_html {
  29         my ($ctx) = @_;
  30         my $srch = $ctx->{-inbox}->search or
  31                 return PublicInbox::WWW::need($ctx, 'Search');
  32         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  33         my $x = $q->{x};
  34         my $query = $q->{'q'};
  35         my $o = $q->{o};
  36         my $asc;
  37         if ($o < 0) {
  38                 $asc = 1;
  39                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  40         }
  41
  42         my $code = 200;
  43         # double the limit for expanded views:
  44         my $opts = {
  45                 limit => $q->{l},
  46                 offset => $o,
  47                 mset => 1,
  48                 relevance => $q->{r},
  49                 asc => $asc,
  50         };
  51         my ($mset, $total, $err, $html);
  52 retry:
  53         eval {
  54                 $mset = $srch->query($query, $opts);
  55                 $total = $mset->get_matches_estimated;
  56         };
  57         $err = $@;
  58         ctx_prepare($q, $ctx);
  59         if ($err) {
  60                 $code = 400;
  61                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  62         } elsif ($total == 0) {
  63                 if (defined($ctx->{-uxs_retried})) {
  64                         # undo retry damage:
  65                         $q->{'q'} = $ctx->{-uxs_retried};
  66                 } elsif (index($q->{'q'}, '%') >= 0) {
  67                         $ctx->{-uxs_retried} = $q->{'q'};
  68                         $q->{'q'} = uri_unescape($q->{'q'});
  69                         goto retry;
  70                 }
  71                 $code = 404;
  72                 $html = "<pre>\n[No results found]</pre><hr>";
  73         } else {
  74                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  75
  76                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  77                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  78                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  79                 $html = '';
  80         }
  81         html_oneshot($ctx, $code);
  82 }
  83
  84 # display non-nested search results similar to what users expect from
  85 # regular WWW search engines:
  86 sub mset_summary {
  87         my ($ctx, $mset, $q) = @_;
  88
  89         my $total = $mset->get_matches_estimated;
  90         my $pad = length("$total");
  91         my $pfx = ' ' x $pad;
  92         my $res = \($ctx->{-html_tip});
  93         my $ibx = $ctx->{-inbox};
  94         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  95         my @nums = @{$ibx->search->mset_to_artnums($mset)};
  96         my %num2msg = map { $_->{num} => $_ } @{$ibx->over->get_all(@nums)};
  97
  98         foreach my $m ($mset->items) {
  99                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 100                 my $pct = get_pct($m);
 101                 my $num = shift @nums;
 102                 my $smsg = delete($num2msg{$num}) or do {
 103                         eval {
 104                                 $m = "$m $num expired\n";
 105                                 $ctx->{env}->{'psgi.errors'}->print($m);
 106                         };
 107                         next;
 108                 };
 109                 my $s = ascii_html($smsg->{subject});
 110                 my $f = ascii_html($smsg->{from_name});
 111                 if ($obfs_ibx) {
 112                         obfuscate_addrs($obfs_ibx, $s);
 113                         obfuscate_addrs($obfs_ibx, $f);
 114                 }
 115                 my $date = PublicInbox::View::fmt_ts($smsg->{ds});
 116                 my $mid = mid_href($smsg->{mid});
 117                 $s = '(no subject)' if $s eq '';
 118                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 119                         $s . "</a></b>\n";
 120                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 121         }
 122         $$res .= search_nav_bot($mset, $q);
 123         undef;
 124 }
 125
 126 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 127 # messages don't reveal FS layout info in case people use non-standard
 128 # installation paths
 129 sub path2inc ($) {
 130         my $full = $_[0];
 131         if (my $short = $rmap_inc{$full}) {
 132                 return $short;
 133         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 134                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 135                 # fall back to basename as last resort
 136                 $rmap_inc{$full} // (split('/', $full))[-1];
 137         } else {
 138                 $full;
 139         }
 140 }
 141
 142 sub err_txt {
 143         my ($ctx, $err) = @_;
 144         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 145         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 146         $err =~ s!(\S+)!path2inc($1)!sge;
 147         $err = ascii_html($err);
 148         "\nBad query: <b>$err</b>\n" .
 149                 qq{See <a\nhref="$u">$u</a> for help on using search};
 150 }
 151
 152 sub search_nav_top {
 153         my ($mset, $q, $ctx) = @_;
 154         my $m = $q->qs_html(x => 'm', r => undef);
 155         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 156         my $initial_q = $ctx->{-uxs_retried};
 157         if (defined $initial_q) {
 158                 my $rewritten = $q->{'q'};
 159                 utf8::decode($initial_q);
 160                 utf8::decode($rewritten);
 161                 $initial_q = ascii_html($initial_q);
 162                 $rewritten = ascii_html($rewritten);
 163                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 164                 $rv .= " returned no results, used:\n";
 165                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 166         }
 167
 168         $rv .= 'Search results ordered by [';
 169         if ($q->{r}) {
 170                 my $d = $q->qs_html(r => 0);
 171                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 172         } else {
 173                 my $d = $q->qs_html(r => 1);
 174                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 175         }
 176
 177         $rv .= ']  view[';
 178
 179         my $x = $q->{x};
 180         if ($x eq '') {
 181                 my $t = $q->qs_html(x => 't');
 182                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 183         } elsif ($q->{x} eq 't') {
 184                 my $s = $q->qs_html(x => '');
 185                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 186         }
 187         my $A = $q->qs_html(x => 'A', r => undef);
 188         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 189         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 190         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 191 }
 192
 193 sub search_nav_bot {
 194         my ($mset, $q) = @_;
 195         my $total = $mset->get_matches_estimated;
 196         my $l = $q->{l};
 197         my $rv = '</pre><hr><pre id=t>';
 198         my $o = $q->{o};
 199         my $off = $o < 0 ? -($o + 1) : $o;
 200         my $end = $off + $mset->size;
 201         my $beg = $off + 1;
 202
 203         if ($beg <= $end) {
 204                 $rv .= "Results $beg-$end of $total";
 205                 $rv .= ' (estimated)' if $end != $total;
 206         } else {
 207                 $rv .= "No more results, only $total";
 208         }
 209         my ($next, $join, $prev);
 210
 211         if ($o >= 0) { # sort descending
 212                 my $n = $o + $l;
 213                 if ($n < $total) {
 214                         $next = $q->qs_html(o => $n, l => $l);
 215                 }
 216                 if ($o > 0) {
 217                         $join = $n < $total ? '/' : '       ';
 218                         my $p = $o - $l;
 219                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 220                 }
 221         } else { # o < 0, sort ascending
 222                 my $n = $o - $l;
 223
 224                 if (-$n < $total) {
 225                         $next = $q->qs_html(o => $n, l => $l);
 226                 }
 227                 if ($o < -1) {
 228                         $join = -$n < $total ? '/' : '       ';
 229                         my $p = $o + $l;
 230                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 231                 }
 232         }
 233
 234         $rv .= qq{  <a\nhref="?$next"\nrel=next>next</a>} if $next;
 235         $rv .= $join if $join;
 236         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev</a>} if $prev;
 237
 238         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 239         $rv .= qq{ | <a\nhref="?$rev">reverse results</a></pre>};
 240 }
 241
 242 sub sort_relevance {
 243         [ sort {
 244                 (eval { $b->topmost->{pct} } // 0) <=>
 245                 (eval { $a->topmost->{pct} } // 0)
 246         } @{$_[0]} ]
 247 }
 248
 249 sub get_pct ($) {
 250         # Capped at "99%" since "100%" takes an extra column in the
 251         # thread skeleton view.  <xapian/mset.h> says the value isn't
 252         # very meaningful, anyways.
 253         my $n = $_[0]->get_percent;
 254         $n > 99 ? 99 : $n;
 255 }
 256
 257 sub mset_thread {
 258         my ($ctx, $mset, $q) = @_;
 259         my $ibx = $ctx->{-inbox};
 260         my $nshard = $ibx->search->{nshard} // 1;
 261         my %pct = map { mdocid($nshard, $_) => get_pct($_) } $mset->items;
 262         my $msgs = $ibx->over->get_all(keys %pct);
 263         $_->{pct} = $pct{$_->{num}} for @$msgs;
 264         my $r = $q->{r};
 265         my $rootset = PublicInbox::SearchThread::thread($msgs,
 266                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 267                 $ctx);
 268         my $skel = search_nav_bot($mset, $q). "<pre>";
 269         $ctx->{-upfx} = '';
 270         $ctx->{anchor_idx} = 1;
 271         $ctx->{cur_level} = 0;
 272         $ctx->{skel} = \$skel;
 273         $ctx->{mapping} = {};
 274         $ctx->{searchview} = 1;
 275         $ctx->{prev_attr} = '';
 276         $ctx->{prev_level} = 0;
 277         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 278
 279         # reduce hash lookups in skel_dump
 280         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 281         PublicInbox::View::walk_thread($rootset, $ctx,
 282                 \&PublicInbox::View::pre_thread);
 283
 284         @$msgs = reverse @$msgs if $r;
 285         $ctx->{msgs} = $msgs;
 286         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 287 }
 288
 289 # callback for PublicInbox::WwwStream::getline
 290 sub mset_thread_i {
 291         my ($ctx, $eml) = @_;
 292         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 293         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 294         my $smsg = shift @{$ctx->{msgs}} or
 295                 $ctx->zmore(${delete($ctx->{skel})});
 296         $smsg;
 297 }
 298
 299 sub ctx_prepare {
 300         my ($q, $ctx) = @_;
 301         my $qh = $q->{'q'};
 302         utf8::decode($qh);
 303         $qh = ascii_html($qh);
 304         $ctx->{-q_value_html} = $qh;
 305         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 306         $ctx->{-title_html} = "$qh - search results";
 307         my $extra = '';
 308         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 309         if (my $x = $q->{x}) {
 310                 $x = ascii_html($x);
 311                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 312         }
 313         $ctx->{-extra_form_html} = $extra;
 314 }
 315
 316 sub adump {
 317         my ($cb, $mset, $q, $ctx) = @_;
 318         $ctx->{ids} = $ctx->{-inbox}->search->mset_to_artnums($mset);
 319         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 320         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 321 }
 322
 323 # callback for PublicInbox::WwwAtomStream::getline
 324 sub adump_i {
 325         my ($ctx) = @_;
 326         while (my $num = shift @{$ctx->{ids}}) {
 327                 my $smsg = eval { $ctx->{-inbox}->over->get_art($num) } or next;
 328                 return $smsg;
 329         }
 330 }
 331
 332 1;