lib/PublicInbox/SearchView.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use List::Util qw(min max);
   9 use URI::Escape qw(uri_unescape);
  10 use PublicInbox::Smsg;
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href fmt_ts);
  12 use PublicInbox::View;
  13 use PublicInbox::WwwAtomStream;
  14 use PublicInbox::WwwStream qw(html_oneshot);
  15 use PublicInbox::SearchThread;
  16 use PublicInbox::SearchQuery;
  17 use PublicInbox::Search qw(get_pct);
  18 my %rmap_inc;
  19
  20 sub mbox_results {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         if ($ctx->{env}->{'psgi.input'}->read(my $buf, 3)) {
  24                 $q->{t} = 1 if $buf =~ /\Ax=[^0]/;
  25         }
  26         require PublicInbox::Mbox;
  27         $q->{x} eq 'm' ? PublicInbox::Mbox::mbox_all($ctx, $q) :
  28                         sres_top_html($ctx);
  29 }
  30
  31 sub sres_top_html {
  32         my ($ctx) = @_;
  33         my $srch = $ctx->{ibx}->isrch or
  34                 return PublicInbox::WWW::need($ctx, 'Search');
  35         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  36         my $x = $q->{x};
  37         my $o = $q->{o};
  38         my $asc;
  39         if ($o < 0) {
  40                 $asc = 1;
  41                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  42         }
  43
  44         my $code = 200;
  45         # double the limit for expanded views:
  46         my $opts = {
  47                 limit => $q->{l},
  48                 offset => $o,
  49                 relevance => $q->{r},
  50                 threads => $q->{t},
  51                 asc => $asc,
  52         };
  53         my ($mset, $total, $err, $html);
  54 retry:
  55         eval {
  56                 my $query = $q->{'q'};
  57                 $srch->query_approxidate($ctx->{ibx}->git, $query);
  58                 $mset = $srch->mset($query, $opts);
  59                 $total = $mset->get_matches_estimated;
  60         };
  61         $err = $@;
  62         ctx_prepare($q, $ctx);
  63         if ($err) {
  64                 $code = 400;
  65                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  66         } elsif ($total == 0) {
  67                 if (defined($ctx->{-uxs_retried})) {
  68                         # undo retry damage:
  69                         $q->{'q'} = $ctx->{-uxs_retried};
  70                 } elsif (index($q->{'q'}, '%') >= 0) {
  71                         $ctx->{-uxs_retried} = $q->{'q'};
  72                         $q->{'q'} = uri_unescape($q->{'q'});
  73                         goto retry;
  74                 }
  75                 $code = 404;
  76                 $html = "<pre>\n[No results found]</pre><hr>";
  77         } else {
  78                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  79
  80                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  81                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  82                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  83                 $html = '';
  84         }
  85         html_oneshot($ctx, $code);
  86 }
  87
  88 # display non-nested search results similar to what users expect from
  89 # regular WWW search engines:
  90 sub mset_summary {
  91         my ($ctx, $mset, $q) = @_;
  92
  93         my $total = $mset->get_matches_estimated;
  94         my $pad = length("$total");
  95         my $pfx = ' ' x $pad;
  96         my $res = \($ctx->{-html_tip});
  97         my $ibx = $ctx->{ibx};
  98         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  99         my @nums = @{$ibx->isrch->mset_to_artnums($mset)};
 100         my %num2msg = map { $_->{num} => $_ } @{$ibx->over->get_all(@nums)};
 101         my ($min, $max, %seen);
 102
 103         foreach my $m ($mset->items) {
 104                 my $num = shift @nums;
 105                 my $smsg = delete($num2msg{$num}) // do {
 106                         warn "$m $num expired\n";
 107                         next;
 108                 };
 109                 my $mid = $smsg->{mid};
 110                 next if $seen{$mid}++;
 111                 $mid = mid_href($mid);
 112                 $ctx->{-t_max} //= $smsg->{ts};
 113                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 114                 my $pct = get_pct($m);
 115
 116                 # only when sorting by relevance, ->items is always
 117                 # ordered descending:
 118                 $max //= $pct;
 119                 $min = $pct;
 120
 121                 my $s = ascii_html($smsg->{subject});
 122                 my $f = ascii_html(delete $smsg->{from_name});
 123                 if ($obfs_ibx) {
 124                         obfuscate_addrs($obfs_ibx, $s);
 125                         obfuscate_addrs($obfs_ibx, $f);
 126                 }
 127                 my $date = fmt_ts($smsg->{ds});
 128                 $s = '(no subject)' if $s eq '';
 129                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 130                         $s . "</a></b>\n";
 131                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 132         }
 133         if ($q->{r}) { # for descriptions in search_nav_bot
 134                 $q->{-min_pct} = $min;
 135                 $q->{-max_pct} = $max;
 136         }
 137         $$res .= search_nav_bot($mset, $q);
 138         undef;
 139 }
 140
 141 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 142 # messages don't reveal FS layout info in case people use non-standard
 143 # installation paths
 144 sub path2inc ($) {
 145         my $full = $_[0];
 146         if (my $short = $rmap_inc{$full}) {
 147                 return $short;
 148         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 149                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 150                 # fall back to basename as last resort
 151                 $rmap_inc{$full} // (split('/', $full))[-1];
 152         } else {
 153                 $full;
 154         }
 155 }
 156
 157 sub err_txt {
 158         my ($ctx, $err) = @_;
 159         my $u = $ctx->{ibx}->base_url($ctx->{env}) . '_/text/help/';
 160         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 161         $err =~ s!(\S+)!path2inc($1)!sge;
 162         $err = ascii_html($err);
 163         "\nBad query: <b>$err</b>\n" .
 164                 qq{See <a\nhref="$u">$u</a> for help on using search};
 165 }
 166
 167 sub search_nav_top {
 168         my ($mset, $q, $ctx) = @_;
 169         my $m = $q->qs_html(x => 'm', r => undef, t => undef);
 170         my $rv = qq{<form\nid=d\naction="?$m"\nmethod=post><pre>};
 171         my $initial_q = $ctx->{-uxs_retried};
 172         if (defined $initial_q) {
 173                 my $rewritten = $q->{'q'};
 174                 utf8::decode($initial_q);
 175                 utf8::decode($rewritten);
 176                 $initial_q = ascii_html($initial_q);
 177                 $rewritten = ascii_html($rewritten);
 178                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 179                 $rv .= " returned no results, used:\n";
 180                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 181         }
 182
 183         $rv .= 'Search results ordered by [';
 184         if ($q->{r}) {
 185                 my $d = $q->qs_html(r => 0);
 186                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 187         } else {
 188                 my $d = $q->qs_html(r => 1);
 189                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 190         }
 191
 192         $rv .= ']  view[';
 193
 194         my $x = $q->{x};
 195         my $pfx = "\t\t\t";
 196         if ($x eq 't') {
 197                 my $s = $q->qs_html(x => '');
 198                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 199                 $pfx = "thread overview <a\nhref=#t>below</a> | ";
 200         } else {
 201                 my $t = $q->qs_html(x => 't');
 202                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 203         }
 204         my $A = $q->qs_html(x => 'A', r => undef);
 205         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]\n};
 206         $rv .= <<EOM if $x ne 't' && $q->{t};
 207 *** "t=1" collapses threads in summary, "full threads" requires mbox.gz ***
 208 EOM
 209         $rv .= <<EOM if $x eq 'm';
 210 *** "x=m" ignored for GET requests, use download buttons below ***
 211 EOM
 212         if ($ctx->{ibx}->isrch->has_threadid) {
 213                 $rv .= qq{${pfx}download mbox.gz: } .
 214                         # we set name=z w/o using it since it seems required for
 215                         # lynx (but works fine for w3m).
 216                         qq{<input\ntype=submit\nname=z\n} .
 217                                 q{value="results only"/>} .
 218                         qq{|<input\ntype=submit\nname=x\n} .
 219                                 q{value="full threads"/>};
 220         } else { # BOFH needs to --reindex
 221                 $rv .= qq{${pfx}download: } .
 222                         qq{<input\ntype=submit\nname=z\nvalue="mbox.gz"/>}
 223         }
 224         $rv .= qq{</pre></form><pre>};
 225 }
 226
 227 sub search_nav_bot { # also used by WwwListing for searching extindex miscidx
 228         my ($mset, $q) = @_;
 229         my $total = $mset->get_matches_estimated;
 230         my $l = $q->{l};
 231         my $rv = '</pre><hr><pre id=t>';
 232         my $o = $q->{o};
 233         my $off = $o < 0 ? -($o + 1) : $o;
 234         my $end = $off + $mset->size;
 235         my $beg = $off + 1;
 236
 237         if ($beg <= $end) {
 238                 my $approx = $end == $total ? '' : '~';
 239                 $rv .= "Results $beg-$end of $approx$total";
 240         } else {
 241                 $rv .= "No more results, only $total";
 242         }
 243         my ($next, $join, $prev, $nd, $pd);
 244
 245         if ($o >= 0) { # sort descending
 246                 my $n = $o + $l;
 247                 if ($n < $total) {
 248                         $next = $q->qs_html(o => $n, l => $l);
 249                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(older)';
 250                 }
 251                 if ($o > 0) {
 252                         $join = $n < $total ? ' | ' : "\t";
 253                         my $p = $o - $l;
 254                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 255                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(newer)';
 256                 }
 257         } else { # o < 0, sort ascending
 258                 my $n = $o - $l;
 259
 260                 if (-$n < $total) {
 261                         $next = $q->qs_html(o => $n, l => $l);
 262                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(newer)';
 263                 }
 264                 if ($o < -1) {
 265                         $join = -$n < $total ? ' | ' : "\t";
 266                         my $p = $o + $l;
 267                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 268                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(older)';
 269                 }
 270         }
 271
 272         $rv .= qq{  <a\nhref="?$next"\nrel=next>next $nd</a>} if $next;
 273         $rv .= $join if $join;
 274         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev $pd</a>} if $prev;
 275
 276         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 277         $rv .= qq{ | <a\nhref="?$rev">reverse</a>} .
 278                 q{ | sort options + mbox downloads } .
 279                 q{<a href=#d>above</a></pre>};
 280 }
 281
 282 sub sort_relevance {
 283         @{$_[0]} = sort {
 284                 (eval { $b->topmost->{pct} } // 0) <=>
 285                 (eval { $a->topmost->{pct} } // 0)
 286         } @{$_[0]};
 287 }
 288
 289 sub mset_thread {
 290         my ($ctx, $mset, $q) = @_;
 291         my $ibx = $ctx->{ibx};
 292         my @pct = map { get_pct($_) } $mset->items;
 293         my $msgs = $ibx->isrch->mset_to_smsg($ibx, $mset);
 294         my $i = 0;
 295         $_->{pct} = $pct[$i++] for @$msgs;
 296         my $r = $q->{r};
 297         if ($r) { # for descriptions in search_nav_bot
 298                 $q->{-min_pct} = min(@pct);
 299                 $q->{-max_pct} = max(@pct);
 300         }
 301         my $rootset = PublicInbox::SearchThread::thread($msgs,
 302                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 303                 $ctx);
 304         my $skel = search_nav_bot($mset, $q).
 305                 "<pre>-- links below jump to the message on this page --\n";
 306
 307         $ctx->{-upfx} = '';
 308         $ctx->{anchor_idx} = 1;
 309         $ctx->{cur_level} = 0;
 310         $ctx->{skel} = \$skel;
 311         $ctx->{mapping} = {};
 312         $ctx->{searchview} = 1;
 313         $ctx->{prev_attr} = '';
 314         $ctx->{prev_level} = 0;
 315         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 316
 317         # reduce hash lookups in skel_dump
 318         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 319         PublicInbox::View::walk_thread($rootset, $ctx,
 320                 \&PublicInbox::View::pre_thread);
 321
 322         # link $INBOX_DIR/description text to "recent" view around
 323         # the newest message in this result set:
 324         $ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs);
 325
 326         @$msgs = reverse @$msgs if $r;
 327         $ctx->{msgs} = $msgs;
 328         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 329 }
 330
 331 # callback for PublicInbox::WwwStream::getline
 332 sub mset_thread_i {
 333         my ($ctx, $eml) = @_;
 334         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 335         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 336         my $smsg = shift @{$ctx->{msgs}} or
 337                 $ctx->zmore(${delete($ctx->{skel})});
 338         $smsg;
 339 }
 340
 341 sub ctx_prepare {
 342         my ($q, $ctx) = @_;
 343         my $qh = $q->{'q'};
 344         utf8::decode($qh);
 345         $qh = ascii_html($qh);
 346         $ctx->{-q_value_html} = $qh;
 347         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 348         $ctx->{-title_html} = "$qh - search results";
 349         my $extra = '';
 350         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 351         if (my $x = $q->{x}) {
 352                 $x = ascii_html($x);
 353                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 354         }
 355         $ctx->{-extra_form_html} = $extra;
 356 }
 357
 358 sub adump {
 359         my ($cb, $mset, $q, $ctx) = @_;
 360         $ctx->{ids} = $ctx->{ibx}->isrch->mset_to_artnums($mset);
 361         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 362         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 363 }
 364
 365 # callback for PublicInbox::WwwAtomStream::getline
 366 sub adump_i {
 367         my ($ctx) = @_;
 368         while (my $num = shift @{$ctx->{ids}}) {
 369                 my $smsg = eval { $ctx->{ibx}->over->get_art($num) } or next;
 370                 return $smsg;
 371         }
 372 }
 373
 374 1;